Discussion :

[lerico]

Bonjour à tous,

Je fais appel à vos connaissances pour traduire un programme en langage C vers du vba.
Certaines fonctions de ce programme me sont inconnues et je peine à le faire fonctionner sous Access.

Le principe est de calculer sur 18 caractères, le crc 8 bits polynôme 0x91, en base 10 (0 -> 255 => 3 chiffres).

Exemple : 300314120242907650 résultat du calcul 048

Voici le code en C:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
const unsigned char CRC7_POLY = 0x91;
 
unsigned char getCRC(unsigned char message[], unsigned char length)
{
 unsigned char i, j, crc = 0;
 
   for (i = 0;i < length; i++)
   {
         crc ^= message[i];
         for (j = 0;j < 8; j++)
         {
               if (crc & 1)crc ^= CRC7_POLY;
               crc >>= 1;
          }
    }
    return crc;
}

En vba cela pourrait donner cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function CRC (Message as String, Longueur_a_coder as long)
Dim i,j as Long

CRC=0

For i=1 to  Longueur_a_coder
    CRC=CRC xor Message(i)
    For j=1 to 8
          if le bit de poids faible de CRC est à 1 then
                 CRC=CRC xor 0x91 ou exclusif bit à bit
                 Décaler les bits de CRC de 1 bit à droite // division entière par 2
          end if
    Next j
Next i
CRC=CRC

Je n'arrive pas à traduire la partie en italique. Pouvez-vous m'apporter une aide sur ce sujet ?

Merci.

[helas]

Bonjour,
le code pourrait être

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
crc = crc xor &h91
crc = crc \ 2

[LedZeppII]

Bonjour,

Je suis d'accord avec Helas.
Je vois la fonction comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function getCRC(message As String, length As Long) As Byte
Const CRC7_POLY As Long = &H91
Dim crc As Long
Dim i As Long, j As Long
Dim OneChar As Long
 
crc = 0
For i = 1 To length
    OneChar = Asc(Mid(message, i, 1))
    crc = crc Xor OneChar
    For j = 0 To 7
        If (crc And 1) = 1 Then crc = crc Xor CRC7_POLY
          crc = crc \ 2
    Next
Next
 
getCRC = CByte(crc)
End Function

Test de la fonction:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub testGetCRC()
Dim s As String
Dim crc As Byte
 
s = "300314120242907650"
crc = getCRC(s, Len(s))
Debug.Print crc & " (0x" & Hex(crc) & ")"
 
End Sub

Cela me donne 48.

A+

[lerico]

Bonjour,

Un grand merci à vous deux.
Je vais effectuer d'autres tests mais je pense que c'est du tout bon.

A+