Discussion :

[Drowan]

Bonjour le forum,


J'ai un petit souci. Je travaille avec une listview dans un formulaire (jusque là rien de bien foufou). J'ai besoin de creer un menu contextuel de type popup lors du click droit dans cet listView.
en cherchant un peu j'ai trouvé ceci, à partir de quoi je vais faire mes test pour concevoir mon menu.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Private Sub lstv_Cahier_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As stdole.OLE_XPOS_PIXELS, ByVal y As stdole.OLE_YPOS_PIXELS)
    If Button = 2 Then Call MenuClickDroit
End Sub
 
Private Sub MenuClickDroit()
    Dim CB As CommandBar
    Dim C As CommandBarButton
 
 
    CommandBars("MonContextuel").Delete
 
    Set CB = CommandBars.Add(Name:="MonContextuel", Position:=msoBarPopup, temporary:=True)
    With CB
        Set C = .Controls.Add(Type:=msoControlButton)
        With C
            .OnAction = "affichetoto"
            .FaceId = 2
            .Caption = "toto"
        End With
        Set C = .Controls.Add(Type:=msoControlButton)
        With C
            .OnAction = "affichezaza"
            .FaceId = 3
            .Caption = "zaza"
        End With
            .ShowPopup
    End With
 
End Sub
 
Sub affichetoto()
MsgBox "C'est Toto"
End Sub
 
Sub affichezaza()
MsgBox "Je m'appelle Zaza"
End Sub

Une fois dans mon formulaire, je réalise mon click droit et le menu s'affiche bien. Mais quand le click sur un choix, rien ne se passe. et si je click sur un deuxième choix par la suite, je me retrouve avec l'erreur 400 (Je ne sais pas ce qu'elle signifie). Quelqu'un aurait l'amabilité de me venir en aide ?

Je n'ai pas précisé, je suis sous excel 2010. (je sais pas si ça change quelque chose mais dans le doute)

J'ai éxécuté le programme en pas à pas, et tout fonctionne jusqu'à la ligne ".ShowPopup" . là il attend que je clique sur un bouton du menu, et lorsque c'est fait, il quitte la procédure MenuClickDroit.

[parmi]

Essaie comme ceci

Dans le code du UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub lstv_Cahier_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As stdole.OLE_XPOS_PIXELS, ByVal y As stdole.OLE_YPOS_PIXELS)
    If Button = 2 Then
        AfficherPopUpMenu
    End If
End Sub
 
Private Sub UserForm_Terminate()
    DeletePopUpMenu
End Sub

Dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Sub DeletePopUpMenu()
    On Error Resume Next
    Application.CommandBars("MonContextuel").Delete
    On Error GoTo 0
End Sub
 
Sub AfficherPopUpMenu()
    ' Delete any existing popup menu.
    Call DeletePopUpMenu
 
    ' Create the popup menu.
    Call MenuClickDroit
 
    ' Display the popup menu.
    On Error Resume Next
    Application.CommandBars("MonContextuel").ShowPopup
    On Error GoTo 0
End Sub
 
Sub MenuClickDroit()
 
    ' Add the popup menu.
    With Application.CommandBars.Add(Name:="MonContextuel", Position:=msoBarPopup, _
         MenuBar:=False, Temporary:=True)
 
        ' First, add two buttons to the menu.
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "toto"
            .FaceId = 2
            .OnAction = "affichetoto"
        End With
 
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "zaza"
            .FaceId = 3
            .OnAction = "affichezaza"
        End With
 
    End With
End Sub
 
Sub affichetoto()
MsgBox "C'est Toto"
End Sub
 
Sub affichezaza()
MsgBox "Je m'appelle Zaza"
End Sub

[Drowan]

Parfait c'est exactement ce qu'il me fallait

merci