Discussion :

[patner]

Bonjour, à toutes et à tous,

Je mets en place une gestion des stocks avec Access 2010.
j'ai utilisé la base Access qui se trouve au lien ci-dessous( je tiens à remercier encore une fois de plus Claude Leloup pour son tuto):

http://claudeleloup.developpez.com/t...tion-de-stock/

Ma question est la suivante :
je souhaiterai afficher un message d'alerte "Attention : veuillez ravitailler le stock pour cet article!"
Quand la quantité de l'onglet Stock Actuel est <=10 sinon masquer mon message.

je sais mettre en place l'alerte, mais je ne sais pas sur quelle étiquette je dois appliquer ma macro.
j'ai essayé de mettre ma macro sur "txtStock" et j'ai un Bug qui me bloque totalement le fonctionnement
de la base.

Pouvez-vous svp m'aider dans ce sens.

Merci d'avance pour votre aide.
Cordialement
Patner

[Malick]

Il faut compléter ce code de Claude comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub CboArticle_AfterUpdate()
  Dim Alerte As String
  'Afficher l'historique
  Me.CTNRsfSortiesDetail.Form.Requery
 'Rendre visibles les contrôles pour l'encodage d'une nouvelle sortie
  Me.txtDate.Visible = True
  Me.txtQuant.Visible = True
  Me.txtImputation.Visible = True
  Me.txtDate = Null
  Me.txtQuant = Null
  Me.txtImputation = Null
  DoCmd.GoToControl "txtDate"
  'Afficher le stock actuel de cet article
  Me.txtStock = StockADate(Me.CboArticle, Format(Date, "mm/dd/yyyy"))
  'Afficher le CMUP actuel et la dernière entrée de cet article
  Me.txtDernEntree = DLookup("EntreeDate", "rDernEntree")
  Me.txtCMUP = DLookup("CMUP", "rDernEntree")
  'Vérifier si le niveau du stock de l'article est inférieur ou égal à 10
  If Nz(Me.txtStock, 0) <= 10 Then
  Alerte = MsgBox("Stock insuffisant pour cet article", vbCritical + vbOKOnly, "Avertissement")
  End If
 
End Sub

[PipoWIL]

Bonjour,

Une possibilité serait de rajouter sur l'événement onOpen ou onLoad du formulaire un peu de code VBA pour gérer le message. L'idée c'est que lorsque l'utilisateur appelle ce formulaire et qu'il se charge, au moment où il se charge il vérifie la quantité actuellement en stock.

Voici une proposition :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Private Sub Form_Load()
 
'Ces quelques lignes vont s'executer à l'ouverture 'Load' du formulaire c'est-à-dire avant même que l'utilisateur ne lise le contenu.
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim strSQL As String
Dim iStockActuel As Integer
Dim iStockMin As Integer
 
'supposons que le stock Actuel soit dans la table [100 TBL STOCK]
'Supposons que la table [100 TBL STOCK] contienne 2 colonnes : PRODUIT et QUANT
 
'Je fais ici une petite query pour extraire la quantité actuelle de ce produit.  Je suppose que ce produit est le champ Text0 sur le formulaire.
strSQL = "SELECT PRODUIT, QUANT "
strSQL = strSQL & "FROM [100 TBL STOCK] "
strSQL = strSQL & "WHERE (PRODUIT = '" & Me.Text0.Value & "')"
 
Set db = Application.CurrentDb
Set rst = db.OpenRecordset(strSQL)
 
iStockActuel = rst!QUANT
 
Set rst = Nothing           'supprimer le pointeur si on ne l'utilise plus.
Set db = Nothing
 
 
'je teste la quantité actuelle en stock.
If iStockActuel < 10 Then
    Me.lblMsgAlerte.Caption = "ALERTE !!!!! Il faut réapprovisionner le stock !"
    Me.lblMsgAlerte.ForeColor = 255          'Rouge
    Me.lblMsgAlerte.Visible = True
Else
    Me.lblMsgAlerte.Visible = False         'ne pas faire apparaître le message
End If
 
 
End Sub

C'est très approximatif. Il faut rajouter la gestion d'erreur et tout ce dont vous avez besoin.



Si l'utilisateur ne recharge pas le formulaire durant ses manipulations, le message ne sera pas réévalué à chaque fois. Il faut alors placer ce genre de code non pas sur le formulaire mais sur le champ qui est manipulé par l'utilsateur. Par exemple, la première ligne de code deviedra

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub ARTICLE_Change()

si c'est le champ ARTICLE qui est manipulé par l'utilisateur.


Bon Week-end.

[ClaudeLELOUP]

Bonjour,

Je ferais comme ceci :

- dans la table tArticles, ajouter une colonne StockAlerte qui te permettrait de définir, article par article, le seuil à partir duquel il faut réapprovisionner ;
- dans le code associé au clic du bouton Enregistrer, ajouter quelques instructions pour vérifier que le stock mis à jour reste supérieur au seuil. Dans le cas contraire, afficher un message d'alerte ;
- dans l'événement après mise à jour de CboArticle, les mêmes instructions.

Es-tu à l'aise avec le VBA ?


P.-S. Bonjour à Malick et PipoWIL qui ont posté pendant que je rédigeais mon message.

[patner]

Bonjour, à tous,
je vous remercie pour votre aide , néanmoins la solution la plus simple pour moi est celle proposée par Claude.
Pour répondre à sa question, non je ne suis pas trop à l'aise avec le code VBA. Mais j’apprends vite.
Je viens de rajouter à ma table article la colonne StockAlerte avec pour chaque article le seuil d'alerte.

1/ je n'arrive pas à repérer le code associé au clic du bouton Enregistrer, je suppose qu'il est dans le Module mFonctions ou dans les requêtes?

2/ comment ajouter quelques instructions pour vérifier que le stock mis à jour reste supérieur au seuil? je sais le faire sur Excel, mais pas dans Access en utilisant des conditions.

3/ dans l'événement après mise à jour de CboArticle, les mêmes instructions?

En gros je suis nul sous Access, mais je veux bien apprendre, je sais créer des tables, mettre en place des Macros,créer le modèle suivant la méthode Merise et les relations entre les tables.

Je me suis dirigé vers Access la gestion de mon stock devient beaucoup plus fastidieux avec Excel.
et la Base que Claude a développée est vraiment ce qu’il me faut
Or mi que je dois ajouter une alerte pour me permettre de commander un ravitaillement, pour ne pas tomber en rupture de stock.

Merci encore pour votre aide
Cordialement
Patner

[ClaudeLELOUP]

Bonjour Patner,

je n'arrive pas à repérer le code associé au clic du bouton Enregistrer, je suppose qu'il est dans le Module mFonctions ou dans les requêtes?

Ouvre ton formulaire en mode construction, double-clique le bouton « Enregistrer » pour afficher les propriétés (onglet Événement)





Clique alors sur les points de suspension à droite pour accéder au code.
Je l’ai modifié comme ceci (24-29) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub btEnregistrer_Click()
  Dim sSql As String
  Dim StockAlerte As Long
  'Est-ce complet ?
  If IsNull(Me.txtDate) Or Nz(Me.txtQuant, 0) = 0 Or Nz(Me.txtImputation, 0) = 0 Then
      MsgBox "Un des champs obligatoires n'est pas rempli", vbCritical
      Exit Sub
  End If
  'Maj tSorties
  sSql = "INSERT INTO tSorties ( SortieDate, SortieQuant, SortieImputation, CMUP, tArticlesFK ) " _
           & "SELECT #" & Format(Me.txtDate, "mm/dd/yy") & "# AS Expr1, " _
           & Me.txtQuant & " AS Expr2, " _
           & """" & Me.txtImputation & """ AS Expr3, " _
           & Replace(Me.txtCMUP, ",", ".") & " AS Expr4, " _
           & Me.CboArticle & " As Expr5;"
 
  DoCmd.SetWarnings False
  DoCmd.RunSQL sSql
  DoCmd.SetWarnings True
  'Réinitialiser pour une nouvelle sortie éventuelle
  Me.CTNRsfSortiesDetail.Requery
  Me.txtDate = Null: Me.txtQuant = Null: Me.txtImputation = Null
  Me.txtStock = StockADate(Me.CboArticle, Format(Date, "mm/dd/yyyy"))
  'Vérifier que le seuil n'est pas franchi
  StockAlerte = DLookup("StockAlerte", "tArticles", "tArticlePK=" & Me.CboArticle)
  If StockADate(Me.CboArticle, Date) <= StockAlerte Then
      MsgBox "Réapprovisionnez cet article !" & Chr(13) & Chr(10) _
              & "Stock d'alerte : " & StockAlerte & "."
  End If
End Sub

En gros je suis nul sous Access, mais je veux bien apprendre, je sais créer des tables, mettre en place des Macros,créer le modèle suivant la méthode Merise et les relations entre les tables.

Le VBA, c’est du mauvais anglais qui te permet de décupler tes possibilités, jette un œil sur ce tutoriel pour commencer ton apprentissage : http://heureuxoli.developpez.com/office/word/vba-all/

et pour le reste :



D'une manière générale, pour se documenter sur les propriétés d'un formulaire ou d'un état, ou de leurs contrôles :
- afficher l'objet en mode construction ;
- cliquer sur la propriété => elle se met en surbrillance ;
- enfoncer la touche <F1>
=> l'aide Access s'ouvre à la bonne page.
De même dans le code, placer le curseur de la souris et enfoncer F1.
On peut aussi :
• ouvrir l'aide <F1>, choisir l'onglet « Aide intuitive » et suivre les instructions ;
• ouvrir la fenêtre d'exécution (<Ctrl> + G), saisir un mot-clé, y placer le curseur de la souris et enfoncer F1.

Bonne continuation.

En P.J. La db du tutoriel avec une alerte.

[patner]

Merci Claude,
laisse-moi te dire que tu es un As
Je te remercie pour ces précieux conseils. En effet, si je m'y mets, je pourrais réaliser pas mal
de choses avec Access, à dieu Excel.

En effet j'avais fait un peu Access en cours, il y a bien longtemps.
Mais j'ai tout oublié, il faut vraiment que je replonge le nez à nouveau dedans.

merci à tous pour ce soutien intellectuel, merci à toute l'équipe de Développez.com

Sans oublier mon ami Claude l'expert.
Cordialement
Patner