Discussion :

[Ours_en_feu]

Bonjour !

Je viens vers vous car j'ai un besoin simple mais que je n'arrive pas à combler:

J'ai un tableau en fichier joint qui doit me permettre de filtrer l'onglet par trigramme dans la colonne "who" puis generer un fichier excel séparé par personne dans la colonne "who" et l'enregistrer.
Je suis parti du tuto de "Philippe Tulliez" ici: https://philippetulliez.developpez.c...dvancedfilter/

ça ok j'ai compris.
Cependant si je tente d'utiliser ce code la en exemple trouvé ici:

https://www.developpez.net/forums/d1...l/#post7190633

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub ExportDataByAdvancedFilter()
 ' Déclaration + Initialisation des variables
 Dim rngList As Range, rngData As Range, rngCriteria As Range, r As Long
 Set rngData = shtData.Range("A1").CurrentRegion
 With shtParam
  Set rngList = .Range("A1"): Set rngCriteria = .Range("C1:C2")
 End With
 ' Etape 1 - Création d'une liste unique basée sur la colonne 1
 With rngData
 .Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True
 End With
 ' Etape 2 - Boucle sur la liste avec placement du critère
 '           Création nouvelle feuille
 '           Exportation vers nouvelle feuille
 '           Déplacement de cette nouvelle feuille vers un nouveau classeur
 For r = 1 To rngList.CurrentRegion.Rows.Count - 1
  rngCriteria.Cells(2, 1) = rngList.Offset(r) ' Insère le critère
  ' 2.1 - Création d'une feuille
  Sheets.Add before:=Sheets(1): Sheets(1).Name = rngList.Offset(r)
  ' 2.2 - Exportation vers nlle feuille suivant critère
  With rngData
  .AdvancedFilter xlFilterCopy, rngCriteria, Sheets(1).Range("A1")
  End With
  ' 2.3 - Déplacement de la feuille cers un nouveau classeur
  Sheets(1).Move
  '
  ' Ici code pour sauver classeur, Envoyer par email etc...
  '
 Next
End Sub

sur ma feuille à moi, il me sort l'erreur:

"Objet requis" sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Set rngData = shtData.Range("A1").CurrentRegion

Alors Ok ma variable rngData est mal déclarée, mais j'aimerais pouvoir lui dire que c'est la colonne "Who" dans l'onglet options, or je ne vois nulle part dans le code de Philippe de déclaration spécifique en disant "c'est dans cet onglet la que tu cherche la data, et dans cet onglet la que tu cherches les criteres"

J'ai raté quelque chose c'est évident, mais quoi et ou ?

J'ai enlevé le code de la macro pour que vous puissiez ouvrir sans risque, mais si vous avez des pistes, je suis preneur.



d'avance merci

[Philippe Tulliez]

Bonjour,
L'erreur obtenue provient sans doute du fait que tu n'as pas de feuille dont la propriété CodeName a pour valeur shtData

Lire éventuellement ce billet VBA – CodeName d’une feuille Excel

[Ours_en_feu]

L'auteur même du tuto et du fichier d'exemple que j'utilise qui répond ! C'est un honneur !

Merci pour la piste, je m'en vais creuser de ce coté

[Ours_en_feu]

Bonjour,
L'erreur obtenue provient sans doute du fait que tu n'as pas de feuille dont la propriété CodeName a pour valeur shtData

Lire éventuellement ce billet VBA – CodeName d’une feuille Excel

Philippe, j'ai regardé ton lien et j'ai parfaitement compris, merci !

J'ai une suite de questions pour bien comprendre ton code, désolé si cela te parait vraiment trivial mais je souhaite parfaitement saisir la philosophie derrière chaque ligne et non simplement copier et coller en changeant des noms de variables.

SI tu permet je te cite chaque ligne qui m'intrigue:


EDIT: je me suis répondu tout seul en cherchant, il me reste cette question:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 With rngData
 .Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True
 End With

peux tu m'expliquer s'il te plait pourquoi tu commence par .resize ?

Sinon quand je met à jour le code de l'exemple pour s'adapter à mon fichier cela donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Sub Rectangleàcoinsarrondis1_Cliquer()
 ' Déclaration + Initialisation des variables
 Dim rngList As Range, rngData As Range, rngCriteria As Range, r As Long
 Set rngData = shtData.Range("H1").CurrentRegion
 With shtParam
  Set rngList = .Range("C1"): Set rngCriteria = .Range("F1:F2")
 End With
 ' Etape 1 - Création d'une liste unique basée sur la colonne 1
 With rngData
 .Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True
 End With
 ' Etape 2 - Boucle sur la liste avec placement du critère
 '           Création nouvelle feuille
 '           Exportation vers nouvelle feuille
 '           Déplacement de cette nouvelle feuille vers un nouveau classeur
 For r = 1 To rngList.CurrentRegion.Rows.Count - 1
  rngCriteria.Cells(2, 1) = rngList.Offset(r) ' Insère le critère
  ' 2.1 - Création d'une feuille
  Sheets.Add before:=Sheets(1): Sheets(1).Name = rngList.Offset(r)
  ' 2.2 - Exportation vers nlle feuille suivant critère
  With rngData
  .AdvancedFilter xlFilterCopy, rngCriteria, Sheets(1).Range("A1")
  End With
  ' 2.3 - Déplacement de la feuille cers un nouveau classeur
  Sheets(1).Move
  '
  ' Ici code pour sauver classeur, Envoyer par email etc...
  '
 Next
End Sub

Mais lors de l'execution j'ai droit à l'erreur: Erreur d'execution 1004, le nom de champ est incorrecte ou manquant dans la zone d'extraction.

l'erreur a lieu ici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 .Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True

Je sais que mes questions sont ras les pâquerettes mais je débute totalement en VBA et je t'avoue que la puissance de l'outil me dépasse or j'ai vraiment envie de le maîtriser petit à petit.

[Philippe Tulliez]

Bonjour,
La fonction Resize redimensionne une plage de cellules et renvoie un objet Range.
Dans l'exemple donné, je veux exporter une liste unique basée sur la colonne A de RngData qui représente par exemple la plage A1:J100
Dans le code ci-dessous, l'exportation concerne A1:A100

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With rngData
 .Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True
End With

Pour t'en convaincre ajoute la ligne de code .Resize(,1).Select en première ligne du bloc With ... End With

Si nous devions effectuer une exportation des données sans les doublons de la colonne C, il faudrait ajouter la propriété Offset
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With rngData
 .Offset(,2).Resize(, 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rngList, Unique:=True
End With

soit déplacement de deux colonnes et redimensionnement d'une colonne

[Ours_en_feu]

Compris pour le resize, mais pourquoi ai-je cette erreur: Erreur d’exécution 1004, le nom de champ est incorrecte ou manquant dans la zone d'extraction.

[Philippe Tulliez]

Bonjour,
Je conseille vivement l'utilisation de l'une des fonctionnalités de l'outil de débogage.
SI l'erreur 1004 est déclenchée à cette ligne là, c'est que soit la variable rngData soit rngList n'est pas alimentée.
Un point d'arrêt sur cette ligne et un Debug.Print rngData.Address(External:=True) ou Debug.Print rngList.Address(External:=True) t'en apprendra sans doute plus.

La lecture ce ce tutoriel Le débogage sous Visual Basic 6 & Visual Basic pour Application (1ère partie) te sera très utile pour avancer.

[EDIT]

Erreur d’exécution 1004, le nom de champ est incorrecte ou manquant dans la zone d'extraction

L'étiquette de colonne de la zone d'exportation (Extraction) n'est sans doute pas identique ou bien manquante (cellule vide ?) à l'étiquette de colonne de la zone source (relire le tutoriel à ce sujet)