Discussion :

[Thomy54]

Bonjour,

Je débute dans le VBA et j'essaye de coder une listbox qui m'affiche le nom de tous mes onglets.

Voici le code que j'ai écrit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub ListBox1_Change()
n = 0
m = 0
Z = 0
 
Sheets("Feuil35").Activate
Z = ListBox1.ListIndex
n = ListBox1.List(Z)
m = Sheets(n).Index
Range("A1").Value = n
Range("A2").Value = m
 
UserForm1.Hide
 
End Sub

-----------

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub UserForm_Activate()
 
Me.ListBox1.Clear
For i = 8 To 33
Me.ListBox1.AddItem Sheets(i).Name
Next
 
End Sub

Il marche plutôt bien seulement il y a un hic !
Il marche une fois et la seconde fois il me renvoi l'erreur d'execution 381. et il a quelquechose contre le ligne suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

n = ListBox1.List(Z)

Auriez vous une réponse ?

Merci d'avance !

Thomas

[Theze]

Bonjour,

Tu devrais déclarer tes variables de façon explicite et bien sûr les typées aussi de façon explicite car sinon elles sont de type "Variant". Dans ton code, au début, la variable "n" est de type "Integer" (n = 0) ensuite le compilateur doit faire une conversion de type pour en faire un type "String" (ce qui, si ça se produit souvent dans le code, le ralenti). Comme tu commence à programmer je te conseillerai d'aller dans le menu Outils > Options... > Onglet Editeur et cocher la case "Déclaration des variables obligatoire", ce qui aura pour effet d'inscrire en tête de tous modules la mention "Option Explicit". Ensuite, le débogueur s'arrêtera sur chaque variable non déclarée.
Bien sûr, il te faudra aussi typer chaque variable, si elle doit recevoir du texte, elle sera de type String ce qui est le cas dans ton code, etc...
De cette façon, je n'ai pas d'erreur en exécutant plusieurs fois l'évènement Change de la ListBox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Private Sub ListBox1_Change()
 
    Dim n As String
    Dim m As Integer
    Dim z As Integer
 
    'Integer retouné
    z = ListBox1.ListIndex
 
    'String retourné
    n = ListBox1.List(z)
 
    'Integer retourné
    m = Sheets(n).Index
 
    Range("A1").Value = n
    Range("A2").Value = m
 
    UserForm1.Hide
 
End Sub
 
Private Sub UserForm_Initialize()
 
    Dim I As Integer
 
    For I = 8 To 33
 
        ListBox1.AddItem Sheets(I).Name
 
    Next
 
    'ceci peut être mis ici, il ne sert à rien de l'exécuter plusieur fois
    Sheets("Feuil35").Activate
 
End Sub

Hervé.

[gFZT82]

Bonjour Thomas , Hervé, le forum,

Une petite explication complémentaire sur le dysfonctionnement que tu as constaté avec ton code.
A la première activation de l'Userform, l'effacement de la ListBox (ListBox1.Clear) ne provoque pas l'évènement Change puisque la ListBox est vide.
Par contre, à la deuxième activation de l'Userform, cet effacement provoque l'évènement Change, la ListBox étant alors renseignée.
La procédure ListBox1_Change() étant lancée avec la ListBox vide, z est égal à -1 et ListBox1.List(Z) ne peut pas retourner un élément puisque la liste est vide.

Cordialement.

[Thomy54]

Merci Hervé mais ça ne marche toujours pas.

gFZT82 que dois je faire pour qu'il marche ? qu'elles sont les modifs necessaires ?

Merci d'avance

[Philippe Tulliez]

Bonjour,
Ceci devrait fonctionner

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Private Sub ListBox1_Change()
 With ListBox1
  If .ListIndex > -1 Then WriteData .ListIndex: UserForm1.Hide
 End With
End Sub
Private Sub UserForm_Activate()
 Dim i As Byte
 Me.ListBox1.Clear
 For i = 8 To 33: Me.ListBox1.AddItem Sheets(i).Name: Next
End Sub
Private Sub WriteData(Selection As Byte)
 With Sheets("Feuil1")
 .Range("A1").Value = ListBox1.List(Selection)
 .Range("A2").Value = Sheets(ListBox1.List(Selection)).Index
 End With
End Sub

[Thomy54]

Ca marche super !!!
Merci beaucoup !!