Discussion :

[juju1988]

Voilà j'ai ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Windows("analyses.xls").Activate
            If Range((nomCel + 1)& i).Value <> "" Then
                Windows("analyses.xls").Activate
                recupVal = Range((nomCel+1)& i).Value
                Windows("exemple.xls").Activate
                ActiveCell.Value = recupVal
            Else
                Windows("analyses.xls").Activate
                recupVar = Range(nomCel & i).Value
                Windows("exemple.xls").Activate
                ActiveCell.Value = recupVar
            End If

J'aimerai qu'au niveau (nomCel + 1) passer à la colonne suivante... En fait dans mon code je parcours ma colonne N ... si au même endroit dans ma colonne O j'ai une valeur alors je prend cette valeur et la récupère en lieu et place de la valeur en colonne N...

Si je ne suis pas claire merci de me poser des questions...

Merci d'avance

[Duffyduff]

Salut,

Si je comprends bien tu utilises deux colonne et le même nombre de lignes.
Pourquoi ne pas utiliser un simple "for each".
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Test()
 
For Each Cel In Range(Cells(53, 1), Cells(63, 1)) ' 1 et 10 à modifier en fonction de la ligne de début et de fin
Cel.Select
ligne = ActiveCell.Row
If Cel.Value = "" Then
Cel.FormulaR1C1 = Cells(ligne, 2).Value 'modifie le "2" avec le numéro de la colonne cible
ElseIf Cells(ligne, 2) = "" Then        'modifie le "2" avec le numéro de la colonne cible
Cells(ligne, 2).FormulaR1C1 = Cel.Value 'modifie le "2" avec le numéro de la colonne cible
End If
Next Cel
End Sub

[juju1988]

Je suis désolée je débute en vba et je ne comprend pas trop ton code... Je n'arrive pas à le transposer par rapport au mien ...

[juju1988]

C'est bon j'ai réussi ... Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
celSuivante = Range(nomCel & i).Column + 1
 
            If Cells(i, celSuivante).Value <> "" Then
                Windows("analyses.xls").Activate
                recupVal = Cells(i, celSuivante).Value
                Windows("exemple.xls").Activate
                ActiveCell.Value = recupVal
            Else
 
                Windows("analyses.xls").Activate
                recupVal = Range(nomCel & i).Value
                Windows("exemple.xls").Activate
                ActiveCell.Value = recupVal
            End If

[fring]

Bonjour,

Il faut éviter dans la mesure du possible de travailler avec les ActiveCell et autres ActiveMachin.

En supposant que tes 2 classeurs sont ouverts, ça donnerait un truc de ce genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub test()
Dim i As Long, DerL As Long
Dim ShS As Worksheet, ShD As Worksheet
 
'on définit la feuille source
Set ShS = Workbooks("analyses.xls").Sheets("Feuil1")
 
'on définit la feuille de destination
Set ShD = Workbooks("exemple.xls").Sheets("Feuil1")
 
'on cherche la dernière ligne de la colonne N de la feuille source
DerL = ShS.Cells(Rows.Count, 14).End(xlUp).Row
 
'on boucle sur toutes les lignes de la colonne N de la feuille source
'de la ligne 1 à la dernière ligne
For i = 1 To DerL
    If ShS.Cells(i, 15) <> "" Then '<-- si valeur dans la colonne O
        ShD.Cells(i, 1) = ShS.Cells(i, 15) '<-- transcription valeur colonne O dans le classeur de destination en colonne A
    Else
        ShD.Cells(i, 1) = ShS.Cells(i, 14) '<-- sinon transcription valeur colonne N
    End If
Next i
 
End Sub

[juju1988]

Ok, merci