Discussion :

[Pierre67]

Bonjour

en exportant d'une application des données au format excel, j'obtiens dans une colonne des données sous le format suivant :

D260, Sens positif, Au PR 2+415/ / Wasselonne

ces données en l'état sont inexploitables, je souhaite scinder (en vba) des données dans plusieurs cellules mais je me heurte à un problème d'utilisation des fonctions textes.
je souhaite obtenir dans plusieurs colonnes
D260
Sens positif
au PR ...
Wasselonne

qui pourrait m'aiguiller vers une solution
merci
cordialement

[pc75]

Bonjour,

La fonction Split() devrait pouvoir t'aider.

[Supermichou]

Bonjour,

peut être pas besoin de vba sur ce genre de manip.

selection la colonne, fait données/convertir/déliminté

coche par virgule et autre "/"

Michel

[kiki29]

Salut, voir Utiliser les fonctions Excel ainsi que Manipuler les chaînes de caractères en VB6 et VBA Excel

[Theze]

Bonjour,

Teste ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Sub Decouper()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tablo
    Dim I As Integer
 
    'adapter le nom de la feuille
    With Worksheets("Feuil1")
 
        'ici, les valeurs brutes en colonne A
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    For Each Cel In Plage
 
        'remplace les "/ /" par des virgule afin de pouvoir
        'Decouper la chaîne entière
        Cel = Replace(Cel, "/ /", ",")
 
        'Decoupe la chaîne dans un tableau
        Tablo = Split(Cel, ",")
 
        For I = 0 To UBound(Tablo)
 
            'puis distribue dans les cellules voisines
            Cel.Offset(0, I + 1) = Trim(Tablo(I))
 
        Next I
 
    Next Cel
 
End Sub

Hervé.

[Pierre67]

Merci à Thèze,

ce que je recherchais, délai de réponse quais immédiat
reflet de la qualité de ce forum

ça fonctionne comme je le souhaitais

merci encore à tous et en particulier à Theze
@+ pour un autre pb :