VBA excel creation de controle dans une form

**arkhamon** · 25/05/2012, 12h31

Bonjoru à tous,

je sèche lamentablement sur un truc simle : créer un contrôle dans une Form de façon dynamique.
Contexte : une form est ouverte, et si je clique dedans, je veux créer une textbox. J'ai ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub UserForm_Click()
Dim te As TextBox
Set te = Me.Controls.Add("Forms.TextBox", "te")
te.Visible = True
te.Top = 0
te.Left = 0
End Sub

mais ca plante avec le message "Invalid class name". J'ai essayé avec VB.TextBox mais ca plante pareil.
Et les exemples trouvés sur Internet ne m'aident pas, y a soit rien qui marche, soit je pige pas...

Merci pour votre aide.

**kiki29** · 25/05/2012, 12h44

Salut, un exemple pour un calendrier

**arkhamon** · 25/05/2012, 15h03

Salut,

trop complique pour moi, je comprends pas tout. En plus ca semble pas être mon cas, à savoir ajouter un controle de base dans une form. L'exemple ajoute un calendrier (spécifique) dans une feuille et fait je ne sais quoi après avec...

**kiki29** · 25/05/2012, 15h30

Re, Création ex nihilo à adapter à ton contexte
Affecter un bouton à UserForm_Dynamique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
Option Explicit
 
'   Références à cocher
'   Microsoft Visual Basic for Applications Extensibility 5.3
'   Microsoft Forms 2.0 Object Library
 
Sub UserForm_Dynamique()
Dim Usf As Object
Dim Lbl As MSForms.Label
Dim CB As MSForms.CommandButton
Dim sStr As String
Dim i As Long
 
    Set Usf = ThisWorkbook.VBProject.VBComponents.Add(vbext_ct_MSForm)
    With Usf
        .Properties("Caption") = "UserForm Dynamique"
        .Properties("Height") = 240
        .Properties("Width") = 320
    End With
 
    Set CB = Usf.Designer.Controls.Add("forms.CommandButton.1")
    With CB
        .Caption = "Fermer"
        .Left = 200
        .Top = 180
    End With
 
    Set Lbl = Usf.Designer.Controls.Add("forms.Label.1")
    With Lbl
        .Caption = "mon texte"
        .TextAlign = fmTextAlignCenter
        .Left = 20
        .Top = 20
        .BackColor = vbRed
        .BorderStyle = fmBorderStyleSingle
    End With
 
    sStr = "Sub CommandButton1_Click()" & _
         vbCrLf & "Unload Me" & _
         vbCrLf & "End Sub"
 
    With Usf.CodeModule
        i = .CountOfLines
        .InsertLines i + 1, sStr
    End With
 
    sStr = "Sub Label1_Click()" & _
         vbCrLf & "MsgBox " & _
         """Vous avez cliqué sur mon texte""" & _
         vbCrLf & "End Sub"
    With Usf.CodeModule
        i = .CountOfLines
        .InsertLines i + 1, sStr
    End With
 
    VBA.UserForms.Add(Usf.Name).Show
    ThisWorkbook.VBProject.VBComponents.Remove Usf
End Sub

**ctac_** · 25/05/2012, 20h12

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub UserForm_Click()
    Dim te As MSForms.TextBox
    Set te = Me.Controls.Add("Forms.TextBox.1", "te")
    te.Visible = True
    te.Top = 0
    te.Left = 0
End Sub

Cordialement

ctac

**arkhamon** · 29/05/2012, 09h27

Trop classe ctac_ !
Merci beaucoup.
Au fait, dans le code "Forms.TextBox.1", le ".1" c'est pourquoi exactement ? Si j'en crée plusieurs, faut incrémenter ?

Pour la suppression, je suppose qu'il faut utiliser

Code :

Sélectionner tout - Visualiser dans une fenêtre à part