Discussion :

[juju05]

Je souhaite convertir l'ensemble des commentaires des cellules d'un colonne dans
une cellule de chaque ligne.

Est-ce réalisable par une fonction excel ou faut-il réaliser une macro. ?

Merci d'avance.

Julien.

[Theze]

Bonjour,

Avec formule je ne sais pas mais avec macro, à adapter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub Commentaire()
 
    Dim Plage As Range
    Dim Cel As Range
 
    'défini la plage en feuille "Feuil1" sur la colonne A, de A1 à A?
    With Worksheets("Feuil1")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'boucle
    For Each Cel In Plage
 
        'gère l'erreur de commentaire absent
        On Error Resume Next
        Cel.Offset(0, 1) = Cel.Comment.Shape.TextFrame.Characters.Text
 
    Next Cel
 
End Sub

Hervé.

[mercatog]

Par macro (à adapter) on transcrit les éventuels commentaires de la colonne B en colonne E

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test()
Dim c As Range
 
On Error Resume Next
For Each c In Worksheets("Feuil1").Range("B:B").SpecialCells(xlCellTypeComments)
    c.Offset(0, 3).Value = c.Comment.Text
Next c
On Error GoTo 0
End Sub

[Excel_man]

Bonjour,
J'ai eu le même besoin et j'avais adapté il y a quelque temps une formule glanée sur un forum (c'est pas de mon niveau ) merci a celle ou celui qui l'as écrite.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Function RecupCommentaire(c)
' Récupère dans la cellule le commentaire de la cellule c
 
   Application.Volatile
   If c.Comment Is Nothing Then
     RecupCommentaire = ""
   Else
     RecupCommentaire = Replace(c.Comment.Text, Chr(10), " ")
   End If
End Function

L'avantage, par rapport aux autres propositions, c'est que c'est une fonction que tu vas pouvoir utiliser ensuite comme tu veux dans tes cellules. (c) étant l'adresse de la cellule ou tu veux récupérer le commentaire.

[juju05]

Merci beaucoup, j'ai utilisé la réponse de excelman.