Discussion :

[Lbn23]

Bonjour,

Depuis de nombreux jours je parcours tout les forums possible sur VBA mais je ne trouve pas de réponse à mon problème...

J'ai une première feuille avec 11 actions avec leurs rendement rangés par colonne et j'aimerai calculer la moyenne des rendements de chaque action en redirigeant les resultats dans un tableau sur une autre feuille où la les actions sont rangées par ligne.

Pour le moment j'ai le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Sub test() 
Dim moyenne As Double 
Dim rendement As Range 
Dim i As Integer, j As Integer 
Set plage = Range("P5", "Z63") 
 
 
For i = 1 To 12 
For j = 1 To 11 
 
ThisWorkbook.Sheets("feuil1").Cells(5, j).Select 
Set rendement = Range(Selection, Selection.End(xlDown)) 
moyenne = WorksheetFunction.Average(rendement) 
 
 
ThisWorkbook.Sheets("Résultats").Cells(i, 2).Value = moyenne 
 
Next j 
Next i 
 
 
End Sub

Les résultats s'inserent dans le tableau mais c'est le meme resultat qui est affiché pour les 11 actions..

Pourriez vous m'aider s'il vous plait, je desespère..

Cordialement!

[gFZT82]

Bonjour,

Voici un code qui semble convenir à ta demande.
Je n'ai pas vu d'utilisation de la plage P5:Z63

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public Sub test()
Dim moyenne As Double
Dim rendement As Range
Dim i As Integer, j As Integer
    Set plage = Range("P5", "Z63")
    For j = 1 To 11
        ThisWorkbook.Sheets("Feuil1").Cells(5, j).Select
        Set rendement = Range(Selection, Selection.End(xlDown))
        moyenne = WorksheetFunction.Average(rendement)
        ThisWorkbook.Sheets("Résultats").Cells(j, 2).Value = moyenne
    Next j
End Sub

Cordialement.

[Lbn23]

merci de ta réponse! malheureusement le code que tu m'as proposé ne marche pas, j'ai un message d'erreur qui s'affiche : erreur d'execution "9" l'indice n'appartient à la selection.

j'ai essayé ce code pour calculer la moyenne des rendements d'une action, et il marche bien:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub test()
Dim moyenne As Double
Dim rendement As Object
 
Set rendement = Range("P5", "P63")
moyenne = WorksheetFunction.Average(rendement)
 
ThisWorkbook.Sheets("Résultats").Range("B2").Value = moyenne
End Sub

mais je n'arrive pas a faire la boucle pour que soit calculée la moyenne des rendements des ttes les actions..
la liste des rendements commence en P5 jusqu'en Z63 c'est pour ca que j'avais écrit set plage=Range("P5", "Z63")

[gFZT82]

Quel est le nom précis de tes 2 feuilles (il est conseillé d'éviter les accents ou les espaces) ?

[Philippe Tulliez]

Bonjour,
Les constantes sont peut-être à modifier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
Const shtFromName As String = "Feuil2"
Const shtDestName As String = "Resultat"
Const FromStartRow As Byte = 5
Public Sub test()
 With ThisWorkbook
  Dim shtFrom As Worksheet: Set shtFrom = .Worksheets(shtFromName)
  Dim shtDest As Worksheet: Set shtDest = .Worksheets(shtDestName)
 End With
 Dim addr As String
 Dim LastRow As Long
 Dim moyenne As Double
 Dim i As Integer, j As Integer
  shtFrom.Activate
  For j = 1 To 11
   LastRow = shtFrom.Cells(FromStartRow + 1, j + 1).End(xlDown).Row
   moyenne = WorksheetFunction.Average(shtFrom.Range(Cells(FromStartRow + 1, j + 1), Cells(LastRow, j + 1)))
   With shtDest
   .Range("A" & j) = shtFrom.Cells(FromStartRow, j + 1)
   .Range("B" & j) = moyenne
   End With
  Next j
End Sub

[EDIT]
Je viens de me rendre compte qu'une variable addr trainait par là par erreur et on peut aussi se passer de la variable moyenne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
Const shtFromName As String = "Feuil2"
Const shtDestName As String = "Resultat"
Const FromStartRow As Byte = 5
Public Sub test()
 With ThisWorkbook
  Dim shtFrom As Worksheet: Set shtFrom = .Worksheets(shtFromName)
  Dim shtDest As Worksheet: Set shtDest = .Worksheets(shtDestName)
 End With
 Dim LastRow As Long
 Dim i As Integer, j As Integer
  shtFrom.Activate
  For j = 1 To 11
   LastRow = shtFrom.Cells(FromStartRow + 1, j + 1).End(xlDown).Row
   WorksheetFunction.Average(shtFrom.Range(Cells(FromStartRow + 1, j + 1), Cells(LastRow, j + 1)))
   With shtDest
   .Range("A" & j) = shtFrom.Cells(FromStartRow, j + 1)
   .Range("B" & j) = WorksheetFunction.Average(shtFrom.Range(Cells(FromStartRow + 1, j + 1), Cells(LastRow, j + 1)))
   End With
  Next j
End Sub

[Lbn23]

j'ai la feuille sur laquelle j'écris mon code "Données" et celle sur laquelle j'aimerais envoyer mes résultats "Résultats"

j'ai joint mon fichier pour plus de clarté

edit:merci corona, mais le code ne marche pas..erreur 1004

[gFZT82]

La liste des rendements commence en P5 jusqu'en Z63 (feuille "Données").
Le code suivant réalise le calcul de la moyenne des rendements des toutes les actions et place les résultats dans la feuille "Résultats".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Sub test()
Dim Ws1 As Worksheet
Dim Ws2 As Worksheet
Dim moyenne As Double
Dim rendement As Range, MaPlage As Range
Dim j As integer
    Set Ws1 = Worksheets("Données")
    Set Ws2 = Worksheets("Résultats")
    Set MaPlage = Ws1.Range("P5", "Z63")
    j = 2
    For Each Col In MaPlage.Columns
        moyenne = WorksheetFunction.Average(Col)
        Ws2.Cells(j, 2).Value = moyenne
        j = j + 1
    Next Col
End Sub

Cordialement.

[Philippe Tulliez]

Bonjour,

j'ai la feuille sur laquelle j'écris mon code "Données" et celle sur laquelle j'aimerais envoyer mes résultats "Résultats"
j'ai joint mon fichier pour plus de clarté
edit:merci corona, mais le code ne marche pas..erreur 1004

C'est assez étonnant parce-que je teste toujours les codes des réponses que j'envoie.
Si tu pouvais me dire à quelle ligne à lieu l'erreur, ce serait bien.
As-tu modifié une ou plusieurs des constantes qui se trouvent en tête de module comme je te l'ai suggéré ?