Discussion :

[zut94]

Bonjour,

Y-a-t'il une fonction qui me permettre de compter le nombre d'apparition d'un caractère dans une chaine? Par exemple dans la chaine suivante, j'aimerai connaitre le nombre de fois qu'apparait le caractère '@', c'est-à-dire 2 fois

Exemple: mon@dresse@11752

[hmira]

Je ne connais pas de fonction native intégrée à SQL Server permettant de faire cela, mais il existe une fonction CHARINDEX très pratique. On utilisant la fonction CHARINDEX dans une petite boucle, il est très facile de déterminer le nombre d’occurrence d’une sous-chaine dans une chaine.

Ci-dessous une fonction que j’ai concoctée et qui répond à ta demande :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
CREATE FUNCTION dbo.FC_U_CountSubStr ( 
        @pi_String varchar(8000), 
        @pi_SubString varchar(8000)
        )  
  RETURNS INT 
  AS 
  BEGIN 
	  DECLARE @LenString INT, 
		@i INT = 1, 
		@p INT = 0, 
		@NbrOccurrence INT = 0; 
 
	  SET @LenString  = len(@pi_String); 
 
	  WHILE @i <= @LenString 
	  BEGIN 
		 SET @p = charindex (@pi_SubString, @pi_String, @i) 
		 IF @p > 0 
		   SET @NbrOccurrence += 1;  
		 ELSE 
		   BREAK;    
		 SET @i = @p +1 ; 
	  END; 
    RETURN @NbrOccurrence; 
  END;   
  GO

Exemple d'utilisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SELECT dbo.FC_U_CountSubStr('mon@dresse@11752', '@') aS  nombreOccurrences

Résultat :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
nombreOccurrences
2

[Philippe Robert]

Il existe une autre solution, que je trouve très astucieuse :

1. Tu comptes le nombre de caractères de ta chaîne (fonction LEN)
2. Tu remplace le caractère que tu souhaites dénombrer par une chaine vide (fonction REPLACE).
3. Tu comptes le nombre de caractères de la chaîne résultante.
4. Tu soustrais le résultat du point 3 du point 1.

Un exemple : compter le nombre de "I'

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
DECLARE @Chaine as varchar(100)
SET @Chaine = 'IL VA PLEUVOIR'
SELECT LEN(@Chaine) - LEN(REPLACE(@chaine,'I', ''))

Résultat : 2

Pas besoin de boucle et moins de code a écrire !

A+

[hmira]

Bien joué !
A+

[ziffox]

Très astucieux !
merci

[SQLpro]

À titre de comparaison....

1) fonction de hmira optimisée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
CREATE FUNCTION dbo.F_COMPTE_LETTRE_1 (@STRING VARCHAR(8000),
                                       @LETTRE CHAR(1)) 
RETURNS SMALLINT
WITH RETURNS NULL ON NULL INPUT
AS 
BEGIN 
DECLARE @LEN SMALLINT, 
		@I   SMALLINT = 0, 
		@J   SMALLINT, 
		@NBR INT = 0; 
 
SET @LEN  = LEN(@STRING); 
 
WHILE @I <= @LEN
BEGIN 
   SET @J = CHARINDEX (@LETTRE, @STRING, @I) 
   IF @J > @I 
   BEGIN
      SELECT @I = @J+1, @NBR += 1;
      CONTINUE;
   END    
   ELSE
            BREAK; 
END;   
RETURN @NBR;
END
GO

Fonction de Philippe Robert optimisée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
CREATE FUNCTION dbo.F_COMPTE_LETTRE_2 (@STRING VARCHAR(8000),
                                       @LETTRE CHAR(1)) 
RETURNS SMALLINT
WITH RETURNS NULL ON NULL INPUT
AS 
BEGIN 
   RETURN LEN(@STRING) - LEN(REPLACE(@STRING, @LETTRE, ''));
END
GO

tests :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
SELECT   dbo.F_COMPTE_LETTRE_1('abracadabra', 'a')
SELECT   dbo.F_COMPTE_LETTRE_1('locomotive', 'a')
SELECT   dbo.F_COMPTE_LETTRE_1(NULL, 'a')
 
SELECT   dbo.F_COMPTE_LETTRE_2('abracadabra', 'a')
SELECT   dbo.F_COMPTE_LETTRE_2('locomotive', 'a')
SELECT   dbo.F_COMPTE_LETTRE_2(NULL, 'a')

Test en vrai grandeur : table de 1 250 000 employés :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
DECLARE @T1 DATETIME2, @T2 DATETIME2
SET @T1 = GETDATE()
SELECT EMP_ID, EMP_NOM, dbo.F_COMPTE_LETTRE_?(EMP_NOM, 'E')
FROM   dbo.T_EMPLOYEE_EMP
SET @T2 = GETDATE()
SELECT DATEDIFF(ms, @T1, @T2)

Résultat :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
fonction                temps (ms)
----------------------- ----------
dbo.F_COMPTE_LETTRE_1       8 043
dbo.F_COMPTE_LETTRE_2       7 717

A +