Discussion :

[Chris171717]

* Bonjour, *

avec le code suivant je fait un tri alphbetique dans une listbox... malheureusement ce tri ne se fait que sur la première colonne de ma listbox...
c'est bien la colonne de référence pour le tri, mais le reste des colonnes ne suit pas...

Comment puis-je adapter ce code pour 6 colonnes... !?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
  With ListBox1
    If .ListCount < 2 Then Exit Sub
    Do
      Ok = True
      For i = 0 To .ListCount - 2
        If .List(i) > .List(i + 1) Then
          temp = .List(i)
          .List(i) = .List(i + 1)
          .List(i + 1) = temp
          Ok = False
        End If
      Next i
    Loop Until Ok = True
  End With

* Merci *

[NVCfrm]

bonsoir,

je penses qu'il te faut aborder la liste comme suit ;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Dim L as Integer, C as Integer, i as Integer,n, Temp
 
L= Ubound(Listbox1.List)
c= Ubound(Listbox1.List,2)
Redim Temp (1 to L, 1 to c)
"La boucle imbriquée te permet de passer en revue les colonnes"
For i = 1 l
    if ....then
       For n= 1 to c
....
       Next
next

Je me poses la question suivante: obtiens tu vraiment un tri cohérent sur ta première colonne avec ton code si différentes lignes ont une valeur identique ?


PS: n'oublies pas que l'indice de base est 0

[Chris171717]

c'est à dire qu'en fait il faudrait générer un code qui reprend le principe de l'option tri de excel...

le tri doit s'effectuer par Nom (colonne A) puis par Prénom (colonne B) puis par classe (colonne C)

c'est bien ça ?

[NVCfrm]

re,

Oui c'est une idée à laquelle je n'avais pas pensé.
tu as déjà un support : Excel qui met à ta disposition plein de fonctions.

tu n'as qu'à envoyer ta liste sur une plage libre. y effectuer le tri proprement et ramener cette valeur.

[Chris171717]

Peut-être une question bête... mais peut-on utiliser la fonction '.Sort' dans une listbox !?

:roll

[sophieceuzin]

Bonjour,

-Ne pas trier directement un ListBox (lent) mais trier dans un tableau.
-Utiliser un tri rapide (Quick Sort) et non pas un tri du type Bubble (très lent)

Voir en PJ différentes façons de trier un ListBox (tableau ou tableur).

Ceuzin

[Chris171717]

Ok je vais regarder ça pour essayer d'adapter... mais je n'ai pas besoin de cliquer quelque part pour faire mon tri, je veux qu'il soit automatique par Nom / Prénom / Classe... à l'ouverture de la listbox

[sophieceuzin]

Tri par nom+prénom

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
 
Private Sub UserForm_Initialize()
 Dim clé() As String, index() As Long, a(), b()
 With Sheets("TriListBox")
   Me.ListBox1.List = .Range("A2:C" & .[A65000].End(xlUp).Row).Value
 End With
 a = Me.ListBox1.List
 ReDim b(LBound(a) To UBound(a), LBound(a, 2) To UBound(a, 2))
 ReDim clé(LBound(a) To UBound(a, 1))
 ReDim index(LBound(a) To UBound(a, 1))
 For i = LBound(a) To UBound(a, 1)
    clé(i) = a(i, 0) & a(i, 1): index(i) = i
  Next i
  Call Tri(clé(), index(), LBound(a), UBound(clé))
  For lig = LBound(clé) To UBound(clé)
     For col = LBound(a, 2) To UBound(a, 2): b(lig, col) = a(index(lig), col): Next col
  Next lig
  Me.ListBox1.List = b
End Sub
 
Sub Tri(clé() As String, index() As Long, gauc, droi) ' Quick sort
  ref = clé((gauc + droi) \ 2)
  g = gauc: d = droi
  Do
    Do While clé(g) < ref: g = g + 1: Loop
    Do While ref < clé(d): d = d - 1: Loop
    If g <= d Then
      temp = clé(g): clé(g) = clé(d): clé(d) = temp
      temp = index(g): index(g) = index(d): index(d) = temp
      g = g + 1: d = d - 1
    End If
  Loop While g <= d
  If g < droi Then Call Tri(clé, index, g, droi)
  If gauc < d Then Call Tri(clé, index, gauc, d)
End Sub

Ceuzin

[Chris171717]

Oups je t'ai dit une bétise... j'étais encore sur mon ancien fonctionnement.. en fait le tri doit se faire :

* après selection de combobox pour un userform
* après click sur un commandbutton pour un autre userform

Je suppose donc que je dois juste adapter et déplacer la partie que tu as mis dans 'Initialize' pour la placer dans 'ComboBox_Click' ou 'CommandButton_Click' selon le cas

Est-ce que c'est bien ça !?

[NVCfrm]

bonsoir,

Peut-être une question bête... mais peut-on utiliser la fonction '.Sort' dans une listbox !?

:roll

non. C'est une méthode qui ne s'applique que sur un objet range.
Pour t'aider voici un exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Dim r_dest As Range, n, lbx
 
'si la liste comporte des entêtes XlGuess
lbx = listbox1.List
Set r_dest = Range("x1").Range(Cells(1, 1), Cells(UBound(lbx, 1), UBound(lbx, 2)))
r_dest = lbx
r_dest.Sort r_dest.Columns(2), xlDescending
lbx = r_dest
 r_dest.ClearContents
listbox1.List = lbx

tu peux trier pour un groupage des valeurs semblables sur différentes colonnes aussi en procédant ainsi jusqu'à 3 niveaux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
r_dest.Sort key1:=r_dest.Columns(1), order1:=xlDescending, key2:=r_dest.Columns(2), _
Order2:=xlDescending, key3:=r_dest.Columns(3), order3:=xlDescending

[Chris171717]

NVCfrm

D'accord, mais du coup comment faire pour trier uniquement dans la listbox... je n'arrive décidément pas à trouver ma solution...
____

sophieceuzin

ton code fonctionne mais du coup je n'ai plus que nom prénom et classes qui s'affichent dans ma listbox...

[sophieceuzin]

Envoie un échantillon du fichier.

Ceuzin

[Chris171717]

Voilà

j'ai inséré ton code dans le userform3 dans le combobox1_click

[sophieceuzin]

Il faut supprimer ces lignes (elles transfèrent toute la bd dans la listbox)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 'With Sheets("Retenues")
 '  Me.ListBox1.List = .Range("A2:I" & .[A65000].End(xlUp).Row).Value
 'End With

Ceuzin

[Chris171717]

Super Merci beaucoup ça fonctionne parfaitement maintenant...

a moi d'adapter à mes autres userform...

Re !

J'ai parlé un peu vite... ça fonctionne partout SAUF pour mon userform4 où je l'ai intégré dans 3 combobox... ça fonctionne pour la première et la troisième mais pas pour la seconde... j'ai une erreur 'incompatibilité de type' à la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

a = Me.ListBox1.List

aurais-tu une idée !?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
'MISE A JOUR DES VALEURS DEPUIS LA COMBOBOX1
Private Sub ComboBox1_Click()
 MajLiset Me.ComboBox1, Me.ComboBox2, Me.ComboBox3
 
 'pour trier l'affichage
 Dim Lig
 Dim Col
 Dim clé() As String, index() As Long, a(), b()
 a = Me.ListBox1.List
 ReDim b(LBound(a) To UBound(a), LBound(a, 2) To UBound(a, 2))
 ReDim clé(LBound(a) To UBound(a, 1))
 ReDim index(LBound(a) To UBound(a, 1))
 For i = LBound(a) To UBound(a, 1)
    clé(i) = a(i, 0) & a(i, 1): index(i) = i
  Next i
  Call Tri(clé(), index(), LBound(a), UBound(clé))
  For Lig = LBound(clé) To UBound(clé)
     For Col = LBound(a, 2) To UBound(a, 2): b(Lig, Col) = a(index(Lig), Col): Next Col
  Next Lig
  Me.ListBox1.List = b
 
End Sub
 
'MISE A JOUR DES VALEURS DEPUIS LA COMBOBOX2
Private Sub ComboBox2_Click()
 MajLiset Me.ComboBox1, Me.ComboBox2, Me.ComboBox3
 
'pour trier l'affichage
 Dim Lig
 Dim Col
 Dim clé() As String, index() As Long, a(), b()
 a = Me.ListBox1.List
 ReDim b(LBound(a) To UBound(a), LBound(a, 2) To UBound(a, 2))
 ReDim clé(LBound(a) To UBound(a, 1))
 ReDim index(LBound(a) To UBound(a, 1))
 For i = LBound(a) To UBound(a, 1)
    clé(i) = a(i, 0) & a(i, 1): index(i) = i
  Next i
  Call Tri(clé(), index(), LBound(a), UBound(clé))
  For Lig = LBound(clé) To UBound(clé)
     For Col = LBound(a, 2) To UBound(a, 2): b(Lig, Col) = a(index(Lig), Col): Next Col
  Next Lig
  Me.ListBox1.List = b
 
End Sub
 
'MISE A JOUR DES VALEURS DEPUIS LA COMBOBOX3
Private Sub ComboBox3_Click()
 MajLiset Me.ComboBox1, Me.ComboBox2, Me.ComboBox3
 
'pour trier l'affichage
 Dim Lig
 Dim Col
 Dim clé() As String, index() As Long, a(), b()
 a = Me.ListBox1.List
 ReDim b(LBound(a) To UBound(a), LBound(a, 2) To UBound(a, 2))
 ReDim clé(LBound(a) To UBound(a, 1))
 ReDim index(LBound(a) To UBound(a, 1))
 For i = LBound(a) To UBound(a, 1)
    clé(i) = a(i, 0) & a(i, 1): index(i) = i
  Next i
  Call Tri(clé(), index(), LBound(a), UBound(clé))
  For Lig = LBound(clé) To UBound(clé)
     For Col = LBound(a, 2) To UBound(a, 2): b(Lig, Col) = a(index(Lig), Col): Next Col
  Next Lig
  Me.ListBox1.List = b
 
End Sub
 
Sub Tri(clé() As String, index() As Long, gauc, droi) ' Quick sort
  Dim ref
  Dim g
  Dim d
  Dim temp
  ref = clé((gauc + droi) \ 2)
  g = gauc: d = droi
  Do
    Do While clé(g) < ref: g = g + 1: Loop
    Do While ref < clé(d): d = d - 1: Loop
    If g <= d Then
      temp = clé(g): clé(g) = clé(d): clé(d) = temp
      temp = index(g): index(g) = index(d): index(d) = temp
      g = g + 1: d = d - 1
    End If
  Loop While g <= d
  If g < droi Then Call Tri(clé, index, g, droi)
  If gauc < d Then Call Tri(clé, index, gauc, d)
End Sub

J'ai rien dit...

J'avais mal placé mon code...

MErci encore pour l'aide

[Chris171717]

Bonjour,

alors je reviens vous voir car j'ai de nouveau un souci avec ce code...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
Private Sub CommandButton3_Click()
  Dim Plage As Range, Est, Add As String, vLi As Integer, Vcol As Byte
  Dim i As Integer
  Dim temp
  Dim Ok As Boolean
 
  With ListBox1
    .Clear
    .ColumnCount = 6
    .ColumnWidths = "120;90;20;255;80;60"
    Set Plage = Range("H2:H" & [H65000].End(xlUp).Row)
    Set Est = Plage.Find(False)
    If Not Est Is Nothing Then
      Add = Est.Address
      Do
        .AddItem Cells(Est.Row, 1)
        For Vcol = 2 To 6
          .List(vLi, Vcol - 1) = Cells(Est.Row, Vcol)
        Next
        vLi = vLi + 1
        Set Est = Plage.FindNext(Est)
      Loop While Not Est Is Nothing And Est.Address <> Add
    End If
    TextBox1 = .ListCount
  End With
 
 
'pour trier l'affichage
 Dim Lig
 Dim Col
 Dim clé() As String, index() As Long, a(), b()
 a = Me.ListBox1.List
 ReDim b(LBound(a) To UBound(a), LBound(a, 2) To UBound(a, 2))
 ReDim clé(LBound(a) To UBound(a, 1))
 ReDim index(LBound(a) To UBound(a, 1))
 For i = LBound(a) To UBound(a, 1)
    clé(i) = a(i, 0) & a(i, 1): index(i) = i
  Next i
  Call Tri(clé(), index(), LBound(a), UBound(clé))
  For Lig = LBound(clé) To UBound(clé)
     For Col = LBound(a, 2) To UBound(a, 2): b(Lig, Col) = a(index(Lig), Col): Next Col
  Next Lig
  Me.ListBox1.List = b
 
  End Sub
 
 
Sub Tri(clé() As String, index() As Long, gauc, droi) ' Quick sort
  Dim ref
  Dim g
  Dim d
  Dim temp
  ref = clé((gauc + droi) \ 2)
  g = gauc: d = droi
  Do
    Do While clé(g) < ref: g = g + 1: Loop
    Do While ref < clé(d): d = d - 1: Loop
    If g <= d Then
      temp = clé(g): clé(g) = clé(d): clé(d) = temp
      temp = index(g): index(g) = index(d): index(d) = temp
      g = g + 1: d = d - 1
    End If
  Loop While g <= d
  If g < droi Then Call Tri(clé, index, g, droi)
  If gauc < d Then Call Tri(clé, index, gauc, d)
End Sub

Avec ce code je tri donc dans ma listbox, mais ça ne tri que par le nom et pas par le prénom...

Auriez-vous une idée !?

[Chris171717]

un petit Up pour savoir si vous avez une idée pour mon souci ci-dessus...