Discussion :

[redhotchilipeppers]

Bonjour tout le monde,

Dans une feuille X, j'ai 2 colonnes A et B
Dans une feuille Y, j'ai 1 colonne C

Comment peut t-on, avec VBA, comparer 2 colonnes différentes : A de la feuille X et C de la feuille Y, et remplacer les valeurs correspondantes de la colonne C de la feuilleY par celle de la colonne B.

Feuille X
A1 = Dupont B1 = Arthur Dupont
A2 = Durand B2 = Pierre Durand
A3 = Smith B3 = John Smith

Feuille Y Avant:
C1:Dupont
C2:Durand
C3:Smith

---> Feuille Y Après:
C1:Arthur Dupont
C2:Pierre Durand
C3:John Smith

Merci d'avance :)

[Thautheme]

Bonsoir Redhotchillipeppers, bonsoir le forum,

Peut-être comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Macro1()
Dim X As Object 'déclare la variable X (onglet X)
Dim Y As Object 'déclare la variable Y (onglet Y)
Dim TX As Variant 'déclare la variable TX (Tableau de cellules de l'onglet X)
Dim TY As Variant 'déclare la variable TY (Tableau de cellules de l'onglet Y)
Dim I As Integer 'déclare la variable I (Incrément)
Dim J As Integer 'déclare la variable J (incrément)
 
Set X = Sheets("X") 'définit l'onglet X (à adapter)
Set Y = Sheets("Y") 'définit l'onglet Y (à adapter)
TX = X.Range("A1:B" & A.Cells(Application.Rows.Count, 1).End(xlUp).Row) 'définit le tableau TX
TY = Y.Range("C1:C" & Y.Cells(Application.Rows.Count, 3).End(xlUp).Row) 'définit le tableau TY
For I = 1 To UBound(TX, 1) 'boucle 1 : sur toutes les lignes du tableau TX
    For J = 1 To UBound(TY, 1) 'boucle 2 : sur toutes les lignes du tableau TY
        'si la valeur la la ligne I, colonne 1 (=> colonne A) de TX est égale à la valeur ligne J, colonne 1 (=> colonne C) de TY
        'la cellule en ligne J, colonne 3 (=C) de l'onglet Y prend la valeur de la ligne I, colonne 2 (=>colonne B) de TX
        If TX(I, 1) = TY(J, 1) Then Y.Cells(J, 3).Value = TX(I, 2)
    Next J 'prochaine ligne de la boucle 2
Next I 'prochaine ligne de la boucle 1
End Sub

[redhotchilipeppers]

Bonjour Thautheme, Merci beaccoup pour ta réponse, ça marche comme je veux