Discussion :

[pingoui]

Bonjour,
J'ai une feuille (1) contenant une base de donnée
Je souhaite comparer les données d'une feuille(2) à ma bd.
- Si je trouve des id identiques, je vérifie si la ligne complète est identique. Sinon mise à jour de la bd (code ok)

- Si des id sont présent dans la feuille (2) et absent de la bd, j'ajoute la/les ligne(s) à la bd. (je ne vois pas trop comment faire)

Avez vous une idée, pour trouver les lignes présentes dans la feuille 2 et pas dans la bd (sans trier les colonnes de la bd)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Sub Compare()
Dim i&, Z1$, Identique As Range
 
With ThisWorkbook.Sheets(1).Range("A2:A6")
 
  For Each o In ThisWorkbook.Sheets(2).Range("A2:A6")
  'noter le N° de ligne
    i = o.Row
    'mémoriser la valeur de la cellule
    Z1 = o.Value
    'cherche les id identiques
    Set Identique = .Find(Z1, LookIn:=xlValues, LookAt:=xlWhole)
    'Si trouvé mémorise le N° de ligne
    If Not Identique Is Nothing Then
    FirstRow = Identique.Row
    MsgBox "ligne identique = " & Identique
        Do
          'Code si identique
          Set Identique = .FindNext(Identique)
          '...Tant qu 'on n'est pas revenu à la ligne de départ
        Loop While Not Identique Is Nothing And Identique.Row <> FirstRow
        'réinitialise la variable avant de changer de ligne
      FirstRow = ""
    End If
    '...cellule de référence (o) suivante
  Next
End With
End Sub

[mercatog]

Bonsoir
Une question: combien tu as de colonnes?

[pingoui]

Bonjour
Une petite vingtaine

[Didier Gonard]

Bonjour,

Vu que tu recherches un ID qui par définition est unique sur une liste, perso, au lieu de Find, j'utiliserais Match et je récupérerais direct le N° de ligne..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
MsgBox WorksheetFunction.Match("DT42356,667055533132011", ActiveSheet.Range("A:A"), 0)
'

pour le reste , je ne comprend pas la question...
cordialement,

Didier

[mercatog]

Bonjour
En fin de compte, tu désire mettre à jour les données de Feuil1 à partir de Feuil2.
Tu parcours la colonne des id de Feuil2, si le id existe en Feuil1 tu remplace la ligne correspondante dans Feuil1 par celle de Feuil2, sinon, tu ajoute la ligne de Feuil2 vers la fin de Feuil1.
Ci-joint proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim Sh As Worksheet
Dim LastLig1 As Long, LastLig2 As Long, i As Long
Dim c As Range
 
Application.ScreenUpdating = False
Set Sh = Sheets("Feuil1")
LastLig1 = Sh.Cells(Sh.Rows.Count, "A").End(xlUp).Row
With Sheets("Feuil2")
    LastLig2 = .Cells(.Rows.Count, "A").End(xlUp).Row
    For i = 2 To LastLig2
        Set c = Sh.Range("A2:A" & LastLig1).Find(.Range("A" & i).Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            .Rows(i).Copy c
            Set c = Nothing
        Else
            LastLig1 = LastLig1 + 1
            .Rows(i).Copy Sh.Range("A" & LastLig1)
        End If
    Next i
End With
Set Sh = Nothing

[pingoui]

Impeccable, merci beaucoup. Efficace et propre !