Formule excel pour lister des absents

**Maryem BN** · 11/02/2016, 10h41

Alors bonjour

,
j'ai un petit souci par rapport à une formule sur excel , j'ai une liste d'absence sur la quelle figurent les noms et prénoms du personnel ainsi que les jours du mois , les gens absents sont marqués par X dans le jour de leur absence .

Dans une autre feuille , j'ai une cellule qui comporte une date d'un jour du mois , alors ce qui est demandé est que à chaque fois que tu tape une date dans une cellule un tableau qui comporte deux colonnes ( noms et prénoms ) affichera les noms et prénoms des absents .

Aiiiiidez moi à trouver une formule pour régler ce pb !

**Kimy_Ire** · 11/02/2016, 10h53

Bonjour Maryem BN,

Tout d'abord je te propose d'aérer d'avantage tes posts car le "pâté" que tu écris est quelque peu indigeste.

Pour autant, si j'ai bien compris, tu cherches à récupérer tous les X en fonction d'une date.
Or, une formule ne te retourne qu'une valeur à la fois. En d'autres termes, si tu as plusieurs personnes absentes le même jour tu ne pourras pas récupérer l'ensemble simplement avec une formule "simple".

Peut-être qu'une procédure événementielle ou du VBA te permettrait d'accéder plus facilement à ce que tu désires ?

Un fichier exemple serait le bienvenue si cette solution est susceptible de te convenir.

Cordialement,
Kimy

**Maryem BN** · 11/02/2016, 10h59

Kimy , je suis nouvelle sur ce forum et du coup c'est ma première discussion , j'apprendrai à aérer mes messages :p

Alors je recherche à récupérer les noms et prénoms dans une liste des absents dont les X figure dans le jour voulu !

C'est pas possible de le faire sur excel ??

**Kimy_Ire** · 11/02/2016, 11h10

Si si, c'est tout à fait possible, mais comme je te disais, une formule simple ne va récupérer qu'une seule occurrence.
Des formules plus complexes pourraient récupérer l'ensemble des valeurs mais je suis moins doué dans cela, d'autant plus que le nombre de valeurs de sortie va varier d'un jour à l'autre.

Je pense qu'il faut d'avantage passer par

une procédure événementielle (d'Excel) : quand tu changes la date, par exemple, un petit bout de code s'active afin de récupérer les absents,
ou un bouton qui lance une macro (Excel) lançant, de la même manière, un petit bout de code récupérant les données souhaitées.

Cordialement,
Kimy

**Maryem BN** · 11/02/2016, 11h16

je n'arrive pas vraiment à comprendre ce que vous voulez dire

; je ne m'y connais pas trop en excel !

Je vous passe le fichier , si vous voulez voir de quoi il s'agit ?

**Kimy_Ire** · 11/02/2016, 11h23

C'est ce que je te demandais dans mon premier post.

**Maryem BN** · 11/02/2016, 11h26

Le voilà

**Kimy_Ire** · 11/02/2016, 12h00

Voici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim oRng As Range, oCell As Range
Dim nb_abs As Integer
 
If Not Application.Intersect(Target, Range("F2")) Is Nothing Then
    If IsDate(Target) Then
        Range("C10:F37").ClearContents
        With Worksheets("Liste des absences ")
            Set oRng = .Rows(6).Find(CStr(Target), LookIn:=xlValues, LookAt:=xlWhole)
            If Not oRng Is Nothing Then
                For Each oCell In .Range(oRng, .Cells(.Rows.Count, oRng.Column).End(xlUp))
                    If LCase(oCell) = "x" Then
                        nb_abs = nb_abs + 1
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 0) = .Cells(oCell.Row, 2)
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 1) = .Cells(oCell.Row, 3)
                    End If
                Next oCell
            Else
                MsgBox "Cette date n'est pas présente dans la feuille de liste des absences."
            End If
        End With
        Range("D40") = nb_abs
    Else
        MsgBox "Vous n'avez pas inséré une date."
    End If
End If
 
End Sub

Je te laisse placer ce bout de code dans ta Feuil2 : "Etat des absences ".
Cela te permettra d'appréhender un peu les procédures événementielles.

Alt + F11
Cliquer sur la Feuil2
Coller le code est sauvegarder
Changer la cellule F2.

Cordialement,
Kimy

**Maryem BN** · 11/02/2016, 12h05

Merciiiiiii infinement

; je vais voir si ça va marcher sur mon pc et si je saurai l'implémenter

**Maryem BN** · 11/02/2016, 12h38

ooops ! j'ai fais toutes les instructions que vous m'avez dites et pourtant les noms et les prénoms ne s'affichent pas sur le tableau

**riton00** · 11/02/2016, 13h28

Bonjour Maryem BN

As-tu mis le code dans Etat des absences puisque chez moi le code de Kimy_Ire fonctionne très bien, mais comme c'est une macro et non une formule il faut transformer ton fichier en xlsm et accepter les macro
Voir fichier joint

Slts

**Kimy_Ire** · 11/02/2016, 14h14

Avec le fichier : Registre des Absences.xlsm.

**Maryem BN** · 11/02/2016, 15h34

Merciiiii beaucouuup ; je vous suis vraiment reconnaissante . Enfin , it works

J'ai juste une petite question , est-ce que ce code va marcher si je change le mois ? j'ai remarqué que ça marche pas

; moi je veux que quelque soit le mois , le tableau doit fait ressortir les noms , pouvez vous modifier le fichier excel

**Kimy_Ire** · 11/02/2016, 15h42

Maryem BN,

Je ne me base que sur les jours qui sont présents dans ta feuille "Liste des absences ". ^^
Je ne vais pas inventer des absences si ta BDD n'est pas complète !

Cordialement,
Kimy

PS : lit ma signature afin de résoudre le post

.

**Maryem BN** · 11/02/2016, 15h52

Je vous ai pas demandé d'inventer des dates , je vous ai juste demandé qu'est ce que je peux modifier sur le code pour que ça marche pour tout les mois et les jours de l'année , si je les change éventuellement sur la liste d'absence !

**Kimy_Ire** · 11/02/2016, 16h10

Maryem BN,

Logiquement, si tu ajoutes des dates avec des croix et que tu places dans la cellule les mêmes valeurs, tout devrait marcher de la même manière.
Je t'envoie le code commenté afin que tu puisses appréhender l'utilité de chaque ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
'Déclaration des variables
Dim oRng As Range, oCell As Range
Dim nb_abs As Integer
 
'Si le changement s'opère en cellule F2...
If Not Application.Intersect(Target, Range("F2")) Is Nothing Then
    'Si la valeur insérée est une date...
    If IsDate(Target) Then
        'on efface le tableau.
        Range("C10:F37").ClearContents
        'Avec la feuille "Liste des absences "...
        With Worksheets("Liste des absences ")
            'on recherche sur la ligne 6 la date insérée.
            Set oRng = .Rows(6).Find(CStr(Target), LookIn:=xlValues, LookAt:=xlWhole)
            'Si on trouve quelque chose :
            If Not oRng Is Nothing Then
                'Pour chaque cellules de la colonne...
                For Each oCell In .Range(oRng, .Cells(.Rows.Count, oRng.Column).End(xlUp))
                    'on vérifie si on a un "x".
                    If LCase(oCell) = "x" Then
                        'Si oui, on ajoute au compteur...
                        nb_abs = nb_abs + 1
                        'et on écrit les valeurs.
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 0) = .Cells(oCell.Row, 2)
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 1) = .Cells(oCell.Row, 3)
                    End If
                Next oCell
            Else
                MsgBox "Cette date n'est pas présente dans la feuille de liste des absences."
            End If
        End With
        'On insère en fin de macro le nombre de "x" trouvés.
        Range("D40") = nb_abs
    Else
        MsgBox "Vous n'avez pas inséré une date."
    End If
End If
 
End Sub

Voila.

Cordialement,
Kimy

**Maryem BN** · 11/02/2016, 16h13

Thank youuuu , j'ai jamais suivi des cours en visual basic , donc tes commentaires me seront vraiments utile , Merciiii encore une fois

(y)

**Maryem BN** · 12/02/2016, 16h20

Bonjour ;

Je reviens encore une fois vers vous pour résoudre un petit problème lié au même fichier . Alors comme vous avez vu le fichier comportait une 'liste d'absence' du mois d'octobre , Maintenant je veux créer plusieurs feuilles ' liste d'absence' de tout les mois de l'année !

Comment est ce que je pourrais faire le lien entre toutes ces ' listes d'absences ' de tout les mois avec la feuille 'Etat des absences ' qui comporte le code VBA ? est ce que je dois modifier des trucs dans le code ? cmt y procéder ??

**Kimy_Ire** · 12/02/2016, 18h45

Bonjour Maryem BN,

Alors il y a quelques conditions...
Tout d'abord, il va falloir que le formalisme de tes différents mois de l'année soit absolument les mêmes. Surtout la ligne 6 qui va devoir contenir les dates.

Sous cette condition, la macro peut être modifiée en conséquence. On peut parcourir toutes les feuilles avec un simple For Each oWksh in Worksheets, cependant ça ne serait pas du tout optimisé.
En effet, une date ne pourrait jamais se trouver dans deux feuilles différentes puisque chacune d'entre elle définie un mois précis.

Ainsi, peux-tu nous en dire d'avantage sur la manière que tu as de nommer tes feuilles ?
Quelque chose qui serait très simple à faire serait de les nommer selon le nombre du mois de l'année. Si ta feuille d'absence de Janvier peut s'appeler "01", celle de Février "02", etc... jusqu'à Décembre en "12", on peut facilement faire quelque chose du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
'Déclaration des variables
Dim oRng As Range, oCell As Range
Dim nb_abs As Integer
 
'Si le changement d'opère en cellule F2...
If Not Application.Intersect(Target, Range("F2")) Is Nothing Then
    'Si la valeur insérée est une date...
    If IsDate(Target) Then
        'on efface le tableau.
        Range("C10:F37").ClearContents
        'Avec la feuille "Liste des absences "...
        'MsgBox Month(Target)
        With Worksheets(Format(Month(Target), "00"))
            'on recherche sur la ligne 6 la date insérée.
            Set oRng = .Rows(6).Find(CStr(Target), LookIn:=xlValues, LookAt:=xlWhole)
            'Si on trouve quelque chose :
            If Not oRng Is Nothing Then
                'Pour chaque des cellules de la colonne...
                For Each oCell In .Range(oRng, .Cells(.Rows.Count, oRng.Column).End(xlUp))
                    'on vérifie si on a un "x".
                    If LCase(oCell) = "x" Then
                        'Si oui, on ajoute au compteur...
                        nb_abs = nb_abs + 1
                        'et on écrit les valeurs.
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 0) = .Cells(oCell.Row, 2)
                        Worksheets("Etat des absences ").Range("C9").Offset(nb_abs, 1) = .Cells(oCell.Row, 3)
                    End If
                Next oCell
            Else
                MsgBox "Cette date n'est pas présente dans la feuille de liste des absences."
            End If
        End With
        'On insère en fin de macro le nombre de "x" trouvés.
        Range("D40") = nb_abs
    Else
        MsgBox "Vous n'avez pas inséré une date."
    End If
End If
 
End Sub