Discussion :

[Runsh63]

Bonjour,

Dans le cadre d'un retraitement de fichier, je dois conserver des numéros de compte à 6 chiffres. Problème : lorsque le numéro de compte est par exemple, "013000", alors avec le bout de code ci-dessous, j'obtiens "13000" alors que je voudrais "013000".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
With Sheets("Retreated data")
 
        Dim LR1 As Long, MyRange As Range
        LR1 = .Cells(.Rows.Count, 1).End(xlUp).Row
 
            For Each MyRange In .Range("E2:E" & LR1)
                MyRange.Value = Format(MyRange.Offset(0, -4).Value & MyRange.Offset(0, -3).Value, "000000")
                MyRange.Offset(0, 1).Value = MyRange.Offset(0, -2).Value - MyRange.Offset(0, -1).Value
 
            Next MyRange
 
    End With

Pourriez-vous m'aider SVP à formater mon numéro de compte à 6 digits ?
Merci d'avance !

[mercatog]

Bonjour
Une proposition en formatant les colonne E et F et en évitant la boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub test()
Dim LR1 As Long
 
With Sheets("Retreated data")
    LR1 = .Cells(.Rows.Count, 1).End(xlUp).Row
    .Range("E2:F" & LR1).NumberFormat = "000000"
    With .Range("E2:E" & LR1)
        .Formula = "=A2&B2"
        .Value = .Value
    End With
    With .Range("F2:F" & LR1)
        .Formula = "=C2-D2"
        .Value = .Value
    End With
End With
End Sub

[Runsh63]

Bonjour mercatog,

Merci beaucoup pour ta réponse, ça marche parfaitement. Une question cependant : quel est l'intérêt de limiter les boucles ? A chaque fois tu me les supprimes, tout du moins tu me conseilles fortement de le faire.

[mercatog]

Bonjour

quel est l'intérêt de limiter les boucles ?

Les boucles sur les cellules prennent plus de temps qu'une solution directe (du moins pour les grandes quantités de données)
Bon c'est un choix à prendre, je ne supprime pas ton code, mais je propose une autre alternative au cas où.

Sinon, ton code sera ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub test()
Dim LR1 As Long
Dim MyRange As Range
 
With Sheets("Retreated data")
    LR1 = .Cells(.Rows.Count, 1).End(xlUp).Row
    .Range("E2:F" & LR1).NumberFormat = "000000"
    For Each MyRange In .Range("E2:E" & LR1)
        MyRange.Value = MyRange.Offset(0, -4).Value & MyRange.Offset(0, -3).Value
        MyRange.Offset(0, 1).Value = MyRange.Offset(0, -2).Value - MyRange.Offset(0, -1).Value
    Next MyRange
End With
End Sub

Teste les 2 codes sur un fichier de 5000lignes, tu comprendras l'intérêt.

[Runsh63]

Je n'avais pas mal pris ta réponse, quand je dis "supprimer" mon code, c'est histoire de... Il faudrait être bête pour un débutant comme moi de ne pas suivre tes conseils, j'en suis d'ailleurs très friand car ils me font progresser. Je voulais juste comprendre, voilà tout.
Merci pour tes explications, je tenterai à l'avenir de limiter mes boucles car en effet, mes fichiers à traiter vont de 600 à 40000 lignes (c'est très disparate !).

[mercatog]

Il y a une autre méthode assez rapide, c'est l'utilisation des variables tableaux.
Exemple, pour ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test()
Dim LR1 As Long, i As Long
Dim Tablo
 
With Sheets("Retreated data")
    LR1 = .Cells(.Rows.Count, 1).End(xlUp).Row
    Tablo = .Range("A2:F" & LR1)
    For i = 1 To UBound(Tablo, 1)
        Tablo(i, 5) = Tablo(i, 1) & Tablo(i, 2)
        Tablo(i, 6) = Val(Tablo(i, 3)) - Val(Tablo(i, 4)) 'J'ai mis Val au cas où un valeur non numérique existe
    Next i
    .Range("E2:F" & LR1).NumberFormat = "000000"
    .Range("A2:F" & LR1) = Tablo
End With
End Sub

Ici on utilise des boucles sur des variables tableaux, c'est assez rapide.