Discussion :

[Liloo14]

Bonjour,
Voilà, j'ai une feuille excel avec des données dans la colonne J sur 10000 lignes. J'aimerais trouver comment faire pour que chaque cellule de la colonne J soit testée de manière à savoir si elle comporte des données numérique ou non et que en fonction de celà la cellule correspondante de la colonne K soit incrémentée d'un 1 si c'est vrai et d'un zéro si c'est faux.
J'ai essayé avec IsNumérique mais je ne pige pas comment l'intégrer dans une boucle.
Quelqu'un aurait-il une idée?
Merci par avance

[Theze]

Bonjour,

Teste ce qui suit mais choisi pour incrémenter la valeur en cellule K ou alors, juste 1 ou 0 en cellule K. Vire la ligne que tu ne veux pas utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Sub Numerique()
 
    Dim plage As Range
    Dim Cel As Range
 
    With Worksheets("Feuil1")
 
        'en colonne J
        Set plage = .Range(.Cells(1, 10), .Cells(.Rows.Count, 10).End(xlUp))
 
    End With
 
    For Each Cel In plage
 
        'sans incrémentation (1 ou 0)
        If IsNumeric(Cel) Then Cel.Offset(0, 1) = 1 Else Cel.Offset(0, 1) = 0
 
        'avec incrémentation
        If IsNumeric(Cel) Then Cel.Offset(0, 1) = Cel.Offset(0, 1) + 1
 
    Next Cel
 
End Sub

Hervé.

[Philippe Tulliez]

Bonjour,
Une autre proposition tenant compte que si la cellule contient une valeur logique telle que VRAI ou FAUX isNumeric renvoie TRUE
Exemple à adapter : Incrémentation de 1 des cellules de la colonne B si la cellule de la même ligne en colonne A est de type numérique. (Test sur 9 lignes)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub IncrementationNumeric()
 Dim row As Long
 Dim cell As Range
 For row = 2 To 9
  Set cell = Cells(row, 1)
  cell.Offset(0, 1) = cell.Offset(0, 1) + Abs((IsNumeric(cell) = True And (VarType(cell) <> vbBoolean)))
 Next
End Sub

[EDIT]
Une autre solution avec Select Case et un exemple avec incrémentation de 1 ou Addition de la valeur de la colonne A

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub IncrementationValeur()
 Dim row As Long
 Dim cell As Range
 For row = 2 To 9
  Set cell = Cells(row, 1)
  With cell
  Select Case True
    Case IsNumeric(.Value) = True And (VarType(.Value) <> vbBoolean)
     '.Offset(0, 1) = .Offset(0, 1) + 1   ' Incrémentation de 1
     .Offset(0, 1) = .Offset(0, 1) + .Value ' Addition du contenu de la colonne A
  End Select
  End With
 Next
End Sub

[Liloo14]

Merci à tout les deux?
Ca marche impec et en plus j'ai compris comment -))
Bonne continuation
Laurent