Discussion :

[eglantine217]

Bonjour,

Je travaille actuellement sur l'automatisation d'un graphique.
Ci-dessous les données et le code
les données de A1 à F2

A	B	C	D	E	F
Semaine	1	2	3	4	5
nbr	0	10	4	6	9

tous les mois je remplie ma colonne F1 et F2 le mois suivant G1 et G2 et je souhaiterais que mon code tienne compte de cette dernière colonne remplie.
(qd c'est la ligne qui varie je sais le faire : end(xlup) ... mais qd c'est la colonne qui s'incrémente je suis perdue

merci de votre aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub graphique()
 
Application.ScreenUpdating = False
 
ThisWorkbook.Sheets("Feuil1").Range("A1:F2").Copy
 
'créer un nouveau classeur et y coller les données
Set nouv = Workbooks.Add
Set pg = nouv.Sheets(1)
pg.Paste
pg.Cells(1).PasteSpecial Paste:=xlValues
 
'tracer le graphique
Set gr = nouv.Charts.Add
With gr
.SetSourceData Source:=Sheets("Feuil1").Range("A2:F2"), PlotBy:=xlRows
 
'.ChartType = xlLine
.Location Where:=xlLocationAsNewSheet
.Axes(xlCategory, xlPrimary).HasTitle = True
.Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "semaines"
.Axes(xlValue, xlPrimary).HasTitle = True
.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "nombre"
 End With
Application.ScreenUpdating = True
Set pg = Nothing
Set gr = Nothing
Set nouv = Nothing
End Sub

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Graphique()
Dim Nouv As Workbook
Dim Pg As Worksheet
Dim NbC As Integer
 
Application.ScreenUpdating = False
With ThisWorkbook.Worksheets("Feuil1")
    NbC = .Cells(2, .Columns.Count).End(xlToLeft).Column
    Set Nouv = Workbooks.Add(1)
    Set Pg = Nouv.Worksheets(1)
    Pg.Range("A1").Resize(2, NbC).Value = .Range("A1").Resize(2, NbC).Value
End With
 
'tracer le graphique
With Nouv.Charts.Add
    .ChartType = xlXYScatterLines
    .SetSourceData Source:=Pg.Range("A1").Resize(2, NbC), PlotBy:=xlRows
    With .Axes(xlCategory, xlPrimary)
        .HasTitle = True
        .AxisTitle.Characters.Text = "Semaines"
    End With
    With .Axes(xlValue, xlPrimary)
        .HasTitle = True
        .AxisTitle.Characters.Text = "Nombre"
    End With
End With
Application.DisplayAlerts = False
Nouv.SaveAs ThisWorkbook.Path & "/Graphique_Semaine_" & Format(Pg.Cells(1, NbC), "00"), FileFormat:=xlNormal
Application.DisplayAlerts = True
Nouv.Close
Set Pg = Nothing
Set Nouv = Nothing
End Sub