Discussion :

[iliesss]

Bonjour
J’ai le code suivant qui me permettre de supprimer toute ligne si les cellules F et G sont nulles a la fois.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
SubligneFetGvide()
derniereLigne = ActiveSheet.UsedRange.Rows.Count
Application.ScreenUpdating = False
For r = derniereLigne To 1 Step -1
If (Range ("F" & r)) = 0 And (Range ("G" & r)) = 0 ThenRows(r).Delete
Next r
End Sub

Mon tableau (A : H) contient 20000 lignes alors le code commence de 1 aux 40000 lignes et après le code mon tableau devient de 1 au 43600.

J’ajoute 125 lignes mon tableau maintenant contient 43725 lignes (43600+25) si je lance le code il va commencer de 1 au 43725 et ça prendre du temps. C’est-à-dire le code toujours commence de la première ligne.

Comment modifier ce code pour commencer de 43600 au 43725 c'est-à-dire la dernière ligne de l’ancienne exécution et ainsi de suite.
Merci

[pgz]

Bonsoir.

Si tu veux faire cela, tu dois mettre un marqueur, comme par exemple un nom défini pour la plage, à redéfinir dans le code de suppression de lignes.

Tu peux aussi accélérer la suppression des lignes en utilisant une variable tableau. L'inconvénient c'est que comme les lignes sont réécrites et pas supprimées, les formats éventuels sont conservés. Si ce n'est pas gênant, cela peut être une solution intéressante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub SubligneFetGvide()
Dim oSh As Excel.Worksheet
Dim v As Variant, i As Long, Index As Long, j As Integer
Dim DerLig As Long, DerCol As Integer
 
Set oSh = ActiveSheet
DerLig = oSh.UsedRange.Rows(oSh.UsedRange.Rows.Count).Row
DerCol = oSh.UsedRange.Columns(oSh.UsedRange.Columns.Count).Column
 
If DerCol < 7 Then DerCol = 7 'au cas où toute la colonne G est vide ainsi que les colonnes suivantes
 
v = oSh.Range(oSh.Cells(1, 1), oSh.Cells(DerLig, DerCol)).Value
 
'tasser les lignes à conserver
Index = 1
For i = 1 To DerLig
    If (v(i, 6) <> 0) Or (v(i, 7) <> 0) Then
        For j = 1 To DerCol
            v(Index, j) = v(i, j)
        Next j
        Index = Index + 1
    End If
Next i
 
'vider les lignes restantes
For i = Index To DerLig
    For j = 1 To DerCol
        v(i, j) = Empty
    Next j
Next i
 
 
oSh.Range(oSh.Cells(1, 1), oSh.Cells(DerLig, DerCol)).Value = v
 
Set oSh = Nothing
End Sub

Cordialement,

PGZ

[iliesss]

merci mon ami merci beaucoup
je pense que ton code est le plus rapide.

[mercatog]

Essaies d'utiliser un filtre automatique, c'est plus rapide que les boucles (je suppose que la ligne 1 est celle des titres)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub LigneFetGvide()
Dim LastLig As Long
 
Application.ScreenUpdating = False
With Sheets("Feuil1")
    'On enlève l'éventuel filtre auto
    .AutoFilterMode = False
    LastLig = .UsedRange.Rows.Count
    'on filtre notre plage sur colonne F avec critères 0 ou vide
    .Range("A1:H" & LastLig).AutoFilter Field:=6, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'Et sur colonne G avec critères 0 ou vide
    .Range("A1:H" & LastLig).AutoFilter Field:=7, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'Si au moins une ligne visible suite au filtre, on supprime les lignes visibles
    If .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then _
       .Range("A2:A" & LastLig).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    'On enlève filtre auto
    .AutoFilterMode = False
End With
End Sub

[iliesss]

salut mon ami .
j'utilise jusqu’à maintenant ton code (LigneFetGvide) et merci infiniment.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub LigneFetGvide()
Dim LastLig As Long
 
Application.ScreenUpdating = False
With Sheets("Feuil1")
    'On enlève l'éventuel filtre auto
    .AutoFilterMode = False
    LastLig = .UsedRange.Rows.Count
    'on filtre notre plage sur colonne F avec critères 0 ou vide
    .Range("A1:H" & LastLig).AutoFilter Field:=6, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'Et sur colonne G avec critères 0 ou vide
    .Range("A1:H" & LastLig).AutoFilter Field:=7, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'Si au moins une ligne visible suite au filtre, on supprime les lignes visibles
    If .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then _
       .Range("A2:A" & LastLig).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    'On enlève filtre auto
    .AutoFilterMode = False
End With
End Sub

j'ai essayé de remplacer ma plage par un tableau alors le code bloquer dans
cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).EntireRow.Delete

SVP aider moi

[mercatog]

Bonsoir

j'ai essayé de remplacer ma plage par un tableau alors le code bloquer dans

Je n'ai pas compris ce que ça veut dire.

[iliesss]

Moi j’ai remplacé ma plage exemple A1:H10 par un tableau nommé tableau1
J’ai utilisé les étapes suivantes :
1* j’ai sélectionné toute la plage A1:H10
2* j’ai utilisé raccourci (Ctl+L) ou bien ongle insertion icône tableaux "office 2010"
Finalement ma plage A1:H10 change les couleurs des cellules est devenu un tableau nommé tableau1

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub LigneFetGvide()
 
Application.ScreenUpdating = False
With Sheets("Feuil1").ListObjects("Tableau1").Range
    .AutoFilter
    'on filtre notre plage sur colonne F avec critères 0 ou vide
    .AutoFilter Field:=6, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'Et sur colonne G avec critères 0 ou vide
    .AutoFilter Field:=7, Criteria1:=0, Criteria2:="=", Operator:=xlOr
    'On supprime les lignes visibles
    .Offset(1, 0).EntireRow.Delete
    'On enlève filtre auto
    .AutoFilter
End With
End Sub