Discussion :

[julielef]

bonjour,
je suis nouvelle sur ce forum.
j'ai besoins de votre aide car je pêche un peu sur ma macro.
Je souhaiterai que la valeur "o" contenus dans certaines cellules de la colonne I, se copie automatiquement dans la colonne de gauche (cad la colonne H).
Je ne peut pas mettre de formule dans les cellules de la colonne H...
J'ai commencer une macro qui fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub commandButton3_Click()
 
Range("I21").Select
If Range ("I21")="o" then Range ("H21")="o"
End Sub

Le problème de cette macro, c'est qu'elle prend les cellules une par une, et que j'ai 2000 lignes... Si je continu comme ça, je vais faire 300 000 lignes de conditions... C'est pas ce que je recherche
J'aimerais pouvoir expliquer à l'ordinateur que si dans la colonne I il y a un "o", alors il recopie cet valeur dans la colonne de gauche (ou la colonne H.) Mais je n'y arrive pas...
quelqu'un saurais comment faire??
merci d'avance
julie

[Jean-Philippe André]

Bonjour,

bienvenue sur DVP ,

pour appliquer a un grand nombre de ligne ton test, tu peux passer par une boucle en VBA

La syntaxe est expliquee dans de nombreux tutoriaux, par exemple celui-ci
http://heureuxoli.developpez.com/off...l/?page=page12

un exemple de syntaxe a obtenir :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub commandButton3_Click()
Dim i As Integer
For i=1 to 100
If Range ("I" & i)="o" then Range ("H" & i)="o"
Next i
End Sub

[julielef]

merci a toi d'avoir pris le temps de me répondre,
cette macro fonctionne vraiment bien!!
cependant, je dois faire la même chose avec d'autre colonne (en fait il y a 30 autres colonnes ou je dois faire la même chose)
est ce que je recopie la macro 30 fois d'affiler??
merci de ma répondre...
julie

[Philippe Tulliez]

Bonjour,
Toujours en utilisation de boucles mais les solutions sont multiples.
Tu parles de 30 colonnes. Sont-elles contigües, si elles sont non contigües, l'écart entre colonnes est-il fixe (toutes les 3 colonnes par exemples) ?
Voici un exemple de code qui va parcourir les colonnes I à U (soit 9 à 21) avec un pas de 2 colonnes et les lignes de 1 à 100 de ces colonnes en modifiant les valeurs de la colonne qui précède si la condition est remplie.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub commandButton3_Click()
 Dim Colonne As Long, Ligne As Long
  ' Parcours toutes les 2 colonnes (I à U)
  For Colonne = 9 To 21 Step 2
    For Ligne = 1 To 100
      If Cells(Ligne, Colonne) = "o" Then Cells(Ligne, Colonne - 1) = "o"
    Next Ligne
  Next Colonne
End sub

On peut aussi utiliser la boucle For Each In Next

[julielef]

aie
mon dossier est trop gros pour que je puisse le mettre sur le forum.
Comment faire???

[Theze]

Bonjour tout le monde,

Il est vrai que les explications de Julie sont plutôt floues mais Julie, est-ce que tu veux que la modif commence par la colonne correspondant à la date entrée en AR15 ? Voir le code ci-dessous, adapter la plage de recherche si ce n'est pas la 1ère ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Private Sub CommandButton3_click()
 
    Dim Colonne As Long, ligne As Long
    Dim Debut As Integer
 
    'date en AR15 cherchée dans la 1ère ligne à partir de H1 jusqu'à BR1
    On Error Resume Next
    Debut = Range("H1:BR1").Find(Range("AR15"), , xlValues).Column
 
    'si pas d'erreur, la date existe et le bouclage commence à partir
    'de la colonne où se trouve la date cherchée en AR15
    If Err.Number = 0 Then
 
        For Colonne = Debut To 71 Step 2
 
            For ligne = 1 To 1000
                If Cells(ligne, Colonne) = "o" Then Cells(ligne, Colonne - 1) = "o"
            Next ligne
 
        Next Colonne
 
    End If
 
End Sub

Hervé.

[casefayere]

Bien,
D'après ce que j'ai eu l'occasion de voir (le fichier, trop lourd à joindre), je pense que la solution se trouve avec ce code sachant que je n'ai pas pris la méthode "find" pour la recherche de date mais une boucle (find trop aléatoire)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CommandButton2_Click()
Dim Colonne As Range, ligne As Long, CelDate As Range
Dim Dte As Single, cel As Range, plage As Range
 
With Sheets("grille de suivi médicaments")
   Set CelDate = .Range("AP9")' la date est en AP9 et non AR15
   Set plage = .Range("F14:BP14")'ici tu as une plage avec tes dates
   If IsDate(CelDate) Then
      Dte = CDate(CelDate)
      For Each cel In plage
         If cel = Dte Then
            For ligne = 15 To 1131
               If Cells(ligne, cel.Column) = "o" Then Cells(ligne, cel.Column - 1) = "o"
            Next ligne
         End If
      Next cel
   End If
End With
End Sub

Il te reste, Julie, à affiner ce code (est-ce bien la colonne précédente ou la suivante, à mettre à jour?)

en attendant, bonne soirée

PS : je me suis permis de changer quelques formules sur ton fichier que je vais te renvoyer, je n'ai pas regardé les formules se référants aux autres feuilles
ci-dessous, image de la feuille concernée :