Discussion :

[billyjak]

Bonjour à tous et merci d'avance à ceux qui prendront un peu de temps pour se pencher sur mon sujet.

Sans grandes connaissances en Macro, j'ai essayé d'appliquer les macros d'un modèle trouvé sur le formum (testFiltreDynamique en PJ) au doc (AVData), sans succès, bien que j'ai pris soins de redéfinir les plages "critères", "extraire" et "rooming" en faisant Ctrl F3... La macro de rafraichissement automatique à l'ouverture semble fonctionner mais il y a une erreur dans l'application de la seconde macro...
L'effet recherché est que les feuilles "commande 1" et "commande 2" soient rafraichies lorsqu'on les affiche pour que le tableau du haut se renseigne en utilisant les infos du tableau "rooming" (nom, prénom, adress...), en respectant le critère "GP".
Ainsi, dans la commande 1, on devrait retrouver les 3 lignes correspondantes au critère GP=1, et dans la commande 2 la ligne répondant au critère GP=2...

Si quelqu'un peut m'aider... grand merci!

[Daniel.C]

Bonjour,

Mets cette macro dans le module "ThisWorkbook" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Dim Plage As Range, GP As Integer
    If Sh.Name = "Commande 1" Then
        GP = 1
    ElseIf Sh.Name = "Commande 2" Then
        GP = 2
    Else
        Exit Sub
    End If
    With Sheets("Rooming")
        .AutoFilterMode = False
        Set Plage = .Range(.[A8], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 19)
        Plage.AutoFilter 1, GP
        Set Plage = Plage.Resize(Plage.Rows.Count - 1).Offset(1, 1)
        If Application.Subtotal(103, Plage) > 0 Then
            With Sh
                Set Plage = Plage.SpecialCells(xlCellTypeVisible)
                Plage.Columns(1).Copy Sh.[A5]
                Plage.Columns(2).Copy Sh.[B5]
                Plage.Columns(4).Copy Sh.[C5]
                Plage.Columns(13).Copy Sh.[D5]
                Plage.Columns(16).Copy Sh.[E5]
                Plage.Columns(17).Copy Sh.[F5]
                Plage.Columns(18).Copy Sh.[G5]
            End With
        End If
    End With
End Sub