Discussion :

[Stivostine69]

Bonjour,

Novice en VBA sur lequel je travaille depuis qqles tps, j'utilise pour peupler mes zones de listes le code suivant (zone de liste appelée ListeTiers):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Form_Activate()
Me!ListeTiers.RowSource = "SELECT * FROM tbl_tiers"
End Sub

C'est le code le plus simple que j'ai trouvé, je ne mesure absolument pas si c'est plus efficient ou moins que des peuplements de zones de liste complexes faisant appelent a des declaration des variables en VBA ... mais en tout cas mes requetes basées sur formulaires fonctionnent derriere. Toutefois, si vous disposez du meilleur code possible de peuplement de zones de liste je suis preneur !!

Mais maintenant, je voudrais passer au vrai listview issu des controles ActivX car ceux ci permettent des présentations bien plus intéressantes dans les formulaires.

Malheureusement mon code ci-dessus ne fonctionne plus dans ces conditions ...

Ainsi je me retourne vers la communauté : une personne pourrait elle m'orienter vers un code permettant le peuplement d'un listview, sans aucune autre option afin de ne faire que cela.

Merci a vous.

PS : J'ai lu avec attention le tuto de "Exemple de remplissage de listview" de M. Hubiche, qui est très bien fait, mais malheureusement il est trop complexe pour moi, et le fichier telechargé bug en AC2010 sur mon PC a la fermeture des formulaires, et je ne sais le debugguer.

[marot_r]

Bonjour.

Pour ta question sur l'efficacité je n'ai jamais fait de comparaisons chiffrées mais généralement, Access, est le plus efficace pour retrouver ses données.
Une autre solution serait de faire une boucle en VBA sur la table pour charger les éléments.
C'est plus compliqué et probablement plus lent.

Pour le chargement de la ListView, il est normal que ton code ne marche pas. Ce n'est pas un objet Access et il a ses propres modes d'interface.

Ici 2 exemples d'utilisation de ListView :

http://www.vbaexpress.com/forum/show...s-VBA-Listview
https://msdn.microsoft.com/en-us/lib...(v=vs.60).aspx

A+

[Stivostine69]

Tes liens étaient très intéressants.
En particulier celui mélangeant treeview et listview, il fait très envie car çà améliorait l'ergonomie de mes formulaires grandement !!

Du coup j'ai trouvé mon bonheur sur ce lien http://www.tek-tips.com/faqs.cfm?fid=6025
J'ai pu remplir mon premier listview et jouer avec la presentation c'est très sympa, de plus je trouve ce code clair.

le code VBA est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
 
 
Public Sub FillEmployees()
    On Error GoTo ErrorHandler
'Set Reference to Microsoft DAO 3.xx Library.
 
    'set variables
    Dim rs As DAO.Recordset
    Dim db As Database
    Dim lstItem As ListItem
    Dim strSQL As String
 
    Set db = CurrentDb()
    strSQL = "SELECT  * FROM Employees"
    Set rs = db.OpenRecordset(strSQL)
 
    With Me.ListView1
        'Set ListView style
        .View = lvwReport
        'This is not supported by ListView 5
        .GridLines = True
        .FullRowSelect = True
        'Clear Header and ListItems
        .ListItems.Clear
        .ColumnHeaders.Clear
    End With
    'Set up column headers
    With Me.ListView1.ColumnHeaders
        .Add , , "Emp ID", 1000, lvwColumnLeft
        .Add , , "Salutation", 700, lvwColumnLeft
        .Add , , "Last Name", 2000, lvwColumnLeft
        .Add , , "First Name", 2000, lvwColumnLeft
        .Add , , "Hire Date", 1500, lvwColumnRight
    End With
    ' Add items and subitems to list control.
 
    rs.MoveFirst
    Do Until rs.EOF
        Set lstItem = Me.ListView1.ListItems.Add()
        lstItem.Text = rs!EmployeeID
        lstItem.SubItems(1) = rs!TitleOfCourtesy
        lstItem.SubItems(2) = rs!LastName
        lstItem.SubItems(3) = rs!FirstName
        lstItem.SubItems(4) = rs!HireDate
       'Next row
        rs.MoveNext
    Loop
    'close recordset
    rs.Close
    DoCmd.Echo True
ErrorHandlerExit:
    Exit Sub
ErrorHandler:
    If Err = 3021 Then    ' no current record
        Resume Next
    Else
        MsgBox "Error No: " & Err.Number & "; Description: " & Err.Description
        Resume ErrorHandlerExit
    End If
 
End Sub

Il faut toutefois faire attention car si un champ possède des null l'enregistrement n'apparait pas, on solutionne par la fonction Nz() comme indiqué dans le lien.

PS pour remplir réellement le listview, faut rajouter :

Private Sub Form_Load()
Call FillEmployees
End Sub