Discussion :

[Capistran77]

Bonsoir à toutes et à tous,

Juste un petit souci avec le bout de code suivant......qui me détecte une série de valeurs en fonction de la reconnaissance d'une valeur en colonne T......j'aimerais y planter un paste special value pour rapatrier les valeurs seulement plutôt que les formules.....où me conseilleriez vous de l'y inclure ?

Merci !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
For Each cel In Range("t6:t56")
If UCase(cel) = "SC" Then
Range("t" & cel.Row & ":x" & cel.Row).Copy _
    Sheets("TEST1").Range("A" & Sheets("TEST1").Range("A65536").End(xlUp).Row + 1)
End If
Next
End Sub

[Philippe Tulliez]

Bonjour,
Tu souhaites faire une exportation des données sans les formules et suivant un ou plusieurs critères.
Je te propose un code VBA basé sur le filtre avancé.
Il faut 3 zones (la liste des données, la zone d'exportation, la zone des critères où tu places une formule ou des critères.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub ExportByAdvancedFilter()
 Dim rngFrom As Range, rngTo As Range, CriteriaRange As Range
 ' Formule chr(34) retourne le caractère ASCII correspondant au code des guillemets
 ' Formule  pour l'exemple =MAJUSCULE(db!K2)="BMW"
 Dim formula$: formula = "=UPPER(db!K2)=" & Chr(34) & "BMW" & Chr(34)
 With ThisWorkbook
  Set rngFrom = .Worksheets("db").Range("A1").CurrentRegion ' Liste des données
  Set rngTo = .Worksheets("Export").Range("A1") ' Zone d'exportation
  Set CriteriaRange = .Worksheets("Param").Range("A1:A2") ' Zone des critères
 End With
 CriteriaRange(2) = formula ' Place la formule dans la 2ème cellule de la zone des critères
 ' Exportation des données suivant critères
 rngFrom.AdvancedFilter xlFilterCopy, CriteriaRange, rngTo
End Sub

Le gros avantage de cette méthode est la paramétrisation de ton application.
Les lignes de code utilisant formula n'étant pas obligatoire, il suffit de modifier à la main la valeur des critères. Ce qui rend pérenne ton développement.
Pour en savoir plus Les filtres avancés ou élaborés dans Excel

[Capistran77]

Merci, c'est on ne peut plus clair !

Meilleures salutations du Québec, où que vous soyez.