Discussion :

[duplaly]

Allo
Voici un Exemple du fichier
En selectionnant un nom avec mon combobox, je veux que la macro cherche le nom dans le tableau adresse et copie toute la ligne.
le résultat doit être copié en colonne dans la feuille master. Il doit commencer dans la cellule en rouge.
il faudrait que la feuille soit considérée comme ActiveSheet car je vais copier la macro sur d'autres feuilles.
Merci pour toute aide.

[Philippe Tulliez]

Bonjour,
Je sais que c'est plus amusant de faire des macros mais en utilisant tout simplement la fonction RECHERCHEV tu pourrais placer les informations contenues dans la feuille [Adresse] sur la feuille [Master] et cela en moins de 5 minutes.
Un petit coup d'oeil sur ce didacticiel à la rubrique Combobox.

[Patrice740]

Bonjour,

Essaie ce code (sur le bouton Insérer adresse) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub CommandButton5_Click()
Const nb As Byte = 4  ' nombre de colonnes qui contiennent l'adresse
Dim c1 As Range       ' première cellule de l'adresse
Dim c2 As Range       ' cellule de destination
Dim n° As Byte        ' n° de la colonne d'adresse
 
  If ComboBox1.Text = "" Then Exit Sub
  'Chercher l'identifiant sélectionné
  Set c1 = Worksheets("Adresse").Columns("B:B").Find(ComboBox1.Text)
  'Définir la destination de l'adresse
  Set c2 = Worksheets("Master").Range("E6")
  'Effacer la zone de destination de l'adresse
  c2.Resize(nb).ClearContents
  'Explorer chaque cellule de l'adresse
  For n° = 1 To nb
    'Si l'information existe...
    If c1.Offset(, n° - 1).Value <> "" Then
      '... la copier dans la cellule de destination
      c1.Offset(, n° - 1).Copy
      c2.PasteSpecial xlPasteValues
      'définir la cellule de destionation suivante
      Set c2 = c2.Offset(1)
    End If
  Next n°
  Application.CutCopyMode = False
 
End Sub

Cordialement
Patrice

[duplaly]

Merci. Il fonctionne nickel

[mercatog]

Bonjour
Qu'on peut simplifier comme ceci (sans boucle ni copier/coller)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub CommandButton5_Click()
Dim c As Range                                                       ' première cellule de l'adresse
 
If ComboBox1.Text <> "" Then
    Set c = Worksheets("Adresse").Range("B:B").Find(ComboBox1.Text, LookIn:=xlValues, lookat:=xlWhole)
    Range("E6:E9").Value = Application.Transpose(c.Resize(1, 4).Value)
    Set c = Nothing
End If
End Sub

Edit:
Ou bien une autre approche: Travailler avec une Combobox multi colonnes

Ci après proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub UserForm_Initialize()                                    'à l'intilisation de l'UserForm
 
With Me.ComboBox1
    .ColumnCount = 4
    .ColumnWidths = "4;0;0;0"
End With
With Sheets("Adresse")
    Me.ComboBox1.List = .Range("B1:E" & .Cells(.Rows.Count, "A").End(xlUp).Row).Value
End With
End Sub
 
Private Sub ComboBox1_Change()
 
Range("E6:E9").ClearContents
End Sub
 
Private Sub CommandButton5_Click()
Dim i As Byte
 
With Me.ComboBox1
    If .ListIndex > -1 Then
        For i = 0 To 3
            Range("E" & 6 + i).Value = .List(.ListIndex, i)
        Next i
    End If
End With
End Sub

[duplaly]

Merci, tout fonctionne aussi avec ce code.