Discussion :

[Fiifteen]

Bonjour, je suis en stage et je dois réaliser un document Word lié avec une base de donnée.
Tout marche très sauf lorsque je doit insérer une image. En effet j'utilise Objet OLE comme type de donnée et lorsque j'insère le champs dans word il m'est inscrit une série de chiffre et de lettre de type: 151C2F00

Je ne trouve donc pas comment mettre l'image ;(

Merci.

[marot_r]

Bonjour.

Autant que je sache on ne peut pas fusionner une image, seulement du texte.

Tu peux peut-être le faire avec du code VBA en simulant par programme la fusion.

Poste sur le site Word à tout hasard.

A+

[ClaudeLELOUP]

Bonjour,

Voici un exemple qui pourrait servir de base.

Au départ




Les fichiers des images sont dans un sous-répertoire « Images » du dossier qui contient la db. Leur nom contient la clé de l’enregistrement correspondant.
Le document Word type est logé dans le même répertoire que celui de la db.

Pour procéder, on s’inspire de cette Q/R de la FAQ Word : Comment faire pour utiliser une image dans un publipostage ? : http://word.developpez.com/faq/?page...ipostage_image

On crée une table intermédiaire avec cette requête :



Qui donne cette table. Elle servira de référence pour le publipostage



Comme proposé dans la Q/R le chemin des images est écrit en doublant les « \ ».



Code associé au bouton « Publipostage »

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Compare Database
Option Explicit
 
 
Private Sub BtPublipostage_Click()
  Dim wdapp As Word.Application
  Dim NomDoc As String
  Dim CheminDocPerso As String
  'Créer la table tPublipost
  DoCmd.SetWarnings False
  DoCmd.OpenQuery "rPublipost"
  DoCmd.SetWarnings True
  'Définir le chemin du doc publiposté
     'ici, il s'appelle tstPubli.docx et est logé dans le même répertoire que la db
  CheminDocPerso = CurrentProject.Path & "\tstPubli.docx"
  'Publipostage proprement dit
  Set wdapp = New Word.Application
  With wdapp
       .Visible = True
       ' Ouvrir le document type
       .Documents.Open CurrentProject.Path & "\PubliImage.docx"
       .ActiveDocument.MailMerge.OpenDataSource _
            Name:=CurrentDb.Name, _
            LinkToSource:=True, _
            Connection:="Table tPublipost", _
            SQLStatement:="SELECT * FROM [tPublipost]"
       .ActiveDocument.MailMerge.Execute
       'on enregistre le doc publiposté
       .ActiveDocument.SaveAs2 CheminDocPerso
       .Documents.Close
       DoEvents
       'on réouvre le doc plubliposté pour activer les images
       .Documents.Open CheminDocPerso
       .Selection.WholeStory
       .Selection.Fields.Update
       'on le sauvegarde
       .ActiveDocument.Save
       .Documents.Close
  End With
  ' Fermer et libérer les objets
  wdapp.Quit
  Set wdapp = Nothing
  ' Afficher le doc publiposté dans une fenêtre
  Shell "C:\WINDOWS\EXPLORER.EXE " & CheminDocPerso
 
End Sub

L’archive à décompresser dans un répertoire quelconque est ici : http://claudeleloup.developpez.com/t...PubliImage.zip
N'hésite pas à revenir si le code te pose problème pour l'adapter à ton cas.

[marot_r]

Cool, merci Claude, j'ignorai totalement qu'on pouvait faire cela.

A+