Discussion :

[nonesofar]

Bonjour,

Je souhaite avec le tutoriel developpez.net lire dans un fichier fermé en vba.

http://silkyroad.developpez.com/VBA/...ursFermes/#LII

j'ai copié ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub RequeteClasseurFerme()
    Dim Cn As ADODB.Connection
    Dim Fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
 
    'Définit le classeur fermé servant de base de données
    Fichier = "C:\Users\ho.rgrange\Documents\test vba\tes_case.xlsx"
    'Nom de la feuille dans le classeur fermé
    NomFeuille = "Feuil1"
 
    Set Cn = New ADODB.Connection
 
    '--- Connection ---
    With Cn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & Fichier & _
            ";Extended Properties=Excel 8.0;"
        .Open
    End With
    '-----------------
 
    'Définit la requête.
    '/!\ Attention à ne pas oublier le symbole $ après le nom de la feuille.
    texte_SQL = "SELECT * FROM [" & NomFeuille & "$]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    'Ecrit le résultat de la requête dans la cellule A2
    Range("A2").CopyFromRecordset Rst
 
    '--- Fermeture connexion ---
    Cn.Close
    Set Cn = Nothing
 
End Sub

J'ai ce message d'erreur juste aprés le .open !



je ne comprends pas ce message, provient-t-il de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Extended Properties=Excel 8.0

En effet j'utilise excel 2013.

En vous remerciant par avance pour vos lumiéres.

Cordialement.

[kiki29]

Salut, eh oui si 2007 ou +, voir ici

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    With Cn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" _
            & Fichier & ";Extended Properties=""Excel 12.0;HDR=YES;"""
        .Open
    End With

[nonesofar]

Hello,

Merci kiki29 super réponse et super efficace.

it's working.

Passe en résolu et bonne journée.