Discussion :

[IronBibs]

Bonjour,

J'aimerais exporter une feuille de mon classeur *.xls dans un fichier *.csv.
A ce niveau là encore pas de soucis.

Mon soucis est que le fichier *.csv résultant de l'export est utilisé par une machine qui fait des mesures. Cette machine va lire ce fichier csv et introduire des informations.
Malheureusement pour cela, il faut impérativement que quand on ouvre le .csv avec un éditeur texte tel que NotePad++, chaque ligne contient 512 caractères ou "col" comme indiqué dans la barre d'information de NotePad++ (par exemple).

Il n'y a jamais plus de 512 caractères par ligne dans le fichier xls d'origine. S'il y a 425 caractères dans ma ligne du fichier xls, il faudrait créer des caractères jusqu'au 512ème.

Est-il possible lors de la création du fichier csv en vba de faire en sorte qu'il y a toujours ce nombre précis de caractères ou colonnes par ligne? Si oui, pouvez vous me donner une piste car je sèche complètement.

Merci !

[kiki29]

Salut, à tester, adapter et optimiser mais la base est là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
 
Sub EcrireFichier()
Dim Fichier As String
Dim LastRow As Long, LastCol As Long
Dim Sep As String, Num As Integer
Dim r As Long, c As Long, sStr As String
 
    Sep = ";"
    Fichier = ThisWorkbook.Path & "\" & "Essai.csv"
    LastRow = Feuil1.Range("A" & Rows.Count).End(xlUp).Row
    Num = FreeFile
 
    Open Fichier For Output As #Num
        For r = 1 To LastRow
            LastCol = Feuil1.Range("IV" & r).End(xlToLeft).Column
            sStr = ""
            For c = 1 To LastCol
               sStr = sStr & Sep & Feuil1.Cells(r, c)
            Next c
            sStr = Mid$(sStr, 2, Len(sStr) - 1)
            sStr = sStr & String$(512 - LastCol, Sep)
            Print #Num, sStr
        Next r
    Close #Num
End Sub

Une autre interprétation donne ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
 
Sub EcrireFichier()
Dim sFichier As String
Dim LastRow As Long, LastCol As Long
Dim Sep As String, Num As Integer
Dim r As Long, c As Long, sStr As String
Dim NbCar As Long
 
    Sep = ";"
    sFichier = ThisWorkbook.Path & "\" & "Essai3.csv"
    LastRow = Feuil1.Range("A" & Rows.Count).End(xlUp).Row
    Num = FreeFile
 
    Open sFichier For Output As #Num
        For r = 1 To LastRow
            LastCol = Feuil1.Range("IV" & r).End(xlToLeft).Column
            sStr = ""
            NbCar = 0
            For c = 1 To LastCol
               sStr = sStr & Sep & Feuil1.Cells(r, c)
               NbCar = NbCar + Len(Feuil1.Cells(r, c))
            Next c
            sStr = Mid$(sStr, 2, Len(sStr) - 1) & Sep
            sStr = sStr & String$(512 - NbCar, Sep)
            Print #Num, sStr
        Next r
    Close #Num
End Sub