Discussion :

[salemhacen]

Bonjour,

Je sollicite votre aide aujourd'hui parce que je suis bloqué sur la résolution d'un problème, voilà dans un onglet Excel, j'ai 5 colonnes ('nom; prénom;matricule;code formation et date de formation'). Je rajoute une sixième colonne qui me permets de calculer la différence entre la date d'aujourd'hui et la date de formation déjà saisi (colonne 5). Mais j'ai quelques personnes qui ont fait plusieurs fois la formation à des dates différentes, ce qui m'intéresse est uniquement la dernière date donc je souhaite afficher après uniquement la différence entre la date d'aujourd'hui est la dernière effectuée par le salarié. C'est une macro que je veux mettre en place qui me calcule la différence de date en nombre de jours par personnes pour leurs dernières dates de formations.
Je vous poste le fichier pour comprendre plus la demande.
Par avance merci.

[Invité]

Bonjour,
NbJour=DateDiff("D",Date1,Date2)

[salemhacen]

Merci rdurupt pour la rapidité de votre réponse mais je n'ai pas trop compris, concrètement je vous joint ce que je souhaite obtenir par des macros pour ensuite les affecter à des boutons.Nouveau Feuille de calcul Microsoft Excel.xlsx

[gFZT82]

Bonjour,

Une proposition avec utilisation d'un dictionnaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
Sub Indicateur()
Dim Dico, k, i
Dim n As Integer
Dim C As Range
    Set Dico = CreateObject("Scripting.dictionary")
    With Worksheets("Feuil1")
        For Each C In .Range("C2:C" & .Range("C" & Rows.Count).End(xlUp).Row)
            If Not Dico.Exists(C.Value) Then
                Dico.Add C.Value, C.Offset(0, 2).Value
            Else
                If C.Offset(0, 2).Value > Dico.Item(C.Value) Then
                    Dico.Item(C.Value) = C.Offset(0, 2).Value
                End If
            End If
        Next C
        k = Dico.keys
        i = Dico.items
        For n = 0 To Dico.Count - 1
            For Each C In .Range("C2:C" & .Range("C" & Rows.Count).End(xlUp).Row)
                If C = k(n) And C.Offset(0, 2) = i(n) Then
                    C.Offset(0, 3) = Date - i(n)
                End If
            Next C
        Next n
    End With
End Sub

[salemhacen]

Merci gFZT82, ça marche bien sur l'exemple demandé, en essayant d'adapter le code sur mon fichier de base qui contient 1000 ligne (tout un effectif) j'ai "erreur 13 incompatibilité de type " sur la ligne de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

C.Offset(0, 3) = Date - i(n)

sachant que la date de formation se trouve sur la colonne "H" et mon calcul d'indicateur sur la colonne "M".
Est ce que c'est possible de m'expliquer aussi le code dictionnaire.
Par avance Merci

[gFZT82]

Le dictionnaire permet d'obtenir la liste des matricules sans doublon.
A chaque clé (matricule), on associe la date de formation la plus récente.

Voici le code adapté à la structure de ton classeur avec quelques commentaires :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Option Explicit
Sub Indicateur()
Dim Dico, k, i
Dim n As Integer
Dim C As Range
    Set Dico = CreateObject("Scripting.dictionary")
    With Worksheets("Feuil1")
        'On balaye tous les matricules
        For Each C In .Range("C2:C" & .Range("C" & Rows.Count).End(xlUp).Row)
            'Si le matricule n'est pas noté dans le dictionnaire
            If Not Dico.Exists(C.Value) Then
                'On ajoute le matricule (clé) dans le dictionnaire avec la date de formation associée (item).
                Dico.Add C.Value, C.Offset(0, 5).Value
            Else
                'Sinon (cas où la matricule a déjà été noté), si la date de formation associée est plus récente que celle notée dans le dictionnaire (item)
                If C.Offset(0, 5).Value > Dico.Item(C.Value) Then
                    'alors, on remplace l'item par la date de formation la plus récente
                    Dico.Item(C.Value) = C.Offset(0, 5).Value
                End If
            End If
        Next C
        k = Dico.keys
        i = Dico.items
        For n = 0 To Dico.Count - 1
            For Each C In .Range("C2:C" & .Range("C" & Rows.Count).End(xlUp).Row)
                If C = k(n) And C.Offset(0, 5) = i(n) Then
                    C.Offset(0, 10) = Date - i(n)
                End If
            Next C
        Next n
    End With
End Sub

Cordialement.

[salemhacen]

'gFZT82' je ne sais pas comment je peux vous remercier ça marche à merveille, c'est parfait, si vous le permettez je demande juste une dernière chose:
après ça je vais faire une petite interface avec 'userform' : bouton rechercher qui me permets de mettre le sois le nom ou prénom ou matricule de quelqu'un ensuite dans une autre cas appelé 'indicateur' j'aurais donc le résultat.
Ma question est la suivant: puisque parfois j'ai la même personne qui se répète plusieurs fois, comment je peux renvoyer uniquement la date qui contient l'indicateur puisque les autres déjà sont vides.

[gFZT82]

Si tu utilises la feuille telle que présentée, cela ne doit pas poser de problème.
La recherche devra se faire sur le matricule car celui-ci est unique (ce qui ne sera peut-être pas le cas du nom et du prénom).
Il faudra balayer toutes les lignes et effectuer un test sur le matricule et la présence de l'indicateur.

Cordialement.

[salemhacen]

oui j'utilise la même feuille, donc si j'ai bien compris je peux faire une recherche par Matricule et le résultat doit donner matricule et indicateur sinon par nom et prénom ce sera pas possible.
Je dois utiliser quel code pour le balayage?

Cordialement.

[gFZT82]

Bonjour,

Si tu as réellement l’intention de faire un traitement avec Userform tel que tu l’as décrit, il va falloir que tu t’attelles sérieusement à l’apprentissage de VBA.
Voici un exemple pour commencer.
Bon courage.

A+

[salemhacen]

Merci beaucoup depuis quelques jours j'essaye de faire de l'autoformation pour bien assimiler VBA.