Discussion :

[jinane13]

Bonjour,
voila j'ai fait un macro qui calcule la moyenne mobile d'une série mais à un certain moment ca donne des 0.
est ce quelqu'un peut m'aider?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub somme()
Dim a, c, moy As Variant
Dim d, e As Variant
Range("B1").Value = "moyenne_mobile"
d = 0
For e = 2 To Cells(1, 7) + 1
d = d + Cells(e, 1)
 Selection.NumberFormat = "0.00"
Next
Cells(2, 2) = d / Cells(1, 7)
c = 0
'cells(1,7) =période
For c = 1 To 10
moy = 0
For a = c * Cells(1, 7) + c To (c + 1) * Cells(1, 7) + c - 1
moy = moy + Cells(a, 1)
Next
Cells(c + 2, 2) = moy / Cells(1, 7)
Selection.NumberFormat = "0.00"
Next
End Sub

[arnaud.123]

Salut,

Peux-tu transmettre ton tableau (ou définir les cellules)
A+

Arnaud

[jinane13]

ci joint le resultat du macro

[jinane13]

j'aimerai aussi savoir comment faire pour calculer le nombre de cellule pleine d'une colonne sous VBA.
Merci d'avance

[mercatog]

Si en G1 tu as la période de calcule de la moyenne mobile

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub MoyenneMobileDirecte()
Dim LastLig As Long
Dim Period As Integer
 
Application.ScreenUpdating = False
With Worksheets("Sheet1")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    .Range("B1").Value = "Moyenne Mobile"
    Period = .Range("G1").Value
    If Period > 0 Then
        With .Range("B2:B" & LastLig - Period + 1)
            .Formula = "=AVERAGE(OFFSET(A2,0,0," & Period & "))"
            .Value = .Value
        End With
    End If
End With
End Sub

________________________________________________________________

Sinon, au cas d'un nombre important de données, il est préférable de travailler avec des variables tableaux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub MoyenneMobile()
Dim LastLig As Long, i As Long
Dim Period As Integer
Dim Tb
 
Application.ScreenUpdating = False
With Worksheets("Sheet1")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    Tb = .Range("A1:B" & LastLig)
    Period = .Range("G1").Value
    If Period > 0 Then
        Tb(1, 2) = "Moyenne mobile (Période " & Period & ")"
        For i = 2 To LastLig - Period + 1
            Call MM(Tb, i, Period)
        Next i
        .Range("A1:B" & LastLig) = Tb
    End If
End With
End Sub
 
Private Sub MM(ByRef Tb, ByVal Deb As Long, ByVal Pas As Integer)
Dim S As Double
Dim i As Long
 
For i = Deb To Deb + Pas - 1
    S = S + Tb(i, 1)
Next i
Tb(Deb, 2) = S / Pas
End Sub

[jinane13]

Merci le problème est résolu