Discussion :

[Kropernic]

Hello,

Sur le projet qui m'occupe actuellement, j'ai besoin de faire ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
    Public Sub CheckForDuplicateSeason(ByRef detailsOwn As List(Of PROMO_DTO.PromoDetailOwn), Optional ByRef detailsDept As List(Of PROMO_DTO.PromoDetailDepartment) = Nothing)
        If detailsDept Is Nothing Then
            Dim data = (From d1 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        From d2 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        Where d1 IsNot d2 And d1.Seasons.Intersect(d2.Seasons).Count > 0
                        Select d1)
 
            For Each d As PROMO_DTO.PromoDetailOwn In data.ToList
                d.ErrorText = "saison"
            Next
        Else
            Dim data = (From d1 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        From d2 As PROMO_DTO.PromoDetailDepartment In detailsDept
                        Where d1.Seasons.Intersect(d2.Seasons).Count > 0
                        Select d1)
 
            For Each d As PROMO_DTO.PromoDetailOwn In data.ToList
                d.ErrorText = "saison"
            Next
        End If
    End Sub

En l'état, VS me fait la gueule et souligne, dans les deux branches du If, la source de la 2e liste de ma query sous prétexte que c'est un paramètre ByRef. Or la source de la première ligne l'est tout autant (surtout qu'il s'agit de la même liste dans le premier cas).

En soit, ce n'est pas bien grave, je peux faire comme indiquer dans la MSDN et modifier mon code comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
    Public Sub CheckForDuplicateSeason(ByRef detailsOwn As List(Of PROMO_DTO.PromoDetailOwn), Optional ByRef detailsDept As List(Of PROMO_DTO.PromoDetailDepartment) = Nothing)
        Dim dto As List(Of PROMO_DTO.PromoDetailOwn) = detailsOwn
        If detailsDept Is Nothing Then
            Dim data = (From d1 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        From d2 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        Where d1 IsNot d2 And d1.Seasons.Intersect(d2.Seasons).Count > 0
                        Select d1)
 
            For Each d As PROMO_DTO.PromoDetailOwn In data.ToList
                d.ErrorText = "saison"
            Next
        Else
            Dim ddp As List(Of PROMO_DTO.PromoDetailDepartment) = detailsDept
            Dim data = (From d1 As PROMO_DTO.PromoDetailOwn In detailsOwn
                        From d2 As PROMO_DTO.PromoDetailDepartment In detailsDept
                        Where d1.Seasons.Intersect(d2.Seasons).Count > 0
                        Select d1)
 
            For Each d As PROMO_DTO.PromoDetailOwn In data.ToList
                d.ErrorText = "saison"
            Next
        End If
    End Sub

Mais j'aimerais bien comprendre le pourquoi malgré tout. Il doit sûrement y avoir une très bonne raison derrière tout ça mais avec le peu d'info que j'ai, cette erreur n'a aucune raison d'être...

[Kropernic]

Bon... Je vois 3 possibilité...

1. J'ai rien compris et j'ai eu un gros coup de bol
2. La MSDN raconte des conneries
3. Y a un sûût dans le framework

D'après cette page, il m'aurait fallu :

• Pour le framework 4.5 : créer une classe implémentant IEqualityComparer(Of Season) (Mais où ? Dans le projet qui abrite la classe Season ou dans le projet où je fais la comparaison ?)
• Pour le framework 4 : que ma classe Season implémente IEquatable(Of Season).

J'ai tenté la première option, rien à faire... (ou alors, voir option 1 du début).
J'ai tenté la seconde option et bingo, ça marque du premier coup.

C'est grave docteur ?

[Sehnsucht]

Question bête ; une utilité concrète avoir mis les paramètres ByRef à la base (parce que c'est surtout ça qui pose problème) ?

[Kropernic]

Question bête ; une utilité concrète avoir mis les paramètres ByRef à la base (parce que c'est surtout ça qui pose problème) ?

Bah pour pouvoir modifier leur contenu et conserver les modifs en sortie de sub.

Mais ta remarque me fait me demander si le fait que ce soit des classes custom (et donc des types par référence) ne fait pas le taff déjà à la base...

[Pol63]

en byval ca gardera aussi le contenu modifié
byref est utile pour les types par valeur pour propager les modifications
pour les types par référence byref sert à changer la référence

genre si dans la sub tu dis param2 = new list() avec byref l'appelant aura le new list

[Kropernic]

Ah bin voilà.

Malgré tout, pour ma culture général, qu'est-ce qui dérange dans le fait d'avoir un paramètre byref dans une query linq ?

[Sehnsucht]

Le fait que justement, on ne pourrait pas réassigner cette variable (ou plutôt que cette réassignation ne se répercuterait pas).

Lorsque on a un argument ByRef on "transmet" le message "on peut réassigner cet argument et ce changement sera visible de l'extérieur" soit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim foo As New Foo
'...
Sub ChangeFoo (ByRef arg As Foo)
    arg = New Foo ' modification répercutée sur "foo initial"
End Sub

Or dans la manière dont sont implémentées les lambdas (et leur closures) cet argument deviendrait un champ d'une classe, et la réassignation de ce champ ne se répercutera pas sur la variable initiale ayant servie à l'appel.
C'est à dire qu'une lambda de ce type Dim changer = Sub () foo = New Foo sera grosso-modo transformée en :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Class Closure ' en réalité c'est un nom généré
    Public local_foo As Foo
 
    Public Sub New (foo As Foo)
        local_foo = foo
    End Sub
 
    Public Sub Invoke ()
        local_foo = New Foo ' ne se répercute pas sur le "foo initial"
    End Sub
End Class

Quant au pourquoi l'erreur n'est signalée qu'au "deuxième From" c'est parce qu'au premier From la lambda ne capture aucun argument ByRef donc en fait, le problème est signalé dès que l'argument ByRef se retrouve "dans une lambda"

exemples (source est l'argument ByRef) :
Quand on écrit From item In source c'est transformé en source.Select (Function (item) item) on voit bien que la lambda ne capture pas d'élement ByRef, donc aucun problème.
Par contre quand on écrit From item1 In source From item2 In source c'est transformé en source.SelectMany (Function (item1) source, Function (item1, item2) New With { Key item1, Key item2 }) là source est bien capturé par la lambda d'où le problème.
On aurait exactement le même type de souci tout en ayant "qu'un seul From" avec ceci par exemple From item In source Select (source) qui se voit donc transformé en source.Select (Function (item) source)

Edit: à propos de quand utiliser ByVal/ByRef ; Pol63 a résumé ma pensée ; j'ajouterais juste que dans 90% des cas ByVal convient et l'utilisation de ByRef reste assez anecdotique (sans doute une des raisons qui ont fait que ByVal est désormais optionnel à préciser car c'est le choix par défaut).

Edit bis: quelque remarques qui sont moins en rapport avec le sujet ; évite les .Count > 0 surtout quand il s'agit d'IEnumerable ça t'oblige à parcourir toute la collection alors que ce qui t'intéresse c'est de savoir s'il y en a au moins un du coup remplace par .Any ; dans le même ordre d'idée faire un .ToList au moment du ForEach n'apporte absolument rien
Après on peut "a priori" réduire un peu la duplication du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Sub CheckForDuplicateSeason(detailsOwn As List(Of PROMO_DTO.PromoDetailOwn), Optional detailsDept As List(Of PROMO_DTO.PromoDetailDepartment) = Nothing)
    ' à remplacer par un If classique pour ceux qui préfèrent
    Dim query = If (detailsDept Is Nothing,
                    From d1 In detailsOwn, d2 In detailsOwn
                    Where d1 IsNot d2 AndAlso d1.Seasons.Intersect (d2.Seasons).Any
                    Select d1,
                    From d1 In detailsOwn, d2 In detailsDept
                    Where d1.Seasons.Intersect (d2.Seasons).Any
                    Select d1)
 
    For Each d In query
        d.ErrorText = "saison"
    Next
End Sub