Discussion :

[peltiarn]

Bonsoir, la raison de mon post est que je n'ai pas trouvé de sujet similaire sur le forum (ce qui m'étonne, peut-être car je n'ai pas utilise les bons mots clés).
Je souhaite simplement afficher une form lentement en jouant sur l'opacité, mais je ne sais pas pourquoi malgres differents essais sa ne fonctionne pas.

Je souhaitai utiliser un sub pour pouvoir appliquer l'affichage lent a n'importe quel form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
' Code bouton
dim Essai as new threading.thread(addressof AfficherForm)
Essai.isbackground = true
Essai.start(form2)
 
'Code du sub
Sub AfficherForm(byval FormCible as form)
FormCible.showdialog()
FormCible.opacity = 0
While Not FormCible.opacity = 1
FormCible.opacity += 0.1
End while
End sub

Mais sa n'a pas fonctionner j'ai donc essayer de simplifier en codant directement dans le "load" d'un form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
'dans le form load:
  Me.Opacity = 0
        While Not Me.Opacity = 1
            Me.Opacity += 0.1
            Threading.Thread.Sleep(100)
        End While

Sans succès non plus ...

[Pol63]

quand on change une propriété sur controle, celui ci demande son redessin à lui même pour refléter les changements
c'est un évènement de redessin qui est mis sur la pile des évènements, qui est donc exécuté quand c'est dépilé, et ca ne peut pas dépiler tant que tu n'es pas sortie de ta sub
le thread principal servant à ton code et à tout ce qui est rafrichissement de l'interface

ceci explique pourquoi ton 2ème code ne fait rien


pour le 1er code il faut savoir que showdialog est bloquant, donc tant que la fenetre n'est pas fermé, les instructions qui sont après sont en attente


après ton code n'est pas safe, il faut activer option strict on sur le projet, il te soulignera alors les choses qu'il ne faut pas écrire car possibles sources de bug

[peltiarn]

Merci pour ces explications,
Il me faut donc poursuivre sur le premier code, le probleme étant que "FormCible.show" ou "FormCible.visible = true" m'affiche la form puis la fait disparaitre aussitot

[Pol63]

ci dessous le code qui fait ce que tu cherches avec les explications (classe à mettre dans un fichier)
ce n'est qu'une façon de faire, il y en a des mieux
n'hésite pas si tu as des questions sur le fonctionnement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Public Class FormAnimation
 
    Public Shared Sub ShowAnimation(f As Form)
        f.Opacity = 0
        AddHandler f.Shown, AddressOf FormShown
        f.Show()
    End Sub
 
    Public Shared Function ShowDialogAnimation(f As Form) As DialogResult
        f.Opacity = 0
        AddHandler f.Shown, AddressOf FormShown
        Return f.ShowDialog
    End Function
 
 
 
    Private Shared Sub FormShown(sender As Object, e As System.EventArgs)
        ' sender contient le déclencheur, ici le form
        Dim f As Form = DirectCast(sender, Form)
        Dim t As New System.Windows.Forms.Timer ' on créé un timer qui va géré l'animation
        t.Interval = 80 ' en ms
        t.Tag = f ' pour lier un form à un timer, et donc retrouver le form en fonction du timer (.tag sert à mettre tout et n'importe quoi)
        AddHandler t.Tick, AddressOf OpacityIncrement ' on s'abonne à l'event tick du timer
        t.Start()
        RemoveHandler f.Shown, AddressOf FormShown ' on se désabonne à l'event, il faut toujours se désabonner des events auxquels on s'est abonné quand on en a plus besoin
    End Sub
 
    Private Shared Sub OpacityIncrement(sender As Object, e As System.EventArgs)
        ' sender contient le déclencheur, ici le timer
        Dim t As Timer = DirectCast(sender, Timer)
        Dim form = DirectCast(t.Tag, Form)
 
        If form.Opacity >= 1 Then ' condition d'arrêt et de sortie
            t.Stop() ' arrêt du timer
            RemoveHandler t.Tick, AddressOf OpacityIncrement ' retirer l'abonnement à l'event
            t.Dispose() ' destruction de l'objet en mémoire
            Exit Sub
        End If
 
        form.Opacity += 0.1 'incrément 
    End Sub
 
End Class

ca s'utilise comme ca :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim f As New Form1
FormAnimation.ShowAnimation(f)

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim f As New Form1
dim r = FormAnimation.ShowDialogAnimation(f)

pour du showdialog

[peltiarn]

J'ai mis du temps a comprendre l'utilisation du Haddhandler mais je crois avoir a peu pres saisis, je te remercie de ton aide ainsi que des commentaires.
Petite question, est il possible d'enlever le temps mort qui est d'environ 2 secondes avant que l'affichage ne commence ?

[Pol63]

J'ai mis du temps a comprendre l'utilisation du Haddhandler mais je crois avoir a peu pres saisis, je te remercie de ton aide ainsi que des commentaires.

quand tu poses un bouton et que tu doubles clics dessus du arrives dans une sub, préfixée de Handles Button1.Click
ca signifie que cette sub va être appelé lors de l'event Click de cette instance
AddHandler / RemoveHandler permet de faire un lien du même type à l'exécution
(pour info à la compilation le mot clé Handles est transformé en AddHandler + RemoveHandler)

Petite question, est il possible d'enlever le temps mort qui est d'environ 2 secondes avant que l'affichage ne commence ?

j'ai fermé ma solution, essaye en mettant 0.3 sur opacity au lieu de 0 au début
sinon faire en sorte que le timer.interval accélère (.interval = 20 au début, et dans l'event tick faire .interval += 10