Discussion :

[Vincent32]

Bonjour,

Encore une petite question, la dernière normalement (du moins pour ce programme).

Je souhaiterais colorer toutes les lignes paires (de la colonne A à L contenant une valeur sur la ligne

Je sais que pour colorer une sélection il faut utiliser cette fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
With Selection.Interior
        .ColorIndex = 15
        .Pattern = xlSolid
    End With

Comment faire pour savoir si la ligne est vide ?

Puis je pour définir si la ligne est paire ou pas utiliser la fonction suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
for n=1 to infinity
if ligne=2n then range(Aligne:Lligne).Select
With Selection.Interior
        .ColorIndex = 15
        .Pattern = xlSolid
    End With
end if

Merci de votre aide

Vincent

[fring]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub test()
Dim derL As Long, x As Long, y As Byte, Verif As String, Sh As Worksheet
 
Set Sh = Sheets("Feuil1") '<-- nom de la feuille à adaper
derL = Sh.Cells.SpecialCells(xlCellTypeLastCell).Row '<-- trouve la dernière ligne utilisée
 
For x = 2 To derL Step 2 '<-- une ligne sur deux de la ligne 2 à la dernière ligne
    Verif = ""
        For y = 1 To 12 '<-- vérification de la colonne A à la colonne L
            Verif = Verif & Sh.Cells(x, y) '<-- concaténation des valeurs de chaque cellule de la ligne dans la variable Verif
        Next y
    If Verif <> "" Then '<-- si la variable Verif n'est pas vide c'est qu'au moins une cellule de la ligne contient une valeur
        Sh.Range(Sh.Cells(x, 1), Sh.Cells(x, 12)).Interior.ColorIndex = 5
    End If
Next x
 
End Sub

[Vincent32]

Merci énormément ça tourne nickel

[EvaristeGaloisBis]

Juste une remarque pourquoi ne pas passer par une mise en forme conditionnelle? °_°