Discussion :

[2lester]

Bonjour à tous,

J'utilise le script suivant (merci Northben) associé à une règle Outlook pour sauvegarder automatiquement sur mon disque des pièces jointes .zip reçues par mail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
 
saveFolder = "C:\Users\..."
 
    For Each objAtt In itm.Attachments
 
    If Right(objAtt.FileName, 3) = "zip" Then
 
    objAtt.SaveAsFile saveFolder & "\" & objAtt.DisplayName
    Set objAtt = Nothing
 
    End If
 
    Next
 
End Sub

Mais je souhaite que les pièces jointes soient sauvegardées dézippées.
Quelles commande dois-je ajouter à mon code ci-dessus pour ce faire ?

Merci par avance pour votre aide.

[Oliv-]

http://www.developpez.net/forums/d12...ieces-jointes/

[2lester]

Bonjour Oliv,

Merci pour ton post. J'avais vu en effet cette réponse que tu as faite à Benoît sur le sujet mais je ne veux pas avoir à télécharger quoi que ce soit pour faire fonctionner ma macro, car si j'ai bien compris dans la soluce que tu donnes c'est le cas...? (ceci dit j'aurais sans doute pu repartir de cette discussion avec Benoît pour exposer mon problème ;-)

Moi ce que je voudrais c'est récupérer en macro ce que fait manuellement le clic droit sur un zip / Extraire tout...

Est-ce possible ?

Merci pour ton aide

[Oliv-]

Voici un code de Ron de Bruin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub Unzip1()
    Dim FSO As Object
    Dim oApp As Object
    Dim Fname As Variant
    Dim FileNameFolder As Variant
    Dim DefPath As String
    Dim strDate As String
 
    Fname = Application.GetOpenFilename(filefilter:="Zip Files (*.zip), *.zip", _
                                        MultiSelect:=False)
    If Fname = False Then
        'Do nothing
    Else
        'Root folder for the new folder.
        'You can also use DefPath = "C:\Users\Ron\test\"
        DefPath = Application.DefaultFilePath
        If Right(DefPath, 1) <> "\" Then
            DefPath = DefPath & "\"
        End If
 
        'Create the folder name
        strDate = Format(Now, " dd-mm-yy h-mm-ss")
        FileNameFolder = DefPath & "MyUnzipFolder " & strDate & "\"
 
        'Make the normal folder in DefPath
        MkDir FileNameFolder
 
        'Extract the files into the newly created folder
        Set oApp = CreateObject("Shell.Application")
 
        oApp.Namespace(FileNameFolder).CopyHere oApp.Namespace(Fname).items
 
        'If you want to extract only one file you can use this:
        'oApp.Namespace(FileNameFolder).CopyHere _
         'oApp.Namespace(Fname).items.Item("test.txt")
 
        MsgBox "You find the files here: " & FileNameFolder
 
        On Error Resume Next
        Set FSO = CreateObject("scripting.filesystemobject")
        FSO.deletefolder Environ("Temp") & "\Temporary Directory*", True
    End If
End Sub