Discussion :

[Dreamz87]

Bonjour à tous !

Voilà je fais appel à vous car je n'arrive pas à cerner d'où vient mon problème étant donné que Visual Basic ne me retourne aucune erreur. Voici l'image :



Voici le contexte : Je sélectionne une formation dans la liste déroulante du haut, qui me retourne le libellé, la date de début/fin ainsi que la liste des salarié ayant demandé cette formation dans la zone de liste à gauche.
Le bouton au milieu doit me permettre de créer un enregistrement dans une table appelée "SUIVRE" à condition que l'avis du supérieur (AvisSuper dans la table "DEMANDER") soit favorable "F". S'il est défavorable "D" on affiche un message pour dire que l'inscription est impossible.
Je cherche a coder ce bouton permettant l'ajout de l'enregistrement, sauf que quand je clique dessus, je n'ai aucune erreur retournée de la part de Visual Basic, mais aucun résultat voulu non plus ! Voici le code du bouton :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Commande12_Click()
Dim bdFormation As Database
Dim rsSuivre As Recordset
Dim requete As String
Set bdFormation = CurrentDb()
requete = "select CodeSala, CodeForm, AvisSuper from DEMANDER where CodeSala ='" & ListeDemandeur & "'" & " AND CodeForm ='" & Modifiable0 & "'"
Set rsSuivre = bdFormation.OpenRecordset(requete, DB_OPEN_DYNASET)
If AvisSuper = "D" Then
MsgBox ("Avis défavorable ... inscription impossible !!!")
End If
If AvisSuper = "F" Then
Set rsSuivre = bdFormation.OpenRecordset("SUIVRE", DB_OPEN_DYNASET)
rsSuivre.AddNew
rsSuivre!CodeSala = ListeDemandeur
rsSuivre!CodeForm = Modifiable0
rsSuivre.Update
MsgBox ("Participation acceptée !")
End If
End Sub

Sauriez vous d'où vient le problème ? D'avance merci pour votre aide !

[tee_grandbois]

Bonsoir,
tu dois utiliser le champ du resordset pour faire ton test : If AvisSuper = "F" ne te ramènera rien car la variable AvisSuper n'existe pas, il faut préfixer avec le nom du recordset : nomdurecordset!champ ou nomdurecordset("champ") ...
De plus, il est préférable de ne pas être avare de déclaration des recordsets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Commande12_Click()
Dim bdFormation As Database
Dim rsDemander As Recordset
Dim rsSuivre As Recordset
Dim requete As String
Set bdFormation = CurrentDb()
requete = "select CodeSala, CodeForm, AvisSuper from DEMANDER where CodeSala ='" & Me.ListeDemandeur & "'" & " AND CodeForm ='" & Me.Modifiable0 & "'"
 
Set rsDemander = bdFormation.OpenRecordset(requete, dbOpenSnapshot)
 
If Not rsDemander.EOF Then
    If rsDemander!AvisSuper = "D" Then
        rsDemander.Close
        Set rsDemander = Nothing
        MsgBox ("Avis défavorable ... inscription impossible !!!")
        Exit Sub
    End If
 
    If rsDemander!AvisSuper = "F" Then
        Set rsSuivre = bdFormation.OpenRecordset("SUIVRE", dbOpenDynaset)
        rsSuivre.AddNew
        rsSuivre!CodeSala = Me.ListeDemandeur
        rsSuivre!CodeForm = Me.Modifiable0
        rsSuivre.Update
        rsSuivre.Close
        Set rsSuivre = Nothing
        MsgBox ("Participation acceptée !")
    End If
End If    
    rsDemander.Close
    Set rsDemander = Nothing
End Sub

[Dreamz87]

Merci pour votre réponse, le code marche à merveille !
Seulement... J'aimerais bien comprendre un peu plus les modifications que vous y avez apporté avec le rsDemander.nothing, If Not rsDemander.EOF etc...
Car je ne l'ai pas vu en cours, donc j'arrive pas trop à comprendre

[tee_grandbois]

Bonjour,
le mot clé Nothing est utilisé à la fin du code pour désallouer la mémoire affectée à une variable objet :
rsDemander est une variable objet de type Recordset à laquelle, par la méthode OpenRecordset, tu affectes la valeur requete qui elle-même est une variable de type String et qui contient un phrase SQL.

On utilise la propriété EOF du recordset pour savoir s'il y a des enregistrements lors d'une lecture en boucle, mais on pourrait utiliser aussi BOF ou RecordCount s'il n'y a pas de boucle, comme dans ton cas. Cela permet d'éviter les messages d'erreur en particulier le 3021 (Aucun enregistrement en cours) et de conditionner l'exécution du code suivant selon la présence ou non de l'enregistrement.

Un conseil si tu ne comprends pas quelque chose dans VBA : avoir le réflexe gagnant d'appuyer sur la touche (après avoir surligné le mot-clé avec la souris).
Je l'utilise encore même 17 ans après avoir utilisé Access pour la première fois.

[Dreamz87]

Merci bien pour toutes ces explications très utiles ! C'est agréable de trouver un forum avec des personnes comme vous !

Oui le réflexe du F1 je l'ai déjà ne vous en faites pas ! Mais bon, même avec l'aide, je ne m'en sors pas toujours

En tout cas merci pour vos réponses aussi rapides et claires ! Je passe le sujet en résolu !