Discussion :

[Oum le dauphin]

Bonjour,
je viens de me mettre au VBA il y'a tout juste une semaine.
J'ai un petit soucis avec les fonction Range et Cells

J'ai crée un code que chercher dans une colonne une valeur,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Sub test()
 
Dim numéro As Double
Dim celluletrouvee As Range
Dim ligne As Integer
Dim col2 As Integer
Dim col As Integer
 
numéro = Sheets("palier").Cells(3, 3)
 
Set celluletrouvee = Sheets("valeur d'étalonnage").Range("AI1:AI500").Find(numéro, lookat:=xlWhole)
 
If celluletrouvee Is Nothing Then
MsgBox ("la valeur indiquées n'ont pas été trouvé dans la liste: indiquer l'instant exact")
Else
ligne = celluletrouvee.Row
col = celluletrouvee.Column
MsgBox ("trouvé : ligne = " & numéro & " , colonne = " & col)
End If

jusque la, ça marche comme je le souhaite.
Mais j'ai besoin de copier une selection vers une autre feuille.
c'est là que j'ai un soucis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
col2 = col + 1
 
Sheets("valeur d'étalonnage").Range(Cells(ligne, col2), Cells(ligne2, col2)).Copy Destination:=Sheets("palier").Range("D3")
End Sub

voila je comprend pas pourquoi
Cells(ligne, col).selec ça marche.
Range(Cells(ligne, col), Cells(ligne2, col)).Select ça ne marche pas, j'hesite à chaque fois sur les formats.

Merci
Alex

[tedo01]

Bonjour,
Par défaut, les fonctions Range et Cells se basent sur la feuille active, sauf lorsqu'elles sont attribuées à une feuille précise par la syntaxe Sheets("nom").Range ou Sheets("nom").Cells.
Dans ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("valeur d'étalonnage").Range(Cells(ligne, col2), Cells(ligne2, col2))

il y a un mélange des deux : Range est pris dans la feuille Sheets("valeur d'étalonnage"), alors que Cells s'applique à la feuille active.
La bonne syntaxe serait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("valeur d'étalonnage").Range(Sheets("valeur d'étalonnage").Cells(ligne, col2), Sheets("valeur d'étalonnage").Cells(ligne2, col2))

Pour simplifier on peut passer par une variable

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim shValEtal As Worksheet
Set shValEtal = Sheets("valeur d'étalonnage")
...
shValEtal.Range(shValEtal.Cells(ligne, col2), shValEtal.Cells(ligne2, col2)).Copy...

[casefayere]

Bonsoir,
ou peut-être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("valeur d'étalonnage")
  .Range(.Cells(ligne, col2).Address, .Cells(ligne2, col2).Address).Copy Destination:=Sheets("palier").Range("D3")
end with

[Oum le dauphin]

Merci pour vos 2 réponses.
C'est très clair ,je comprend un peu mieux comment ça marcher

merci
Alex