Discussion :

[fxbrg]

Bonsoir,

Je n'arrive pas à savoir si c'est un problème de faisabilité ou si je m'y prends comme un manche (ou les deux!! lol)

J'ai une requête Access paramétrée basée sur un formulaire. Elle se lance en fonction de 3 paramètres (combobox), ça marche nickel.

En fonction de cette requête (par le biais d'un .rowsource ), je renseigne un 4éme combobox, dont je veux faire à son tour un paramètre.

Comment puis-je utiliser ce 4ème paramètre sur la requête en cours? J'ai essayé de créer un recordset genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
strq="select * from marequete where param4=macombobox"
set rst=currentdb.OpenRecordset(strq)

mais j'ai un message d'erreur me disant que trop peu de paramètres sont entrés (3, ce qui correspond aux paramètres de la requête). Or le formulaire est bien ouvert, (si je teste la requête, elle fonctionne et est bien fonction du formulaire).

Bref, votre aide est bienvenue, merci d'avance!!

JFB

[fxbrg]

Re :-)

Je viens de divaguer sur une solution trouvée sur le forum, vraiment pas belle, mais fonctionnelle...

Ma requete parametrée et enregistrée : rq_pxle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Set qry = CurrentDb.CreateQueryDef("test", "select gamme from rq_pxle group by gamme")
DoCmd.OpenQuery "test"
Set rst = Screen.ActiveDatasheet.Recordset
rst.MoveFirst: MsgBox rst(0) (juste pour essayer...)
CurrentDb.QueryDefs.Delete "test"
rst.Close: Set rst = Nothing
DoCmd.Close acQuery, "test"

Je suis sûr qu'il y a mieux, la nuit porte conseil...

Merci d'avance,

JFB

[belu33fr]

Bonjour,
Si j'ai bien compris:
- Tu as un formulaire qui s'ouvre sans requete au depart
- Dans ce formulaire, tu as 3 combo qui, lorsque tu selectionnes quelquechose dedans, constituent une requete qui devient le recordsource de ton formulaire
- Dans ce meme formulaire, tu as une 4ieme combo dont le rowsorce est lui aussi la requete de ton formulaire
- Lorsque tu selection dans ce 4ieme, il contitue une requete qui devient le recordsource de ton formulaire
Est-ce cela?

[stigma]

Essaye ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

set rst=currentdb.OpenRecordset=("select * from marequete where param4 = " & macombobox & "")

A condition que macombobox soit en numerique. si c'est un string, remplacer " par & Chr(34) &

[fxbrg]

Bonjour,
Belu : la requête n'est pas la source de mon formulaire (il est dépendant d'une table articles). J'explique : j'ai une (très) longue table de prix. Grâce aux 3 premières combo je fais un premier tri avec la requête paramétrée enregistrée.

J'extrais ensuite de la requête la liste des fabricants des "prix" restants, que j'utilise comme rowsource d'une 4éme combobox. En fonction de ce 4eme choix, je veux encore affiner la requête - un fabricant peut propose x gammes, alors qu'un autre non, etc (et ce, plusieurs fois, j'ai plein de critères), pour finir par n'avoir plus qu'un prix... mais je ne veux pas toujours récupérer des infos pour une combobox, parfois ce sont des cases à cocher, d'autres des Options.

D'où l'idée de me servir de la requête initiale comme source de données - recordset (en plus c'est une requête avec des Join, en sql elle fait trois pages!! lol), filtrée à chaque fois du nouveau critère.

Stigma : c'est exactement ce que je fais (sans le = après recordset) et qui ne fonctionne pas... parce que la requête est paramétrée - erreur trop peu de paramètres...bien qu'elle soit lancée avant l'appel!

Je vais sans doute m'orienter vers une concaténation de clauses Where - même avec mes join, mais c'est dommage qu'on ne puisse récupérer cette requête, ça va m'obliger à écrire plein de fois la même chose, pas très propre...

Merci de votre aide, en tout cas,

Amicalement,

JFB

[=JBO=]

Bonjour,

[...]
D'où l'idée de me servir de la requête initiale comme source de données - recordset (en plus c'est une requête avec des Join, en sql elle fait trois pages!! lol), filtrée à chaque fois du nouveau critère.
[...]
Je vais sans doute m'orienter vers une concaténation de clauses Where - même avec mes join, mais c'est dommage qu'on ne puisse récupérer cette requête, ça va m'obliger à écrire plein de fois la même chose, pas très propre...

Le problème auquel tu te retrouves confronté est que Access sait évaluer une requête comportant des expressions qui désignent un contrôle de formulaire; en revanche DAO/ADO/Jet ne connaissent pas Access et toute expression non reconnue par leur évaluateur est considérée comme un paramètre.

Il y a un remède simple qui consiste à faire appel à la fonction Eval() qui rend le contrôle à Access pour évaluer ces expressions.

Ainsi, dans ta requête, au lieu du code suivant:

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

select * from marequete where param4=Forms!MonFormulaire!MaComboBox

Tu peux écrire:

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

select * from marequete where param4=Eval("Forms!MonFormulaire!MaComboBox")

Evidemment, ce n'est pas très pratique de réécrire toutes les requêtes qui sont basées sur des formulaires.
Alors il est possible de réutiliser leur code SQL comme expliqué dans cette discussion:
http://www.developpez.net/forums/d21...quete-critere/

Tu peux aussi lire cette discussion en anglais qui propose une fonction générique pour ouvrir un Recordset, à partir d'une requête Access ou d'une requête SQL:
http://www.utteraccess.com/forums/sh...ll#Post1627801

Je te donne ci-dessous le code "complet" de la fonction générique permettant d'ouvrir un Recordset DAO à partir d'une requête basée sur des "paramètres de formulaires" et/ou "paramètres demandés à l'utilisateur".
C'est la synthèse des 2 discussions mentionnées ci-dessus:

[EDIT]
J'ai amélioré la fonction générique:
* gestion d'erreur (un peu) plus complète,
* modification de la syntaxe d'expression "francophone" pour qu'elle se conforme à la syntaxe anglo-saxonne.
[/EDIT]

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Public Function GenericOpenRecordset(strSQL As String, _
                            Optional intType As DAO.RecordsetTypeEnum = dbOpenDynaset, _
                            Optional intOptions As DAO.RecordsetOptionEnum, _
                            Optional intLock As DAO.LockTypeEnum, _
                            Optional pdb As DAO.Database) As DAO.Recordset
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim rst As DAO.Recordset
    Dim prm As DAO.Parameter
    Dim sExpr As String
 
    If Not pdb Is Nothing Then
        Set db = pdb
    Else
        Set db = CurrentDb
    End If
 
    On Error Resume Next
 
    Set qdf = db.QueryDefs(strSQL)
    If Err = 3265 Then
        Set qdf = db.CreateQueryDef("", strSQL)
    End If
 
    For Each prm In qdf.Parameters
        Err.Clear
 
        sExpr = prm.Name
        sExpr = Replace(sExpr, "[Formulaires]!", "Forms!")
        sExpr = Replace(sExpr, "Formulaires!", "Forms!")
 
        prm.Value = Eval(sExpr)
 
        Select Case Err.Number
        Case 2482, 2450
            ' 2482 = Paramètre non évaluable.
            ' 2450 = Impossible de trouver le formulaire auquel il est fait référence
            '        dans une expression de macro ou un code Visual Basic.
            ' Demande la saisie du paramètre dans une inputbox
            prm.Value = InputBox(prm.Name)
        End Select
    Next
 
    On Error GoTo 0
 
    If intOptions = 0 And intLock = 0 Then
        Set rst = qdf.OpenRecordset(intType)
    ElseIf intOptions > 0 And intLock = 0 Then
        Set rst = qdf.OpenRecordset(intType, intOptions)
    ElseIf intOptions = 0 And intLock > 0 Then
        Set rst = qdf.OpenRecordset(intType, intLock)
    ElseIf intOptions > 0 And intLock > 0 Then
        Set rst = qdf.OpenRecordset(intType, intOptions, intLock)
    End If
    Set GenericOpenRecordset = rst
 
    Set prm = Nothing
    Set rst = Nothing
    Set qdf = Nothing
    Set db = Nothing
 
End Function

[Jean-Philippe André]

Bonjour,

en complément de la solution proposée par =JBO=,
je recommande la lecture de la à ce sujet :
http://access.developpez.com/faq/?page=zdl#DepZdl

l'adaptation au cas présent étant toute tracée

[fxbrg]

Re :-)

Je savais que c'était possible, un grand merci =JBO=!! (le pro?)

Mais...

La solution avec Eval ne fonctionne pas, puisque ce n'est pas le param4 qui pose problème, mais la lecture de la requête enregistrée et avec critères (rq_pxle).

J'essaie de mettre en oeuvre la fonction générique pour ouvrir le recordset, mais ça coince...

Juste pour que je sois sûr : je passe en paramètre le nom de ma requête, right?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set rst2 = GenericOpenRecordset("rq_pxle")
MsgBox rst2(0)
rst2.Close: Set rst = Nothing

J'ouvre mon formulaire, je rentre les critères... Si je lance la requête à la main, elle fonctionne. Si je lance le code ci-dessus, j'ai d'abord autant de InputBox qu'il y a de critères (c'est le bout de code Err 2482), puis bien sûr, un message me disant qu'il n'y a pas d'enregistrement (je valide les InputBox en faisant OK, sans rien entrer).

Que peut-il bien se passer...?

[=JBO=]

Re-Bonjour,

Aie aie aie... ça coince !

La solution avec Eval ne fonctionne pas, puisque ce n'est pas le param4 qui pose problème, mais la lecture de la requête enregistrée et avec critères (rq_pxle).

Laissons momentanément de côté la solution avec Eval(), mais sache qu'elle fonctionne toujours... (1) si on sait où écrire l'appel à Eval() et (2) si le formulaire est ouvert et renseigné

J'essaie de mettre en oeuvre la fonction générique pour ouvrir le recordset, mais ça coince...

Juste pour que je sois sûr : je passe en paramètre le nom de ma requête, right?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set rst2 = GenericOpenRecordset("rq_pxle")
MsgBox rst2(0)
rst2.Close: Set rst = Nothing

Oui, c'est comme ça qu'il faut s'y prendre !

J'ouvre mon formulaire, je rentre les critères... Si je lance la requête à la main, elle fonctionne. Si je lance le code ci-dessus, j'ai d'abord autant de InputBox qu'il y a de critères (c'est le bout de code Err 2482), puis bien sûr, un message me disant qu'il n'y a pas d'enregistrement (je valide les InputBox en faisant OK, sans rien entrer).

Là il y un problème...
Normalement, aucun InputBox() ne devrait s'ouvrir si Eval() "retrouve" le formulaire et les contrôles référencés dans la requête.

A contrôler impérativement:

(1) Est-ce que la fonction GenericOpenRecordset() est bien exécutée à partir du VBA d'Access ???

(2) la syntaxe d'accès aux contrôles du formulaire respecte-t-elle les conventions:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Forms!LeNomDuFormulaire!LeNomDuContrôle

Si les noms du formulaire ou du contrôle comportent des caractères spéciaux (par exemple le caractère espace) il faut alors les encadrer de crochets:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Forms![LeNomDuFormulaire]![LeNomDuContrôle]

Au passage, j'ai amélioré la gestion d'erreur de la fonction "générique-magique" (traitement de l'erreur 2450).
_

[fxbrg]

Ben vi, ça coince...

(1) tout se passe dans Access
(2) un exemple du critère : [Formulaires]![dev_ART_LE]![dimensions]
pas d'accent, pas d'espace...

Pour info, tout est dans un même module, lancé par un bouton test sur le formulaire.

Là il y un problème...
Normalement, aucun InputBox() ne devrait s'ouvrir si Eval() "retrouve" le formulaire et les contrôles référencés dans la requête.

Ben voui, ya un os...
Et pour raccrocher à ton commentaire disant que Eval fonctionne toujours, que fait Eval exactement?

Un grand merci pour ton aide et ta patience!! :-)

[=JBO=]

Alors je crois que la "coinçitude" est encore due à notre singularité francophonistique... (ça rime avec informatique )

(2) un exemple du critère : [Formulaires]![dev_ART_LE]![dimensions]
pas d'accent, pas d'espace...

Il faudrait utiliser la syntaxe anglo-saxonne, comme dans les exemples donnés plus haut.
Dans ton cas, pourrais-tu essayer cette syntaxe et nous dire ce qu'il en est ?

Code Expression Access :

Sélectionner tout - Visualiser dans une fenêtre à part

[Forms]![dev_ART_LE]![dimensions]

Si c'est bien là le souci, alors 3 remèdes possibles:
* tout corriger à la main (avec tes doigts sur le clavier);
* développer une moulinette qui fait la correction de syntaxe dans tous les formulaires et toutes les requêtes concernés;
* modifier la fonction générique-magique pour rectifier la syntaxe "à la volée".
__ [EDIT]modification effectuée dans le message qui contient la fonction "générique-magique"[/EDIT]

Et pour raccrocher à ton commentaire disant que Eval fonctionne toujours, que fait Eval exactement?

Relis mes messages précédents je te prie.
Eval() est une des fonctions d'Access utilisables en VBA et dans les requêtes SQL.
Cette fonction Access opère sur une chaîne de caractères, qui doit être une expression valide, tente de l'évaluer et retourne le résultat de l'évaluation.
Tu peux l'expérimenter dans l'environnement de développement intégré (EDI) de VBA, en faisant des tests dans la fenêtre de débogage.

Exemple de test simplissime (pour voir)... je crois que tu connais déjà le résultat de l'évaluation :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

? Eval("1+1")

Par exemple, essaie les différentes syntaxes:

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
? Eval("[Formulaires]![dev_ART_LE]![dimensions]")
? Eval("[Forms]![dev_ART_LE]![dimensions]")
? Eval("Forms!dev_ART_LE!dimensions")

Et pense à lire l'aide en ligne qui est claire.
_

[fxbrg]

Alors celle-là, je risquais pas de la trouver!!

Effectivement, avec les Forms au lieu de Formulaires, ça fonctionne... je suis scié! mais content :-)

Je reconnais que j'ai été un peu fainéant pour le coup de Eval, j'aurais du lire l'aide, mais comme je te sentais bien parti... non , je déconne, j'apprécie, comme disent les Anglo Saxons! Et je viens de faire les tests que tu proposes (sauf le premier... :-), c'est très clair (je suppose que les deux dernières lignes donnent le même résultat parce qu'il n'y a pas de caractères interdits et que du coup les crochets ne servent à rien?)

Et je vais peut-être dire une grosse connerie, mais EDI j'ai pas... il faut que je télécharge une version de Visual Studio Express? Personne me dit rien...

En tout cas un immense merci, pour ta patience, la clarté de tes explications, l'étendue de ton savoir (et on n'a du qu'effleurer la surface de l'iceberg), ton sens de l'humour et ta volonté de partager! Je voulais le dire, c'est fait!

Amicalement,

JFB

[=JBO=]

Merci de ton Merci

volonté de partager

C'est le bon côté des forums en général, et de DVP en particulier !

Effectivement, avec les Forms au lieu de Formulaires, ça fonctionne... je suis scié! mais content :-)

J'ai modifié la fonction générique pour qu'elle fasse la correction à la volée (nul besoin d'aller modifier toutes les requêtes, ouf !).

Et je vais peut-être dire une grosse connerie, mais EDI j'ai pas... il faut que je télécharge une version de Visual Studio Express? Personne me dit rien...

Depuis la version 2000 d'Access, les procédures VBA sont développées au sein d'un environnement spécifique dérivé de celui de Visual Basic.
C'est ça l'EDI... Ok !?

Bonne continuation.
_