Discussion :

[Nomorerulz]

Bonjour à tous,

J'essaie présentement de faire ajuster plusieurs colonnes de formule en fonction du nombre de lignes dans le fichier qui est variable en fonction de l'extraction de données quotidienne.

Voici ce que j'ai en ce moment.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
'---------------Erase the data in sku range in "toolMexico" tab------------------------------------------------------------------------------------------
    Worksheets("toolMexico").Activate
    Range("E14").Select
    Range(Selection, Selection.End(xlDown)).Select
    Range(Selection, Selection.End(xlToRight)).Select
    Selection.ClearContents
 
'---------------Extend the formulas to the end of the sku range in "toolMexico" tab----------------------------------------------------------------------
    Range("E12").Select
    Range(Selection, Selection.End(xlDown)).Select
    Range(Selection, Selection.End(xlToRight)).Select
    Selection.AutoFill Destination:=Range("E12:CJ137")

Je bloque à la dernière ligne.
J'aimerais que le range s'ajuste en fonction du nombre de colonne, mais je ne sais pas comment adapter ce bout de code.
Vos suggestions sont les bienvenues.

Merci d'avance,
Nomorerulz

[gFZT82]

Bonjour,

Essaie comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim Plage As Range
'---------------Erase the data in sku range in "toolMexico" tab------------------------------------------------------------------------------------------
    With Worksheets("toolMexico")
        Set Plage = .Range(.Range("E14"), .Range("E14").End(xlToRight))
        .Range(Plage, Plage.End(xlDown)).ClearContents
'---------------Extend the formulas to the end of the sku range in "toolMexico" tab----------------------------------------------------------------------
        With Plage.Offset(-2).Resize(2)
            .AutoFill Destination:=.Resize(126)
        End With
        Set Plage = Nothing
    End With

Cordialement.

[vinc_bilb]

Bonjour

Vous pouvez passer par le current region (similaire au Ctrl + * sous Excel), par exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Set InpRng = Worksheets("toolMexico"). Range("E14").CurrentRegion
Debug.Print InpRng.Address, InpRng.Rows.Count

[Invité]

bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
With Sheets("Feuil1")
   With .Range(.Cells(14, "E"), .Cells(.UsedRange.Rows.Count, "E"))
        .ColumnWidth = 100
        .EntireRow.AutoFit
        .EntireColumn.AutoFit
    End With
End With
End Sub

[Nomorerulz]

Bonjour à tous,

Tout d’abord, merci pour vos nombreuses réponses.

gFZT82,
Le code que vous m'avez fournit marche à merveille, mais il cesse d'ajuster après 126 lignes.
Y aurait-il un moyen d'adapter ce code pour le rendre dynamique?

vinc_bilb,
J'ai tenté d'intégrer votre code au mien, mais je crois passer à côté de quelque chose.
Je n'ai pas beaucoup d'expérience en vba et je crains ne pas savoir comment l'adapter correctement.

rdurupt,
Le code que vous avez indiqué semble traiter l'autofit des cellules.
Or, j'ai besoin d'aide pour ajuster l'autofill de manière dynamique.
Ai-je raison ou suis-je passé à côté de l'essentiel?

Votre aide à tous est très appréciée!
Nomorerulz

[Invité]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
With Sheets("Feuil1")
   With .Range(.Cells(14, "E"), .Cells(.UsedRange.Rows.Count, .UsedRange.Columns.Count))
        .ColumnWidth = 100
        .EntireRow.AutoFit
        .EntireColumn.AutoFit
    End With
End With
End Sub

[Nomorerulz]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
With Sheets("Feuil1")
   With .Range(.Cells(14, "E"), .Cells(.UsedRange.Rows.Count, .UsedRange.Columns.Count))
        .ColumnWidth = 100
        .EntireRow.AutoFit
        .EntireColumn.AutoFit
    End With
End With
End Sub

Ai-je besoin d'ajouter quelque chose à ceci?
Lorsque je met le code en place, les formules restent en place et rien n'est descendu vers le bas.
Ceci semble ajuster la taille de mes cellules.

Désolé si je n'ai pas bien saisi ce que vous tentez de m'enseigner.

Nomorerulz

[gFZT82]

gFZT82,
Le code que vous m'avez fournit marche à merveille, mais il cesse d'ajuster après 126 lignes.
Y aurait-il un moyen d'adapter ce code pour le rendre dynamique?

Dans la première partie, tu effaces les données depuis la ligne 14 et jusqu'à la dernière ligne renseignée.
Dans la deuxième partie, tu effectues une recopie incrémentée des données des lignes 12 et 13 mais rien ne permet de définir jusqu'à quelle ligne doit s'effectuer cette recopie.
Il manque des indications sur la structure de la feuille et la finalité du traitement pour permettre de déterminer cette limite de la plage... et c'est pour cela que j'ai conservé la plage initiale de 126 lignes (ligne 12 à 137).

Cordialement.

[Nomorerulz]

Je comprends, je n'ai effectivement pas précisé cela.
Il faut que ces deux lignes soient collées jusqu'à égalité de la dernière cellule de la colonne D.
Il est facile de le faire à la main en sélectionnant la plage et en double cliquant, car il n'y a pas d'espacement dans la colonne D.
Par contre, je désire automatiser ceci dans une macro puisque ceci fait partit d'un autre procédé.
Quel moyen devrais-je utiliser pour déterminer la dernière cellule de la colonne D pour l'indiquer dans votre code en lieu de l'écart initial?

Merci,
Nomorerulz

[gFZT82]

La dernière ligne est déterminée par la ligne de code
DerLig = .Range("D" & Rows.Count).End(xlUp).Row

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim Plage As Range
Dim DerLig As Long
'---------------Erase the data in sku range in "toolMexico" tab------------------------------------------------------------------------------------------
    With Worksheets("toolMexico")
        DerLig = .Range("D" & Rows.Count).End(xlUp).Row
        Set Plage = .Range(.Range("E14"), .Range("E14").End(xlToRight))
        .Range(Plage, Plage.End(xlDown)).ClearContents
'---------------Extend the formulas to the end of the sku range in "toolMexico" tab----------------------------------------------------------------------
        With Plage.Offset(-2).Resize(2)
            .AutoFill Destination:=.Resize(DerLig - 11)
        End With
        Set Plage = Nothing
    End With

Cordialement.

[Nomorerulz]

gFZT82,

Merci énormément

ça ne pourrait pas mieux fonctionner!

Je vous souhaite une belle journée,
Nomorerulz