Discussion :

[FCL31]

Bonjour à tous

Grace au tuto de Heureux-oli j'ai créer le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub CmdMarge_Click()
Dim rs As Recordset
Dim db As Database
Dim SQL As String
Dim aWapp As Word.Application
Dim chemin As String
 
chemin = "D:\Company Shared Folders\Secure BD"
Set wApp = New Word.Application
wApp.Visible = True
wApp.Documents.Add Template:=chemin & "\Fax.dot", NewTemplate:=False, DocumentType:=0
 
SQL = "SELECT * FROM Rq_Secure WHERE Réf_Sinistre=" & Chr(34) & Me.Réf_Sinistre & Chr(34) & "AND Ville=" & Chr(34) & Me.Ville & Chr(34)
 
Set db = CurrentDb
Set rs = db.OpenRecordset(SQL)
 
While Not rs.EOF
    With wApp
        .ActiveDocument.Bookmarks("Sinistre").Range.Text = rs.Fields("Réf_Sinistre")
        .ActiveDocument.Bookmarks("Contrat").Range.Text = rs.Fields("n°Police")
        .ActiveDocument.Bookmarks("Conces").Range.Text = rs.Fields("Conces_Concessionnaire")
        .ActiveDocument.Bookmarks("Fax").Range.Text = rs.Fields("Fax")
        .ActiveDocument.Bookmarks("Nom").Range.Text = rs.Fields("Nom")
        .ActiveDocument.Bookmarks("Client").Range.Text = rs.Fields("Client_Utilisateur")
        .ActiveDocument.Bookmarks("Type").Range.Text = rs.Fields("Type_Machine")
        .ActiveDocument.Bookmarks("Modele").Range.Text = rs.Fields("Désignation")
        .ActiveDocument.Bookmarks("Serie").Range.Text = rs.Fields("N°_de_série")
        .ActiveDocument.Bookmarks("Date_Appel").Range.Text = rs.Fields("Date_appel_en_GTI")
        .ActiveDocument.Bookmarks("Nom_2").Range.Text = rs.Fields("Nom")
    End With
    rs.MoveNext
Wend
 
Set rs = Nothing
Set db = Nothing
 
End Sub

Ce code marche

En fait mon fax (Fax.dot) est un fax type :
Ma BDD renseigne une partie du courrier : Destinataire, n° fax; Objet, ...

Toutefois, il manque le contenu même du fax.
Pour mettre ce contenu, une fois dans mon fichier Word, j’insère un autre fichier Word au milieu du doc pour compléter mon fax.

Je suppose que vous voyez la question arriver qui est:
Comment depuis Access, à l'aide d'une éventuelle lite déroulante, je peut insérer un fichier Word dans mon fichier Word Fax.dot ?

Je sais pas si j'ai été clair mais si quelqu'un a compris, merci d'avance de votre aide.

PS : dans mon code, si il me manque une donnée dans ma BDD pour un Signet, j'ai une erreur (normal).
Comment puis-je éviter cette erreur ?

Bonne journée

[loufab]

Bonjour,
haaa l'automation... on est un peu perdu !

Bref ! C'est du code VBA Word.
Donc il te faut poster dans VBA Word.

Cordialement,

[Heureux-oli]

Salut,

La première étape est l'insertion d'un champ IncludeText qui recevra le chemin du fichier.

Pour le chemin du fichier, il te suffit d'avoir un déroulant avec les choix que tu souhaites.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

activedocument.Fields.Add Range:=Selection.Range, type:=wdFieldIncludeText, text:="C:\\temp\\a.doc"

[FCL31]

Bonjour

Merci de votre réponse

A force de chercher, j'ai trouver ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Wapp.Selection.InsertFile _
                         Filename:="D:\Company Shared Folders\Secure BD\Bloc_Courrier_Fax\" & Me.Modifiable6.Column(1), _
                         Range:="", _
                         ConfirmConversions:=False, _
                         Link:=False, _
                         Attachment:=False

que j'ai rajouté à la fin du code de j'ai posté sur mon premier post (juste après le wend) dans ACCESS.


J'ai aussi ajouté

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Document_New()
Selection.GoTo What:=wdGoToBookmark, Name:="Bloc"
End Sub

dans mon fichier WORD

Et on dirait que sa veu bien marcher

J'ai pas essayé ton code Heureux-oli mais maintenant que j'en ai deux, lequel est le mieux ???

Mais j'ai toujours mon problème qui est que si dans ma BDD ACCESS, le renseignement d'un Signet WORD est manquant, sa plante.
Comment puis-je résoudre se problème ??

J'ai un autre problème sur le même doc WORD mais je vais créer un nouveau sujet.

Merci de votre aide

A+

[Heureux-oli]

Salut,

Mais j'ai toujours mon problème qui est que si dans ma BDD ACCESS, le renseignement d'un Signet WORD est manquant, sa plante.
Comment puis-je résoudre se problème ??

En ajoutant le signet manquant.

[FCL31]

Sur WORD le signet est présent mais c'est sur ACCESS qu'il est possible que le champ d'un des signet est nul

Par exemple, dans mon code du premier post, on a

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

        .ActiveDocument.Bookmarks("Type").Range.Text = rs.Fields("Type_Machine")

-Type = le nom du signet dans WORD
-Type_Machine = Nom de champ de la requête où se trouve les données dans ACCESS
Si dans l'enregistrement utilisé sur le moment, il n'y a pas de Type_Machine renseigné dans ACCESS, sa plante.

Il faudrait un truc du style que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If IsNull(rs.Fields("Type_Machine")) then
.ActiveDocument.Bookmarks("Type").Range.Text = ""
End If

Mais il faudrait le faire pour chaqu'un des signets (sans être sur que ce code soit bon).

Je pense qu'il doit y avoir un moyen plus simple pour le faire.

[Heureux-oli]

Salut,

Peut-être avec Nz() ?

[FCL31]

Bonjour Heureux-oli

Voici le code que j'ai fais avec Nz()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
While Not rs.EOF
    With Wapp
        .ActiveDocument.Bookmarks("Sinistre").Range.Text = Nz(rs.Fields("Réf_Sinistre"), " ")
        .ActiveDocument.Bookmarks("Contrat").Range.Text = Nz(rs.Fields("n°Police"), " ")
        .ActiveDocument.Bookmarks("Conces").Range.Text = Nz(rs.Fields("Conces_Concessionnaire"), " ")
        .ActiveDocument.Bookmarks("Fax").Range.Text = Nz(rs.Fields("Fax"), " ")
        .ActiveDocument.Bookmarks("Nom").Range.Text = Nz(rs.Fields("Nom"), " ")
        .ActiveDocument.Bookmarks("Client").Range.Text = Nz(rs.Fields("Client_Utilisateur"), " ")
        .ActiveDocument.Bookmarks("Type").Range.Text = Nz(rs.Fields("Type_Machine"), " ")
        .ActiveDocument.Bookmarks("Modele").Range.Text = Nz(rs.Fields("Désignation"), " ")
        .ActiveDocument.Bookmarks("Serie").Range.Text = Nz(rs.Fields("N°_de_série"), " ")
        .ActiveDocument.Bookmarks("Date_Appel").Range.Text = Nz(rs.Fields("Date_appel_en_GTI"), " ")
        .ActiveDocument.Bookmarks("Nom_2").Range.Text = Nz(rs.Fields("Nom"), " ")
        .ActiveDocument.Bookmarks("Interv").Range.Text = Nz(rs.Fields("Interventiuon"), " ")
    End With
    rs.MoveNext
Wend

Je sais pas si c'est vraiment se que tu voulais que je face (je n'ais jamais utililser Nz() avant) mais pour le moment, j'ai pas eu de plantage.

Tu peu me confirmer si le code est bon STP.

Merci pour ton aide

[Heureux-oli]

Salut,

L'intellisense te donne la syntaxe, si tu la respecte, c'estbon et comme tu n'as pas d'erreur, je pense que ça devrait le faire.

[FCL31]

Beaucoup

Je jamais je rencontre un problème, je te recontacte

Merci
A+