Discussion :

[ARTETA13]

Bonjour,

Etant un novice sous VBA, je souhaiterai convertir une feuille excel en pdf
par contre l'utilisateur doit entrer un nom pour sauvegarder et cliker sur enregistrer.Je voudrais donc savoir comment sauter cette étape en définissant une adresse par défaut.

Merci pour votre aide!!

[Cocotte278]

Bonjour Arteta13,

J'ai bien un bout de code pour sauvegarder en PDF mais l'utilisateur devra qd même cliquer sur un bouton !

Je te le mets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Private Sub CommandButton10_Click()
'Permet une impression en PDF
 
With ActiveSheet.PageSetup
    .RightHeader = "" & Chr(10) & "" & Chr(10) & "" & Chr(10) & "" & Chr(10) & "&G"
    .LeftFooter = "&P / &N" & Chr(10) & "" & Chr(10) & "" & Chr(10) & ""
    .CenterFooter = "&12&D - &T" & Chr(10) & "" & Chr(10) & "" & Chr(10) & ""
    .RightFooter = "&""Arial,Italique""&Graphique" & Chr(10) & "" & Chr(10) & "" & Chr(10) & ""
    .Zoom = 70
    .CenterHorizontally = True
    .CenterVertically = True
    .Orientation = xlLandscape
End With
 
Me.Hide
Application.ActivePrinter = "PDFCreator sur Ne00:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:= _
"PDFCreator sur Ne00:", Collate:=True
Me.Show
 
End Sub

J'execute ceci avec un bouton.
Perso, je ne suis pas sûre que l'on puisse shinter le clic de confirmation...

Cdt

[ARTETA13]

Il ne reconnait pas le: Me.Hide (utilisation incorrecte du mot clé)

[Cocotte278]

Si tu ne travailles pas avec un Userform, enlève

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Hide

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Show

.

[ARTETA13]

Merci pour ton aide!!!!
Je vais essayer de creuser pour pouvoir automatiser l'enregistrement!

Je n'arrive toujours pas à trouver une solution pour enregistrer par defaut mon pdf dans un dossier définis.
Un peu d'aide??

[kiki29]

Salut, avec PDFCreator, en cherchant un peu tu aboutis à qqch comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Option Explicit
 
Sub Tst_PdfCreator_01()
Dim JobPDF As Object
Dim sNomPDF As String
Dim sNomPS As String
Dim sCheminPDF As String
Dim Ar() As String, Cpt As Long, i As Long
 
    sNomPDF = "Essai.pdf"
    sCheminPDF = ThisWorkbook.Path & "\"
 
    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")
 
    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF
 
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
 
        .cClearCache
    End With
 
    Cpt = 0
    For i = 1 To ThisWorkbook.Sheets.Count
        ReDim Preserve Ar(Cpt)
        Ar(Cpt) = Sheets(i).Name
        Cpt = Cpt + 1
    Next i
    If Cpt = 0 Then Exit Sub
 
    Sheets(Ar).PrintOut copies:=1, ActivePrinter:="PDFCreator"
    Sheets("Feuil1").Activate
 
    'Fichier dans la file d'attente
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False
 
    'Attendre que la file d'attente soit vide
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
 
    JobPDF.cClose
    Set JobPDF = Nothing
 
End Sub

Il y a peut-être également qqs options à cocher via le menu Imprimante/Options de PDFCreator.exe