Discussion :

[argyronet]

Bonjour,

j'ai un message d'erreur 2471, "l'expression entrée comme paramètre de requête est à l'origine de l'erreur suivante : "Attach_State"".
je comprend à peu près le problème c'est au niveau de la table TBLSystemApp, les champs de table en question n'ont pas été bien spécifiés dans ton post pour nous qui ne sommes pas trop avancés en vba.
voici les champs je retiens (IDKey, Attach_State)

Désolé, je n'ai pas compris ta demande...
Sauf erreur de ma part, il semble que tu considères que j'ai en ma possession toutes les applications du monde dont la tienne et que je peux te donner le pourquoi de l'erreur que tu rencontres ?
Eh bien non...

Si tu veux de l'aide il va falloir être un peu plus explicite.

Argy

[abdoulrazak434]

ok compris,je voudrais lier ma base frontale à la dorsale, en fait j’essaie exactement d'utiliser votre code argyronet, alors j'ai crée un formulaire et j'ai copier et coller votre code dans le load du formulaire bien entendu dépourvu de tous champs comme vos l'avez dit. et ensuite créer la table TBLSystemApp je ne sais pas reelement quels sont les champs de la table en question et surtout leur type.
en d'autre termes j'ai pas bien compris l'utilisation de cette table. espérant être un peu plus clair.

D'avance merci et très cordialement

[argyronet]

Ah oui, je me souviens...
C'est un code exemple.
A toi de configurer le code en fonction des tables que tu veux lier et celle qui sont locales (pour peu qu'il y en ait mais c'est rare que dans une application, il n'y ait pas quelques tables locales).
Dans mon exemple "TBLParametres" est locale donc pas besoin de la lier et surtout, pas la supprimer ; pour les autres, on les supprime d'abord (on pourrait aussi modifier le lien mais bon à toi de voir ce qui est plus pratique) avant de les rattacher.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
 
 
Public Function ReAttachLinkedTables() As Boolean
Dim oDBFE                                              As dao.Database
Dim oDBBE                                              As dao.Database
Dim oTables                                            As dao.TableDef
Dim intNbTables                                        As Integer
Dim strTableName                                       As String
Dim strDBPath                                          As String
Dim T                                                  As Integer
 
    On Error GoTo ReAttachLinkedTables_Error
    'Le chemin complet de la base sur le serveur
    strDBPath = GetLinkedDatabaseName()
    'Il est préférable d'obtenir le chemin UNC plutôt que la lettre
    'affectée au Map.
 
    Set oDBFE = CurrentDb
    Set oDBBE = DBEngine.OpenDatabase(strDBPath, False, False)
 
    ''' Supprime d'abord toutes les tables liées...
    For Each oTables In oDBFE.TableDefs
        strTableName = oTables.Name
        If Left(strTableName, 3) = TBLPx Then
            Select Case strTableName
                    ', ....Toutes les tables locales à garder
                Case "TBLParametres"
                    ', ... Toutes les tables à lier
                Case "TBLClients", "TBLCommandes"
                    DoCmd.DeleteObject acTable, strTableName
            End Select
        End If
    Next oTables
 
    ''' Relie toutes les tables concernées (lues depuis la base dorsale)
    For Each oTables In oDBBE.TableDefs
        T = T + 1
        strTableName = oTables.Name
        Select Case strTableName
                ', ....Toutes les tables locales à garder
            Case "TBLParametres"
                ', ... Toutes les tables à lier
            Case "TBLClients", "TBLCommandes"
                DoCmd.TransferDatabase acLink, "Microsoft Access", strDBPath, acTable, strTableName, strTableName
        End Select
    Next oTables
 
    ReAttachLinkedTables = True
    On Error GoTo 0
 
ReAttachLinkedTables_Exit:
    If Not oDBBE Is Nothing Then oDBBE.Close
    If Not oDBFE Is Nothing Then oDBFE.Close
    Set oTables = Nothing
    Set oDBBE = Nothing
    Set oDBFE = Nothing
    Exit Function
 
ReAttachLinkedTables_Error:
    ReAttachLinkedTables = False
    Resume ReAttachLinkedTables_Exit
End Function

[B]Attach_State/B] est un champ qui contient une information O/N dans la table Paramètre mais cette table, tu n'en a pas besoin ; c'est dans mon exemple...

Argy

[abdoulrazak434]

bonjour, merci argy, je puisé de gauche à droite et juste adapté votre code mon cas et cela marche très correctement

merci et très cordialement