Discussion :

[HelixLeChat]

Bonjour,

Dans ma feuille, j'ai 3 colonnes A, B et C.

Dans A --> 1 à i.
Dans les colonnes B et C, des nombres aléatoires.

Ce que je cherche à faire :

(1)Colonne D, pour Di je calcule Bi+Ci-C(i+1).
Si Di <0, j'affiche 0, sinon j'affiche 1 (donc si Di >= 0).

(2)Lorsque dans la colonne D, il y a un 1, j'aimerais intervertir les plages (Ai:Ci) et (A(i+1):C(i+1))

(3)A nouveau étapes (1) puis (2) jusqu'à ce que la colonne D ne comporte que des 0.

Bien sûr, c'est faisable à la mimine, mais lorsque i est important, cela devient ingérable...
C'est pourquoi j'aimerais bien me créer une petite macro !

Et comme vous pouvez vous en douter, je ne suis absolument pas ami avec Excel et ses macros ...

Merci d'avance pour vos pistes de résolution.

[mercatog]

(3)A nouveau étapes (1) puis (2) jusqu'à ce que la colonne D ne comporte que des 0.

Une première question, es tu sûr que ton petit algorithme ne diverge pas (c'est à dire si tu es sûr d'avoir des 0 en D)

[HelixLeChat]

Alors oui pour répondre à ta question.

En fait, pour plus de précisions.

-le véritable petit algo :

Di = [Bi*C(i+1)*(P+Ci)] - B(i+1)*Ci*(P+C(i+1))]

Donc pour D1 = B1*C2*(P+C1) - B2*C1*(P+C2)

Avec P une constante,
Bi et Ci nombres aléatoires entre 1 et n (je fixe n dans le tirage, en général n = 100).
P, Bi et Ci ont entre 10 et 20 décimales.

Donc en théorie, l'algo peut diverger effectivement, mais en pratique à priori non du fait des nombres tirés.
Mais cela peut arriver... Je n'avais pas pensé à ce contrôle.

-En consultant le forum, j'ai vu qu'il était possible de déterminer le temps d'éxécution de l'algo (avec plus ou moins de précisions).
Est-il possible de déterminer le nombre d'itérations également ?

Merci.

[mercatog]

Tu peux mettre un fichier pour pouvoir tester?

[HelixLeChat]

Et voivi.

[mercatog]

Essaies avec la sub Tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Sub TESTER()
Dim Bi As Double, Ci As Double, Bii As Double, Cii As Double, Di As Double, P As Double
Dim CTR As Integer, Limit As Integer
Dim LastLig As Long, i As Long
Dim Encore As Boolean
Dim S As Single
Dim Tb
 
Application.ScreenUpdating = False
Limit = 2000                                                                                       'Limite des itérations pour éviter la boucle infinie en cas de divergence
S = Timer                                                                                          'Pour compter le temps d'exécution
P = Application.Pi()                                                                               'Ici j'ai pris Pi comme variable pour P
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("A1:C" & LastLig)
    Do
        Encore = False
        For i = 1 To UBound(Tb, 1) - 1
            Bi = Tb(i, 2)
            Ci = Tb(i, 3)
            Bii = Tb(i + 1, 2)
            Cii = Tb(i + 1, 3)
            Di = Bi * Cii * (P + Ci) - Bii * Ci * (P + Cii)
            If Di > 0 Then
                Permut Tb, i, i + 1
                Encore = True
            End If
        Next i
        CTR = CTR + 1
    Loop Until Not Encore Or CTR >= Limit
    .Range("A1:C" & LastLig) = Tb
End With
If CTR = Limit Then
    MsgBox "Solution non trouvée en " & CTR & " boucles (" & Timer - S & " secondes)"
Else
    MsgBox "Traitement terminé en " & CTR & " boucles (" & Timer - S & " secondes)"
End If
End Sub
 
'Permet de permuter les lignes i et j
Private Sub Permut(T As Variant, i As Long, j As Long)
Dim Tmp As Double
Dim k As Byte
 
For k = 1 To UBound(T, 2)
    Tmp = T(i, k)
    T(i, k) = T(j, k)
    T(j, k) = Tmp
Next k
End Sub

[HelixLeChat]

Erreur d’exécution 13 : incompatibilité de type ...