Discussion :

[mohammedmay]

Bonjour
Je suis nul en macro excel
je bloque sur une macro que je voudrait rendre plus souple
a la base elle verfie que la valeur n+1 est inferieur ou egale a la valeur n
on meme temp elle me donne la date de la valeur initial pour chaque serie .
Se que je voudrait qu'elle accepte ces que cette condition peut ne pas etre verfier pour n+1 ou n+2 mais quelle verifie pour n+3
on meme temp que la macro me donne la date de debut et la date de fin de la serie .
j'espere que j'ai ete explicite .
merci d'avance.

J'ai oublier d'ajouter le fichier avec la macro
Pièce jointe 99098

[mercatog]

Bonjour et bienvenu au forum
Malheureusement ni l'explication, ni le style utilisé n'est compréhensible.

Essaies de reformuler ta question en un français clair par rapport à ton fichier

[mohammedmay]

Excuser mon langage approximatif
Voici la macro comment elle calcul
V (i) =>V (i+1) on stock v (i) dans une nouvelle colonne

Chaque fois que ces vérifier elle stocke le V i ça me donne des séries de donner à partir d’une série total avec pour chaque nouvelle série la date de départ.

Maintenant je veux que si la condition V i=>V i+1 ne soit pas vérifiée elle vérifie encore pour i+2 et i+3

Donc sa consiste a vérifier

Si V (i) => V ( i+1) si non
Si V (i+1) => V( i+2) si non
Si V (i+2) => V( i+3) si non on arête

On plus je voudrais qu’elle me donne
La date Pour de la valeur initial donc i=1 et la date final pour i =n


merci d'avance encore une fois

[mercatog]

C'est toujours pas clair, néanmoins, regarde ce premier code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Test()
Dim LastLig As Long, i As Long, j As Long, n As Long
Dim Tb, Res()
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("A1:B" & LastLig)
 
    Do
        i = i + 1
        If Tb(i, 2) >= Tb(i + 1, 2) Then
            j = j + 1
            n = 0
            ReDim Preserve Res(1 To 2, 1 To j)
            Res(1, j) = Tb(i, 1)
            Res(2, j) = Tb(i, 2)
        Else
            n = n + 1
        End If
    Loop While i < LastLig - 1 And n < 3
 
    .Range("E1").Resize(j, 2) = Application.Transpose(Res)
End With
End Sub

[mohammedmay]

Merci pour le code je les utiliser mais il ne créer que une seule série
ma macro transforme les colonne source en une série de colonne
cordialement

Le problème ces que le code n'ecremente pas il s'arete a la 1er serie
alors que je devrait avoir une serie de colone dans les valeur sont decroissante
merci encore

[mercatog]

Une question mal formulée recevra des réponses hasardeuses.
Je continu dans la devinette, ci-après autre code.

Attention à la limité d'Excel 2003 (maximum 256 colonnes)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub Test()
Dim LastLig As Long, i As Long, j As Long, n As Long
Dim Fin As Boolean
Dim Tb, Res()
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("A1:B" & LastLig)
    Do
        i = i + 1
        If Tb(i, 2) >= Tb(i + 1, 2) Then
            j = j + 1
            ReDim Preserve Res(1 To 2, 1 To j)
            Res(1, j) = Tb(i, 1)
            Res(2, j) = Tb(i, 2)
            Fin = False
        Else
            Fin = True
        End If
        If Fin And j >= 3 Then
            .Range("E1").Offset(0, n).Resize(j, 2) = Application.Transpose(Res)
            j = 0
            n = n + 2
            ReDim Res(1 To 2, 1 To 1)
        End If
    Loop While i < LastLig - 1 And n < 251         'la condition sur n pour ne pas dépasser 256 colonnes disponible sur excel 2003 vu le grand nombre de données
 
End With
End Sub

[mohammedmay]

Merci pour ton indulgence
Mais toujours est-il que la macro s’arrête a n+1 alors que je voudrait que elle s'arrête a n+3
Si la condition n'est pas vérifier pour le premier rang on la vérifie quand même pour le deuxième et si non pour troisième.

si V (n) < V (n+1)
alors on vérifie que V (n+1) => V (n+2) si non
on vérifie que V (n+2) => V (n+3)

Merci d'avance

[mercatog]

Tu peux mettre sur ton fichier le résultat escompté?

[mohammedmay]

Voici le fichier avec les resultats atendu, les celule en rouge ces se qui va devoire changer par rapport au code que vous mavait envoyer .
sa voudrait dire que sa remonte mais pas trop .
Merci pour l'efort que vous faite.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Test3()
Dim LastLig As Long, i As Long, j As Long, n As Long
Dim Fin As Boolean
Dim Tb, Res()
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("A1:B" & LastLig)
    .Range("E1").CurrentRegion.Clear
    Do
        i = i + 1
        Fin = False
        If Tb(i, 2) < Tb(i + 1, 2) And Tb(i, 2) < Tb(i + 2, 2) And Tb(i, 2) < Tb(i + 3, 2) Then Fin = True
        If Not Fin Then
            j = j + 1
            ReDim Preserve Res(1 To 2, 1 To j)
            Res(1, j) = Tb(i, 1)
            Res(2, j) = Tb(i, 2)
        Else
            If j > 0 Then
                .Range("E1").Offset(0, n).Resize(j, 2) = Application.Transpose(Res)
                j = 0
                n = n + 2
                Erase Res
            End If
        End If
    Loop While i < LastLig - 3 And n < 251       'la condition sur n pour ne pas dépasser 256 colonnes disponible sur excel 2003 vu le grand nombre de données
 
End With
End Sub

[mohammedmay]

Je te remercie pour la macro voici comment j'ai changer juste un petite critere
maintenat j'ai un probleme elle afiche comme valeur de depart des valeur inferieure a celle d'apres
je te renvois le fichier avec ta macro dedans les celule en rouge ne devrait pas etre stocker (ou aparaitre).
merci pour ton aide.

Le fichier na pas ete charger trop d'espace

[mercatog]

Et tu sais pourquoi tu as changé la condition?
Le code tel que donné ne répond pas à la demande conformément à ton fichier exemple initial?

Ce que j'avais compris c'est d'extraire les sous séries qui répondent à 2 critères:
1. Séries décroissantes
2. Tolérer un maximum 3 points singuliers successifs (où la série n'est pas décroissante)

[mohammedmay]

Ces se que je demande mais il me donne des valeur initial qui ne sont pas le maximum de la serie

Voici le fichier avec les résultats de la macro les cellule en rouge sont plus grande que se qui devait être prévue
Rq: Pourquoi la macro ma changer le format de date en assayant de le changer il remet le même format .
merci pour ton aide .
cordialement .

[mercatog]

Tu as les séries suivantes (3ème série par exemple)
1.79 1.8 1.8 1.79 1.79 1.78 1.78 1.78 c'est normal, les 1.8 sont considérés comme des points singuliers.

Pour gérer le problème des dates

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Test4()
Dim LastLig As Long, i As Long, j As Long, n As Long
Dim Fin As Boolean
Dim Tb, Res()
 
Application.ScreenUpdating = False
With ThisWorkbook.Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("A2:B" & LastLig)
    .Range("E1").CurrentRegion.Clear
    Do
        i = i + 1
        Fin = False
        If Tb(i, 2) < Tb(i + 1, 2) And Tb(i, 2) < Tb(i + 2, 2) And Tb(i, 2) < Tb(i + 3, 2) Then Fin = True
        If Not Fin Then
            j = j + 1
            ReDim Preserve Res(1 To 2, 1 To j)
            Res(1, j) = CDbl(Tb(i, 1))
            Res(2, j) = Tb(i, 2)
        Else
            If j > 0 Then
                With .Range("E1").Offset(0, n)
                    .Resize(j, 2) = Application.Transpose(Res)
                    .Resize(j, 1).NumberFormat = "dd/mm/yyyy hh:mm"
                End With
                j = 0
                n = n + 2
                Erase Res
            End If
        End If
    Loop While i < LastLig - 4 And n < 251         'la condition sur n pour ne pas dépasser 256 colonnes disponible sur excel 2003 vu le grand nombre de données
End With
End Sub

[mohammedmay]

Je vais retirer par un trie les valeur aberrante.je te remercie pour ton aide.
cordialement