Discussion :

[timon37]

Je cherche, à partir du fichier joint, à rappatrier dans l'onglet correspondance en fonction de la colonne A et de la colonne B la famille située dans l'onglet table. (A,B,C,D, P1,P2,P3). Le tout en VBA, sachant que chaque onglet peut avoir un nombre de lignes variables.

[mercatog]

Proposition par code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Remp()
Dim Fct As String, Cde As String, Res As String
Dim Plage As Range, c As Range, v As Range
Dim LastLig As Long, i As Long
Dim Col As Integer
 
Application.ScreenUpdating = False
With Worksheets("TABLE")
    .AutoFilterMode = False
    Set Plage = .Range("A1").CurrentRegion
End With
With Worksheets("CORRESPONDANCE")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    For i = 2 To LastLig
        Fct = .Range("A" & i).Value
        Cde = .Range("B" & i).Value
        Set c = Plage.Rows(1).Find(Fct, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Col = c.Column
            Set c = Nothing
            Plage.AutoFilter field:=1, Criteria1:=Cde
            Res = Plage.Offset(1, 0).Columns(Col).SpecialCells(xlCellTypeVisible)(1, 1)
        Else
            Res = ""
        End If
        .Range("C" & i).Value = Res
    Next i
    Worksheets("TABLE").AutoFilterMode = False
End With
Set Plage = Nothing
End Sub

[timon37]

merci beaucoup, exactement ce que je cherchais
cdlt,