Discussion :

[JOHN14]

Bonjour à tous,

J'ai un problème, je voudrais créer une jointure entre deux tables ACCESS.

Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
    sTableName_1 = "SYNDICATS"
    sTableKey_1 = "CLE_SYNDICAT"
 
    sTableName_n = "TOTAL_OPERATION_TIMBRE_EXERCICE"
    sTableKey_n = "LIEN_CLE_SYNDICAT"
 
 
    Dim dbs: Set dbs = CurrentDb
 
    ' Add a foreign key to the Orders table.
    dbs.Execute "ALTER TABLE " & sTableName_n _
        & " ADD CONSTRAINT " & sTableKey_n _
        & " FOREIGN KEY (" & sTableKey_1 & ")" _
        & " REFERENCES " & sTableName_1 & " (" & sTableKey_1 & ");"

J'ai le message: Définition de champ "CLE_SYNDICAT" non valide dans la définition de l'index ou de la relation. Pourtant le champ existe.

Je ne comprends pas. Mercie de votre aide

[Tofalu]

Le champ cle_syndicat existe bien dans les deux tables ?

[JOHN14]

Bonjour,
Le champ "CLE_SYNDICAT" exite en clé primaire dans une table et je veux créer une contrainte référentielle avec le champ "LIEN_CLE_SYNDICAT" d'une autre table.
ie établir une jointure 1-n par VBA.

[Tofalu]

Il faut créer le champ dans la deuxième table au préalable. La clé étrangère n'est que la contrainte d'intégrité liant deux champs existants

[JOHN14]

Bonjour,
Les deux champs existent mais ils n'ont pas le même nom. Ce qui est possible manuellement devrait pouvoir se faire par VBA ?
Cdt.

[Tofalu]

Voici un exemple utilisant DAO

Structure des tables :

tblClient(id,Nom,Prenom)
tblCommande(idcommande,idClient)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub CreerCleEtrangere()
Dim oDb As DAO.Database
 
Dim oRel As DAO.Relation
Dim oFld As DAO.Field
 
Set oDb = CurrentDb
'Crée une relation entre la table tblClient et tblCommande.
'La table principale doit être celle disposant d'un index unique
Set oRel = oDb.CreateRelation("RelClientCommande", "tblClient", "tblCommande")
With oRel
    'Ajoute un champ de jointure dans la relation
    'Name : nom du champ dans la table principale tblClient
    'ForeignName : nom du champ dans la table "étrangère" tblCommande
    Set oFld = .CreateField
    With oFld
        .Name = "Id"
        .ForeignName = "IdClient"
    End With
    .Fields.Append oFld
    'Mise à jour et suppression en cascade
    .Attributes = .Attributes + dbRelationDeleteCascade + dbRelationUpdateCascade
End With
'Ajoute la relation à la structure de la base
oDb.Relations.Append oRel
 
End Sub