Discussion :

[edelweisseric]

Bonjour à toutes et tous

Dans une colonne, j'ai des dates de naissance, non triées, avec des cellules vides, comme ceci :
20/08/2008
18/12/1945
18/02/1948
18/09/1987
13/11/1964


30/12/2004
31/01/2005
21/09/1950
18/03/1984
15/08/1983

07/11/1997

31/08/1947

02/09/2000
06/12/2000
27/02/2002
04/11/2003

Je cherche une formule, en "E1" par exemple, qui me donnerait la prochaine date anniversaire. Pour aujourd'hui (14/1/2017) je devrais obtenir "31/01". Il se peut qu'il y ai plusieurs dates (jour/mois) identiques.

Merci d'avance
Eric

[excfl]

A1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=AUJOURDHUI()

Autres dates en colonne A

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(A2:A1000;EQUIV(MIN(ABS(A1-A2:A1000));ABS(A1-A2:A1000);0))

Formule matricielle à valider avec CTRL MAJ ENTREE.
Format : Date

[edelweisseric]

Bonjouur et merci excfl

Perso cela ne fonctionne pas.
J'ai compris ceci :
A1 14/01/2017 => =aujourd'hui
A2 20/08/2008
A3 18/12/1945
A4 18/02/1948
A5 18/09/1987
A6 13/11/1964
A7
A8
A9 30/12/2004
A10 31/01/2005
A11 21/09/1950
A12 18/03/1984
A13 15/08/1983
A14
A15 07/11/1997
A16
A17 31/08/1947
A18
A19 02/09/2000
A20 06/12/2000
A21 27/02/2002
A22 04/11/2003

et ta formule, copiée/collée avec CTRL MAJ ENTREE, me donne, en B1 => la date d'aujourd'hui 14/01/2017
J'ai réduit le "1000" en "22", mais cela donne le même résultat. Où est mon erreur ?

Eric

[papouclo]

Bonjour,
La solution immédiate qui me vient à l'esprit consiste à calculer en colonne B la date du prochain anniversaire pour chaque date de naissance écrite en colonne A. (voir image)
La formule en B2 est :
=SI(A2>0;MOIS.DECALER(A2;12*(ANNEE(AUJOURDHUI())-ANNEE(A2)+(MOIS(AUJOURDHUI())>MOIS(A2))+(MOIS(AUJOURDHUI())=MOIS(A2))*(JOUR(AUJOURDHUI())>JOUR(A2))));"")
à recopier vers le bas.
Une MFC permet de mettre en évidence le minimum de la colonne B donc le prochain anniversaire à venir.

Cordialement
Claude

[78chris]

Bonjour

En matriciel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(($A$2:$A$30<>"")*(DATE(ANNEE(AUJOURDHUI());MOIS($A$2:$A$30);JOUR($A$2:$A$30))>AUJOURDHUI());DATE(ANNEE(AUJOURDHUI());MOIS($A$2:$A$30);JOUR($A$2:$A$30));1000000))

[edelweisseric]

Bonsoir à tous

Messieurs les "émérite" et "éminent" merci pour vos propositions

Claude, ta formule ne fonctionne pas sur 2003 , je n'ai pas vérifié celle de Chris.

Merci
Eric

[papouclo]

Bonjour,
Si on veut toujours obtenir en colonne B la liste des dates anniversaire à venir avec Excel 2003, remplacer ma première formule en B2 par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI($A2<>"";DATE(ANNEE(AUJOURDHUI())+(MOIS(AUJOURDHUI())>MOIS($A2))+(MOIS(AUJOURDHUI())=MOIS($A2))*(JOUR(AUJOURDHUI())>JOUR($A2));MOIS($A2);JOUR($A2));"")

et recopier en colonne B.
La formule de 78chris présente un modèle intéressant (à réinvestir dans d'autres cas): utiliser dans la fonction SI un majorant important comme réponse à donner pour les cas ne respectant pas les critères de choix proposés puisque l'on doit ensuite utiliser la fonction MIN sur la matrice obtenue mais dans le problème posé ici, si par malheur (voir la figure ci après), toutes les dates anniversaires pour l'année courante sont déjà passées (donc inférieures à la date donnée par la fonction AUJOURDHUI), il nous faudra vraiment être patients pour fêter l'anniversaire suivant d'après la réponse obtenue.
On pourra utiliser la fonction matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI($A$2:$A$30<>"";DATE(ANNEE(AUJOURDHUI())+(MOIS(AUJOURDHUI())>MOIS($A$2:$A$30))+(MOIS(AUJOURDHUI())=MOIS($A$2:$A$30))*(JOUR(AUJOURDHUI())>JOUR($A$2:$A$30));MOIS($A$2:$A$30);JOUR($A$2:$A$30));""))

à valider par Ctrl + Maj + Entrée.

Cordialement
Claude

[edelweisseric]

Bonsoir à tous

Testé et adopté

Merci Claude

Aric