Discussion :

[celeborn56]

bonjour,
débutant en flash je cherche s'il est possible de faire une copie écran d'une application flash.
J'ai créé un dessin que l'on peut colorier en ligne et je voudrais sauvegarder ce dessin sur un serveur, je pensais donc faire une copie écran d'une zone définie en xy et hauteur, largeur, mais je ne trouve point. Quelqu'un pourrait-il éclairer ma lanterne ?
merci pour votre aide
Thierry

[beekeep]

Bonjour,

une solution pour enregistrer une image à partir d'un display object :

Code AS3 :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
package Utils
{
    import com.adobe.images.JPGEncoder;
 
    import flash.display.BitmapData;
    import flash.display.DisplayObject;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.*;
    import flash.utils.ByteArray;
 
    public class ImageManager
    {
        public static function SaveToJpg(object:DisplayObject, p_sFileName:String):void
        {
            var jpgSource:BitmapData = new BitmapData(object.width, object.height);
            jpgSource.draw(object);
 
            var jpgEncoder:JPGEncoder = new JPGEncoder(85);
            var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
 
            var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
            var jpgURLRequest:URLRequest = new URLRequest("save_jpg.php?name=" + p_sFileName + ".jpg");
 
            jpgURLRequest.requestHeaders.push(header);
            jpgURLRequest.method = URLRequestMethod.POST;
            jpgURLRequest.data = jpgStream;
 
            var jpgLoader:URLLoader = new URLLoader();
 
            jpgLoader.addEventListener(Event.COMPLETE, SaveToJpg_loadSuccessHandler);
            jpgLoader.addEventListener(IOErrorEvent.IO_ERROR, SaveToJpg_loadErrorHandler);
 
            jpgLoader.load(jpgURLRequest);
        }
 
        private static function SaveToJpg_loadSuccessHandler(event:Event):void
        {
            trace("Load result : " + event.target.data.toString());
        }
 
        private static function SaveToJpg_loadErrorHandler(event:IOErrorEvent):void
        {
            trace("Error");
        }
    }
}

Code PHP :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
<?php
 
if ( isset ( $GLOBALS["HTTP_RAW_POST_DATA"] ))
{    
    file_put_contents($_GET['name'], $GLOBALS["HTTP_RAW_POST_DATA"]);
 
    echo "image saved";
 
}else{
    echo "error : no data";
}
 
?>

[Lorenzo77]

si ton code est pour >=FP10, la partie qui envoie les données au PHP n'est pas obligatoire, il suffit d'utiliser un FileRefence.save() sur le ByteArray renvoyé par JPGEncoder ou PNGEncoder (voir as3corelib) : http://help.adobe.com/fr_FR/Flash/CS...lasses=1#save()

[savoirnet]

J'avais le même problème et en copiant votre réponse, j'ai réussi, merci à vous.