Changer la sélection dans un Range().select

**MatAir** · 21/07/2011, 19h51

Bonjour,
je tente de faire une mise en forme de cellules d'une ligne selon la valeur d'une cellule de cette même ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 Dim i As Integer
    For i = 3 To 285 Step 1
    Range("Ci:Qi").Select
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, _
        Formula1:="=$B$i"
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    With Selection.FormatConditions(1).Font
        .Color = -16383844
        .TintAndShade = 0
    End With
    With Selection.FormatConditions(1).Interior
        .PatternColorIndex = xlAutomatic
        .Color = 13551615
        .TintAndShade = 0
    End With
    Selection.FormatConditions(1).StopIfTrue = False
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, _
        Formula1:="=$B$i"
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    With Selection.FormatConditions(1).Font
        .Color = -16752384
        .TintAndShade = 0
    End With
    With Selection.FormatConditions(1).Interior
        .PatternColorIndex = xlAutomatic
        .Color = 13561798
        .TintAndShade = 0
    End With
    Selection.FormatConditions(1).StopIfTrue = False
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=NBCAR(SUPPRESPACE(Ci))=0"
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    Selection.FormatConditions(1).StopIfTrue = True
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, _
        Formula1:="=$B$i"
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    With Selection.FormatConditions(1).Font
        .Color = -16751204
        .TintAndShade = 0
    End With
    With Selection.FormatConditions(1).Interior
        .PatternColorIndex = xlAutomatic
        .Color = 10284031
        .TintAndShade = 0
    End With
    Selection.FormatConditions(1).StopIfTrue = False
    Next i
    
End Sub

À la base, le code a été créé avec enregistrer une macro et je tente de le modifier (le texte en vert sont mes modificationpour qu'il se répète en boucle sur les ligne 3 a 285. Malheureusement, il semble que je ne puisse pas faire ca simple.

Les cellules à mettre en forme conditionnelle sont toujours de la colonne C à la colonne Q mmis en forme selon la valeur de la cellule de la colonne B

Quelqu'un pourrait me donner un coup de main

Merci

**gFZT82** · 21/07/2011, 20h08

Bonjour,

Tu dois écrire sous la forme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("C" & i & ":Q" & i).Select

Cordialement

**MatAir** · 21/07/2011, 20h10

Bonjour,

Je reçois une erreur de syntaxe avec ce code.
J'ai essayé de sortir les : mais sans succès

**mercatog** · 21/07/2011, 20h12

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Dim i As Integer
 
With Sheets("Feuil1")
    For i = 3 To 285
        With .Range("C" & i & ":Q" & i)
            .FormatConditions.Delete
            .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=$B$" & i
            With .FormatConditions(1)
                .Font.Color = -16383844
                .Interior.Color = 13551615
                .StopIfTrue = False
            End With
 
            .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:="=$B$" & i
            With .FormatConditions(2)
                .Font.Color = -16752384
                .Interior.Color = 13561798
                .StopIfTrue = False
            End With
 
            .FormatConditions.Add Type:=xlExpression, Formula1:="=NBCAR(SUPPRESPACE(C" & i & "))=0"
            With .FormatConditions(3)
                .SetFirstPriority
                .StopIfTrue = True
            End With
 
            .FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, Formula1:="=$B$" & i
            With .FormatConditions(4)
                .Font.Color = -16751204
                .Interior.Color = 10284031
                .StopIfTrue = False
            End With
        End With
    Next i
End With

**MatAir** · 21/07/2011, 20h29

Bonjour Mercatog,
Je sais pas pourquoi mais à chaque fois que j'ai tenté d'utiliser la commande
With sheets("Feuil1")

J'ai reçu une erreur d'exécution '9'

L'indice n'appartient pas à la sélection

Est-ce que je peux juste mettre Feuil1 en avant du .Range et mettre Range en avant de tout les autres . ???

**mercatog** · 21/07/2011, 20h35

Parce que TA feuille ne s'appelle pas Feuil1. Tu dois adapter.

Sans boucle qui est assez lente:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
With Sheets("Feuil1") 'Adapte ici le nom de ta feuille
    With .Range("C3:Q285")
        .FormatConditions.Delete
        .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=INDIRECT(Adresse(Ligne();2))"
        With .FormatConditions(1)
            .Font.Color = -16383844
            .Interior.Color = 13551615
            .StopIfTrue = False
        End With
 
        .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:="=INDIRECT(Adresse(Ligne();2))"
        With .FormatConditions(2)
            .Font.Color = -16752384
            .Interior.Color = 13561798
            .StopIfTrue = False
        End With
 
        .FormatConditions.Add Type:=xlExpression, Formula1:="=NBCAR(SUPPRESPACE(INDIRECT(Adresse(Ligne();3))))=0"
        With .FormatConditions(3)
            .SetFirstPriority
            .StopIfTrue = True
        End With
 
        .FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, Formula1:="=INDIRECT(Adresse(Ligne();2))"
        With .FormatConditions(4)
            .Font.Color = -16751204
            .Interior.Color = 10284031
            .StopIfTrue = False
        End With
    End With
End With

**MatAir** · 21/07/2011, 21h16

Rebonjour,
Je suis peut-être pas très bon en programmation , en fait je suis à chier mais je suis quand même capable de bien lire du code et de comprendre que ma feuille doit s'appeller Feuil1 pour que ca marche

je suis pas un imbécile fini, je suis juste un peu con

La dernière fois j'avais contourner le problème en marquant Feuil1 avant chaque point mais là, ca ne marche pas plus

**mercatog** · 21/07/2011, 21h25

je suis pas un imbécile fini, je suis juste un peu con

Qu'est ce que tu viens d'écrire sur la morale?
Le code fourni pour t'aider est fonctionnel et testé 36 fois sur mon fichier où ma feuille s'appelle bien Feuil1. (Le nom sur la feuille d'excel et non le CodeName qui apparait dans l'éditeur vba)

Si tu estimes que TA feuille de TON classeur sur lequel tu testes s'appelle Feuil1, l'erreur n'aurait pas eu lieu.
Si tu as ouverts plusieurs classeurs, peut être le classeur actif est autre.
Pour cela, remplace par ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ThisWorkbook.Worksheets("Feuil1") 'Adapte ici le nom de ta feuille

Changer la sélection dans un Range().select

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager