Discussion :

[Etienne Bureau]

Bonjour à tous,

Je n'arrive pas à trouver la solution au problème posé ci dessous:

J'ai en colonne A une liste de code. Certains possèdent en 5ème position un "/".

Selon le modèle ci dessous, je voudrais, pour chaque ligne où l'on retrouve le"/" en 5ème position que la colonne B me donne le nombre de cellules ou de lignes au dessus et adjacentes qui possèdent le "/" en 5ème position.
De la même façon, la colonne C me renverrait le nombre de cellules ou de lignes mais en dessous et adjacentes.

A	B	C
xx	RIEN	RIEN
2016/5645	0	2
2016/5645	1	1
2016/5645	2	0
xx	RIEN	RIEN
x/x	RIEN
2016/5645	0	1
2016/5645	1	0
xxf/	RIEN

J'imagine que ça doit être possible via une formule matricielle mais je n'y suis pas arrivé.
Idem VBA, j'ai pensé compter la plage sélectionnée jusqu'à interruption du critère (Do while?) mais pas les connaissances nécessaires .

Merci pour votre aide.

Cordialement

[casefayere]

Bonsoir,
les données de la plage en A2, C & autant que tu veux, titres en ligne 1
un exemple entre autres

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub test()
Dim Dcel As Range, N As Long, x As Long, y As Long
  With Sheets("Feuil1")
    Set Dcel = .Range("A" & .Rows.Count).End(xlUp)
    For y = Dcel.Row To 2 Step -1
      N = 0
      If Mid(.Range("A" & y), 5, 1) = "/" Then
        For x = y - 1 To 1 Step -1
          If Mid(.Range("A" & x), 5, 1) = "/" Then
            N = N + 1
          Else
            Exit For
          End If
        Next x
        If N = 0 Then
          .Range("B" & y) = 0
        Else
          .Range("B" & y) = N
        End If
      Else
        .Range("B" & y) = "RIEN"
      End If
    Next y
    '---colonne C
    For y = 2 To Dcel.Row
      N = 0
      If Mid(.Range("A" & y), 5, 1) = "/" Then
        For x = y + 1 To Dcel.Row
          If Mid(.Range("A" & x), 5, 1) = "/" Then
            N = N + 1
          Else
            Exit For
          End If
        Next x
        If N = 0 Then
          .Range("C" & y) = 0
        Else
          .Range("C" & y) = N
        End If
      Else
        .Range("C" & y) = "RIEN"
      End If
    Next y
  End With
End Sub

si beaucoup de lignes, passer par une variable tableau

[Etienne Bureau]

Merci Casefayere ça fonctionne impec!

Encore une petite question, si je voulais construire une "function" pour la colonne B ou C à renseigner dans chaque cellule pour que ce soit dynamique, comment devrais-je m'y prendre?


Cordialement

[casefayere]

je regarderai ce soir, là je n'ai pas le temps, avec ce que j'ai présenté, je pense que deux fonctions seront nécessaires, une pour col B une pour C

[Etienne Bureau]

Ok merci beaucoup pour ton temps et ton aide

[casefayere]

j'en suis là, fonctions personnalisées
fonction pour col B

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function Slasch1(ByVal Target As Range) As String
 
'Target représente la cellule à analyser
 
Dim N As Long, x As Long, y As Long
y = Target.Row
N = 0
For x = y To 2 Step -1
  If Mid(Cells(x, 1).Value, 5, 1) <> "/" Then
    Exit For
  Else
    N = N + 1
  End If
Next x
If N = 0 Then Slasch1 = "RIEN": Exit Function
If N = 1 Then Slasch1 = 0: Exit Function
Slasch1 = N - 1
End Function

fonction pour col C

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Function Slasch2(ByVal Target As Range) As String
 
'Target représente la cellule à analyser
 
Dim N As Long, x As Long, y As Long, Dcel As Long
y = Target.Row
Dcel = Cells(Rows.Count, Target.Column).End(xlUp).Row
N = 0
For x = y To Dcel
  If Mid(Cells(x, 1).Value, 5, 1) <> "/" Then
    Exit For
  Else
    N = N + 1
  End If
Next x
If N = 0 Then Slasch2 = "RIEN": Exit Function
If N = 1 Then Slasch2 = 0: Exit Function
Slasch2 = N - 1
End Function

si tu ne veux pas que les résultats soient des "String" pour les chiffres, il suffit de l'enlever

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Function Slasch1(ByVal Target As Range)

à la place de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Function Slasch1(ByVal Target As Range) As String

Pour choisir le signe en remplacement de "/"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function Slasch1(ByVal Target As Range, Sep As String)
......
......
For x = y To 2 Step -1
  If Mid(Cells(x, 1).Value, 5, 1) <> Sep Then
....
....

Pour choisir le signe en remplacement de "/" et sa position

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function Slasch1(ByVal Target As Range, Sep As String, P As Integer)
.....
.....
For x = y To 2 Step -1
  If Mid(Cells(x, 1).Value, P, 1) <> Sep Then
......
.....

Dis-moi tout

[Etienne Bureau]

Merci,
c'est exactement ce dont j'avais besoin.

Top!

Cordialement

[casefayere]

j'en suis ravi et si tu veux me ravir un peu plus, regardes la dernière ligne de ma signature

Bonne soirée