Discussion :

[Beaudelicius]

Bonjour forum,

J'ai un problème, lorsque mon userform s'initialise, je désire alimenter une listview selon un tableau qui peut contenir différent nombre de variable.

Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
With Me.ListView1
    With .ColumnHeaders
        .Clear
        .Add , , "Contrat", 30
        .Add , , "Nb jours", 30
        .Add , , "Départ.", 30
        .Add , , "Date Prod", 30
    End With
 
    If last > 2 Then
        j = 1
        For i = 3 To last
            .ListItems.Add j, , Sheets("Feuil1").Range("AL" & i).Value                  'Contrat
            .ListItems(j).ListSubItems.Add , , Sheets("Feuil1").Range("AM" & i).Value  'Nb jours
            .ListItems(j).ListSubItems.Add , , Sheets("Feuil1").Range("AO" & i).Value  'Produit
            .ListItems(j).ListSubItems.Add , , Sheets("Feuil1").Range("AP" & i).Value  'Date Prod
        j = j + 1
        Next i
    End If
.View = lvwList
End With

1) Mes entêtes ne s'affiche pas
2) La seule colonne qui s'affiche dans ma listview est la première colonne, donc seulement les contrats.

Merci de votre aide

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub UserForm_Initialize()
Dim Last As Long, i As Long, j As Long
Dim Tb
 
With Sheets("Feuil1")
    Last = .Cells(.Rows.Count, "AL").End(xlUp).Row
    If Last > 2 Then
        Tb = .Range("AL3:AP" & Last)
        With Me.ListView1
            .HideColumnHeaders = False
            .View = lvwReport
            .AllowColumnReorder = True
            .FullRowSelect = True
            With .ColumnHeaders
                .Clear
                .Add , , "Contrat", 50
                .Add , , "Nb jours", 50
                .Add , , "Départ.", 50
                .Add , , "Date Prod", 50
            End With
            For i = 1 To UBound(Tb, 1)
                j = j + 1
                .ListItems.Add j, , Tb(i, 1)                    'Contrat
                .ListItems(j).ListSubItems.Add , , Tb(i, 2)     'Nb jours
                .ListItems(j).ListSubItems.Add , , Tb(i, 3)     'Produit
                .ListItems(j).ListSubItems.Add , , Tb(i, 4)     'Date Prod
            Next i
        End With
    End If
End With
End Sub

[Beaudelicius]

Merci mercatog tout marche à la perfection

[mercatog]

On aurait pu s'en passer de la variable j

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub UserForm_Initialize()
Dim Last As Long, i As Long
Dim Tb
 
With Sheets("Feuil1")
    Last = .Cells(.Rows.Count, "AL").End(xlUp).Row
    If Last > 2 Then
        Tb = .Range("AL3:AP" & Last)
        With Me.ListView1
            .HideColumnHeaders = False
            .View = lvwReport
            .AllowColumnReorder = True
            .FullRowSelect = True
            With .ColumnHeaders
                .Add , , "Contrat", 50
                .Add , , "Nb jours", 50
                .Add , , "Départ.", 50
                .Add , , "Date Prod", 50
            End With
            For i = 1 To UBound(Tb, 1)
                .ListItems.Add i, , Tb(i, 1)               'Contrat
                .ListItems(i).ListSubItems.Add , , Tb(i, 2)    'Nb jours
                .ListItems(i).ListSubItems.Add , , Tb(i, 3)    'Produit
                .ListItems(i).ListSubItems.Add , , Tb(i, 4)    'Date Prod
            Next i
        End With
    End If
End With
End Sub

[Beaudelicius]

OK merci beaucoup, mais j'ai une autre question.

Je veux que lorsque quelqu'un selection un élément dans la listeview et click sur le bouton supprimé, l'élément s'éfface de ma feuille. Avant d'utiliser ton code ça fonctionnait, mais plus maintentant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
i = ListView1.SelectedItem.Index
Set contrat = Sheets("Feuil1").Range("AL3:AL1000").Find(Me.ListView1.ListItems(i).Text)
Range(Cells(contrat.Row, 38), Cells(contrat.Row, 42)).ClearContents

Pourrais tu me dire pourquoi.

Merci

[mercatog]

Regarde le commentaire si tu veux supprimer toute la ligne de Feuil1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton1_Click()
Dim c As Range
Dim Contrat As String
Dim i As Integer
 
Contrat = Me.ListView1.SelectedItem.Text
If Contrat <> "" Then
    i = Me.ListView1.SelectedItem.Index
    Set c = Sheets("Feuil1").Range("AL:AL").Find(Contrat, LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then
        c.Resize(1, 5).ClearContents
        'c.EntireRow.Delete 'Pour supprimer toute la ligne
        Set c = Nothing
        Me.ListView1.ListItems.Remove i
    End If
End If
End Sub