Discussion :

[ESVBA]

Bonjour,

j'ai une textbox qui permet de filtrer une listbox indépendante, j'y place le nom et son index dans deux colonnes.
Ca fonctionne.

Je souhaite par un double-clic sur la listbox atteindre dans le sous-formulaire l'enregistrement correspondant.
Ca ne fonctionne pas.

Formulaire : FormRecherche
SFormulaire : sfArticle
ListBox : NomListBox
Champ index : IDVille type Numéro Auto entier Long

J'ai ce code dans le formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Private Sub NomListBox_DblClick(Cancel As Integer)
    Dim Lig As Long
 
    Lig = Forms!FormRecherche!NomListBox.ListIndex
 
    Forms![FormRecherche]![sfArticle].Form![IDVille].SetFocus
 
    'DoCmd.FindRecord CLng(Forms!FormRecherche.NomListBox.Column(1, Lig))
    'ou
    DoCmd.GoToRecord acActiveDataObject, , acGoTo, CLng(Forms!FormRecherche.NomListBox.Column(1, Lig))
 
    Forms!sfArticle.Requery
End Sub

Sur la ligne 7, j'ai "Propriété ou méthode non gérés par cet objet"

D'après mes recherches, la formule est bonne.
Qu'est-ce qui cloche ?

Merci.

ESVBA

[madefemere]

Bonjour,

Moi j'utiliserais la méthode Findfirst du RecordSet de ton sous-formulaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub NomListBox_DblClick(Cancel As Integer)
    Dim IdCherche As Integer
 
    IdCherche = Me.NomListBox
    With Me.sfArticle.Form.RecodsetClone
         .FindFirst "[IdVille]=" & IdCherche
         Me.[sfArticle].Form.BookMark = .BookMark
    End with
 
    Me.sfArticle.Requery
End Sub

Attention, code non vérifié

Cordialement,

[ESVBA]

effectivement ça fonctionne avec quelques modifications.

J'étais très loin du compte. Je pensais simplement aller à la valeur de la clé.



Un grand merci à toi madefemere.

Mon code définitif (!) fonctionnel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub NomListBox_DblClick(Cancel As Integer)
    Dim IdCherche As Long
    Dim Lign         As long
 
    Lign = Forms!FormRecherche!NomListBox.ListIndex
    IdCherche = Forms!FormRecherche.NomListBox.Column(1, Lign)
 
    With Me.sfArticle.Form.RecordsetClone
         .FindFirst "[IDVille]=" & IdCherche
         Me.[sfArticle].Form.Bookmark = .Bookmark
    End With
 
    Me.sfArticle.Requery
End Sub

Si quelqu'un avait un code avec un "GotoRecordset" pour mon information ?
Merci.

ESVBA